"{ Encoding: utf8 }"

	instanceVariableNames:'source lookahead token'

	poolDictionaries:'GDBMICommandStatus'

	category:'GDB-Private'

parseNl

    | c |

    c := self peek.

    (c == Character return or:[ c == Character cr ]) ifTrue:[ 

        self next

    ].

    "Created: / 30-05-2014 / 09:52:36 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 31-05-2014 / 00:38:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseOutOfBandRecord

    "

    out-of-band-record → async-record | stream-record

    "

    ('*+=' includes: self peek) ifTrue:[ 

        self parseAsyncRecord.

    ].

    ('~@&' includes: self peek) ifTrue:[ 

        self parseStreamRecord.

    ].

    self error: 'Invalid out-of-bound record'

    "Created: / 30-05-2014 / 09:52:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseOutput

    "

    output → ( out-of-band-record )* [ result-record ] '(gdb)' nl

    "

    | events |

    events := GDBMIEventSet new.

    [ 

        self peek isDigit ifTrue:[ self parseToken ].

        self peek ~~ $^

    ] whileTrue:[ 

        events add: self parseOutOfBandRecord.

    ].

    events add: self parseResultRecord.

    self expect: '(gdb)'.

    self parseNl.

    ^ events

    "Created: / 30-05-2014 / 09:52:36 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 31-05-2014 / 00:39:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseResultClass

    "

    result-class → 'done' | 'running' | 'connected' | 'error' | 'exit'

    "

    | c1 c2 |

    c1 := self peek.

    c1 == $d ifTrue:[ 

        self expect: 'done'.

        ^ CommandStatusDone.

    ].

    c1 == $r ifTrue:[ 

        self expect: 'running'.

        ^ CommandStatusRunning.

    ].

    c1 == $c ifTrue:[ 

        self expect: 'connected'.

        ^ CommandStatusConnected.

    ].

    c1 == $e ifTrue:[ 

        self next.

        c2 := self peek.

        c2 == $x ifTrue:[ 

            self expect: 'xit'.

            ^ CommandStatusExit.

        ].

        c2 == $r ifTrue:[ 

            self expect: 'rror'.

            ^ CommandStatusError.

        ].

    ].

    ^ self error:'Unsupported result class'

    "Created: / 31-05-2014 / 00:16:31 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseResultRecord

    "

    result-record → '^' result-class ( ',' result )* nl

    "

    | result |

    self expect: $^.

    result := GDBMICommandResult new.

    result status: self parseResultClass.

    self peek == $, ifTrue:[ 

        self next.

        result value: self parseResult.

    ].

    self parseNl.

    ^ GDBMICommandResultEvent new result: result.

    "Created: / 30-05-2014 / 09:52:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 31-05-2014 / 00:34:33 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

!GDBMIParser methodsFor:'parsing-async events'!

parseAsyncClass

    "raise an error: this method should be implemented (TODO)"

    self peek == $s ifTrue:[ 

        self expect: 'stopped'.

        ^ self

    ].

    self error:'Unsupported async class'

    "Created: / 30-05-2014 / 10:15:54 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseAsyncOutput

    "

    async-output → async-class ( ',' result )* nl

    "

    self parseAsyncClass.

    [ self peek == $, ] whileTrue:[ 

        self next.

        self parseResult

    ].

    self parseNl.

    "Created: / 30-05-2014 / 10:13:28 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseAsyncRecord

    "

    async-record → exec-async-output | status-async-output | notify-async-output

    "

    self peek == $* ifTrue:[ 

        ^ self parseExecAsyncOutput.

    ].

    self peek == $+ ifTrue:[ 

        ^ self parseStatusAsyncOutput.

    ].

    self peek == $= ifTrue:[ 

        ^ self parseNotifyAsyncOutput.

    ].

    ^ self error: 'Invalid async-record'

    "Created: / 30-05-2014 / 09:57:30 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseExecAsyncOutput

    "

    exec-async-output → '*' async-output

    "

    self expect: $*.

    ^ self parseAsyncOutput.

    "Created: / 30-05-2014 / 10:10:36 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseNotifyAsyncOutput

    "

    status-notify-output → '=' async-output

    "

    self expect: $*.

    ^ self parseAsyncOutput.

    "Created: / 30-05-2014 / 10:10:37 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseStatusAsyncOutput

    "

    status-async-output → '+' async-output

    "

    self expect: $*.

    ^ self parseAsyncOutput.

    "Created: / 30-05-2014 / 10:10:36 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBMIParser methodsFor:'parsing-misc'!

parseResult

    "

    result → variable = value

    "

    | name value |

    name := self parseVariable.

    self expect: $=.

    value := self parseValue.

    ^ name -> value

    "Created: / 30-05-2014 / 10:15:55 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 31-05-2014 / 00:39:51 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseString

    ^ String streamContents:[:s|

        [ self peek isLetter or:['-' includes: self peek ] ]  whileTrue:[

            s nextPut: self next.

        ]

    ].

    "Created: / 30-05-2014 / 10:32:02 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 31-05-2014 / 00:33:59 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseVariable

    "

    variable → string

    "

    ^ self parseString

    "Created: / 30-05-2014 / 10:31:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBMIParser methodsFor:'parsing-stream output'!

parseConsoleStreamOutput

    self expect: $~.

    ^ self parseCString

    "Created: / 30-05-2014 / 10:28:16 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseLogStreamOutput

    self expect: $&.

    ^ self parseCString

    "Created: / 30-05-2014 / 10:28:18 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseStreamRecord

    "

    stream-record → console-stream-output | target-stream-output | log-stream-output

    "

    self peek == $~ ifTrue:[ 

        ^ self parseConsoleStreamOutput

    ].

    self peek == $@ ifTrue:[ 

        ^ self parseTargetStreamOutput

    ].

    self peek == $& ifTrue:[ 

        ^ self parseLogStreamOutput

    ].

    self error:'Invalid stream record'

    "Created: / 30-05-2014 / 09:57:31 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseTargetStreamOutput

    self expect: $@.

    ^ self parseCString

    "Created: / 30-05-2014 / 10:28:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBMIParser methodsFor:'parsing-values'!

parseConst

    "

    const → c-string

    "

    ^ self parseCString.

    "Created: / 30-05-2014 / 10:36:04 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseList

    "

    list → '[]' | '[' value ( ',' value )* ']' | '[' result ( ',' result )* ']'

    "

    self expect: $[.

    ^ self peek == $] ifTrue:[ 

        self next.

         #()

    ] ifFalse:[ 

        Array streamContents:[ :s|

            s nextPut: self parseValue.

            [ self peek == $, ] whileTrue:[

                self next.

                s nextPut: self parseValue.

            ].

            self expect: $].

        ].

    ].

    "Created: / 30-05-2014 / 10:36:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseTuple

    "raise an error: this method should be implemented (TODO)"

    | object |

    object := GDBTuple new.

    self expect: ${.