"{ Package: 'jv:calipel/s' }"

Object subclass:#BenchmarkRunner

	instanceVariableNames:'debugging'

	classVariableNames:''

	poolDictionaries:''

!

!BenchmarkRunner class methodsFor:'documentation'!

documentation

"

 Replace 'Object', 'NewClass1' and

 the empty string arguments by true values.

 Install (or change) the class by 'accepting',

 either via the menu or the keyboard (usually CMD-A).

 You can also change the category simply by editing

 the categoryString and accepting.

 To be nice to others (and yourself later), do not forget to

 add some documentation; preferably under the classes documentation

 protocol.

 (see the `create documentation stubs' item in the methodList menu;

  switch from instance to class to find this menu item.)

 Notice, that ST/X uses the convention to document the class using

 comment-only class methods (however, ST80 comments are supported and

 can be changed via the class-documentation menu).

"

! !

!BenchmarkRunner class methodsFor:'instance creation'!

new

    "return an initialized instance"

    ^ self basicNew initialize.

! !

!BenchmarkRunner methodsFor:'accessing'!

debugging

    ^ debugging

!

debugging:aBoolean

    debugging := aBoolean.

! !

!BenchmarkRunner methodsFor:'error handling'!

exit: code

    debugging ifFalse:[

        BenchmarkPlatform current exit: code

    ].

    "Created: / 02-11-2012 / 02:32:10 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 06-06-2013 / 09:13:42 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!BenchmarkRunner methodsFor:'initialization'!

initialize

    "Invoked when a new instance is created."

    debugging := BenchmarkPlatform current isHeadless not

    "Modified: / 06-06-2013 / 09:24:00 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!BenchmarkRunner methodsFor:'main'!

main:argv

    | i suite result report file params classes runs |

    params := Dictionary new.

    classes := OrderedCollection new.

    report := BenchmarkReport text.

    runs := 5.

    i := 1.

    [ i <= argv size ] whileTrue:[

        | arg |

        arg := argv at: i.

        i := i + 1.

        arg first == $- ifTrue:[

            arg = '-n' ifTrue:[

                runs := Integer readFrom: (argv at: i) onError:[

                    self error: '-n requires an integer parameter'.

                    self exit: 1.

                ].

                i := i + 1.

            ].

            arg = '-o' ifTrue:[

                file := argv at: i.

                i := i + 1.

            ].

            arg = '-r' ifTrue:[

                | reportNm |

                reportNm := (argv at: i).

                i := i + 1.

                report := Smalltalk at: reportNm asSymbol.

                report isNil ifTrue:[

                    self error: 'No report class named ''', reportNm, ''''.

                ].

            ].

            arg = '--text' ifTrue:[

                report := BenchmarkReport text.

            ].

            arg = '--json' ifTrue:[

                report := BenchmarkReport json.

            ].

            arg second = $D ifTrue:[

                | eqIdx |

                ((arg size > 2) and:[(eqIdx := arg indexOf: $= startingAt: 3) ~~ 0]) ifTrue:[

                    params at: (arg copyFrom: 3 to: eqIdx - 1) put: (arg copyFrom: eqIdx + 1)

                ] ifFalse:[

                    self error: 'No parameter value'

                ]

            ]

        ] ifFalse:[

            classes add: arg.

        ]

    ].

    "Build suite"

    suite := BenchmarkSuite new.

    classes do:[:each|

        | classNm class selector |    

        i := each indexOf: $#.

        i ~~ 0 ifTrue:[

            classNm := each copyTo: i - 1.

            selector := (each copyFrom: i + 1) asSymbol.

        ] ifFalse:[

            classNm := each.

        ].

        class := Smalltalk at: classNm asSymbol.

        class isNil ifTrue:[

            self error: 'Class ', classNm , ' does not exists'.

        ].

        Smalltalk isSmalltalkX ifTrue:[

            class isLoaded ifFalse:[class autoload].

        ].

        selector isNil ifTrue:[

            suite addBenchmark: (BenchmarkSuite class: class)

        ] ifFalse:[

            suite addBenchmark: (BenchmarkSuite class:class selector:selector)

        ]

    ].

    "Run suite"

    result runs: runs.

    suite run: result with: params.

    "Write report"

    file notNil ifTrue:[

        file asFilename writingFileDo:[:s|

            report write: result on: s 

        ]

    ] ifFalse:[

        report write: result on: BenchmarkPlatform current stdout

    ].

    self exit: 0.

!

options

    "Prints common command line options to stderr"

    BenchmarkPlatform current stderr nextPutAll:

'

Common options:

  -o FILE ................ write output to FILE instead of to standard output (default: stdout)

  -n RUNS ................ how many times to run each bechmark (default: 5)

  -r REPORTCLASS ......... user REPORTCLASS to generate report (default: BenchmarkReportText)

  --text ................. generate text report (equivalent to -r BenchmarkReportText)

  --json ................. generate JSON report (equivalent to -r BenchmarkReportJSON)

  -DNAME=VALUE ........... defines a parameter NAME with value of VALUE

Suitespec format:

  <suitespec> is CLASSNAME[#SELECTOR]

More documetation:

  see https://bitbucket.org/janvrany/jv-calipel/wiki/Home

'

    "Created: / 06-06-2013 / 11:01:42 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!BenchmarkRunner class methodsFor:'documentation'!

version_HG

    ^ '$Changeset: <not expanded> $'

! !