"{ Encoding: utf8 }"

"

jv:libgdbs - GNU Debugger Interface Library

Copyright (C) 2015-now Jan Vrany

Copyright (C) 2021-2023 LabWare

Permission is hereby granted, free of charge, to any person obtaining a copy

of this software and associated documentation files (the 'Software'), to deal

in the Software without restriction, including without limitation the rights

to use, copy, modify, merge, publish, distribute, sublicense, and/or sell

copies of the Software, and to permit persons to whom the Software is

furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all

copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, EXPRESS OR

IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,

FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE

AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER

LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,

OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE

SOFTWARE.

"

"{ Package: 'jv:libgdbs' }"

"{ NameSpace: Smalltalk }"

Model subclass:#GDBDebugger

	instanceVariableNames:'connection commandSequenceNumber inferiorStateSequenceNumber

		inferiors breakpoints selectedThread selectedFrame

		prettyPrintingEnabled frameFiltersEnabled finalizationRegistry

		debuggerFeatures targetFeatures supportedCommands directories

		properties'

	classVariableNames:'FinalizationLobby'

	poolDictionaries:'GDBCommandStatus GDBFeatures'

	category:'GDB'

!

!GDBDebugger class methodsFor:'documentation'!

copyright

"

jv:libgdbs - GNU Debugger Interface Library

Copyright (C) 2015-now Jan Vrany

Copyright (C) 2021-2023 LabWare

Permission is hereby granted, free of charge, to any person obtaining a copy

of this software and associated documentation files (the 'Software'), to deal

in the Software without restriction, including without limitation the rights

to use, copy, modify, merge, publish, distribute, sublicense, and/or sell

copies of the Software, and to permit persons to whom the Software is

furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all

copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, EXPRESS OR

IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,

FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE

AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER

LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,

OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE

SOFTWARE.

"

! !

!GDBDebugger class methodsFor:'initialization'!

initialize

    FinalizationLobby := Registry new.

    "Modified: / 14-07-2023 / 14:16:35 / Jan Vrany <jan.vrany@labware.com>"

! !

!GDBDebugger class methodsFor:'instance creation'!

new    

    ^ self newWithProcess: GDBProcess new

    "Modified: / 12-12-2017 / 21:15:24 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

newWithProcess: aGDBProcess

    ^ self basicNew initializeWithProcess: aGDBProcess

    "Created: / 20-06-2014 / 21:44:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBDebugger methodsFor:'accessing'!

announcer

    ^ connection eventAnnouncer.

    "Created: / 02-06-2014 / 23:06:20 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

breakpointForId: id

    ^ self breakpointForId: id ifAbsent:[self error: ('No breakpoint with id ''%1'' found!!' bindWith: id)]

    "Created: / 18-05-2018 / 13:39:31 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 07-02-2019 / 15:04:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

breakpointForId: id ifAbsent: block

    self breakpoints do:[:bp |

        bp number = id ifTrue:[ ^ bp ].

        bp locations do: [ :loc |

            loc number = id ifTrue:[ ^ loc ].

        ].

    ].

    ^ block value.

    "Created: / 07-02-2019 / 15:04:10 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

breakpoints

    breakpoints isNil ifTrue:[ 

        breakpoints := List new.

    ].

    ^ breakpoints

    "Created: / 06-07-2017 / 16:06:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

consoleInput

    ^ connection consoleInput

    "Created: / 31-05-2017 / 23:20:29 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 02-06-2017 / 23:13:23 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

consoleOutput

    ^ connection consoleOutput

    "Created: / 31-05-2017 / 23:20:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 02-06-2017 / 23:13:31 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

directories

    "Return a list of directories where GDB looks for source code and an Array.

     Variables such as $cdir and $cwd are NOT expanded.

    "

    | result |

    directories isNil ifTrue:[

        result := self send: (GDBMI_gdb_show arguments: #('directories')).

        OperatingSystem isMSWINDOWSlike ifTrue:[ 

            "/ On Windows, GDB uses cygwin paths (i.e., slashed, unix-like paths). 

            "/ Convert them to Windows paths as used in Smalltalk/X:

            directories := ((result propertyAt: #value) tokensBasedOn: $;) 

                                collect: [ :d | (Filename cygNamed:d) pathName ]

                                as: Array.

        ] ifFalse:[ 

            directories := ((result propertyAt: #value) tokensBasedOn: $:) asArray

        ].

    ].

    ^ directories

    "Created: / 09-03-2018 / 12:05:53 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 03-04-2018 / 21:14:45 / jv"

!

features

    "Return a list of features supported ty this version og GDB.

     See 

            * `GDBFeatures` pool

            * https://sourceware.org/gdb/onlinedocs/gdb/GDB_002fMI-Support-Commands.html,

              command `-list-features`

    "

    | features |

    features := targetFeatures.

    features isNil ifTrue:[

        "/ No target (or target event support), use default features of native target.

        "/ But be careful, when GDB quits, connection may be gone!!

        features := #().

        connection notNil ifTrue: [ 

            features := connection nativeTargetFeatures

        ].

    ].

    ^ debuggerFeatures , features.

    "Created: / 07-02-2018 / 10:50:56 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 26-03-2018 / 21:35:22 / jv"

    "Modified: / 09-04-2018 / 15:39:42 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 17-11-2021 / 15:35:34 / Jan Vrany <jan.vrany@labware.com>"

!

inferiorForId: id

    ^ inferiors ? #() detect:[:e | e id = id ] ifNone:[ 

        self error: ('No inferior (thread group) with id ''%1'' found!!' bindWith: id)

    ].

    "Created: / 07-09-2014 / 21:22:56 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

inferiorStderr

    ^ connection inferiorPTY masterReadStream

    "Created: / 09-06-2014 / 10:01:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 09-06-2014 / 18:26:55 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 02-08-2023 / 12:51:17 / Jan Vrany <jan.vrany@labware.com>"

!

inferiorStdin

    ^ connection inferiorPTY masterWriteStream

    "Created: / 09-06-2014 / 10:00:30 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 09-06-2014 / 18:27:03 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 02-08-2023 / 12:51:26 / Jan Vrany <jan.vrany@labware.com>"

!

inferiorStdout

    ^ connection inferiorPTY masterReadStream

    "Created: / 09-06-2014 / 10:01:16 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 09-06-2014 / 18:27:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 02-08-2023 / 12:51:05 / Jan Vrany <jan.vrany@labware.com>"

!

inferiors

    ^ inferiors ? #()

    "Modified: / 06-07-2017 / 16:06:00 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

selectedFrame

    ^ selectedFrame

    "Created: / 09-03-2021 / 14:46:20 / Jan Vrany <jan.vrany@labware.com>"

!

selectedInferior

    selectedThread isNil ifTrue: [ 

        inferiors size == 1 ifTrue: [ 

            ^ inferiors anyOne

        ].

        ^ nil

    ].

    ^ selectedThread group

    "Created: / 07-09-2014 / 23:02:53 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 09-03-2021 / 16:16:49 / Jan Vrany <jan.vrany@labware.com>"

!

selectedThread

    ^ selectedThread

    "Created: / 09-03-2021 / 16:06:07 / Jan Vrany <jan.vrany@labware.com>"

!

threadForId: id

    inferiors ? #() do:[:tg |

        tg threads do:[:t | 

            t id = id ifTrue:[ ^ t ]

        ].

    ].

    self error: ('No thread with id ''%1'' found!!' bindWith: id)

    "Created: / 04-02-2018 / 21:37:53 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBDebugger methodsFor:'accessing-private'!

connectionTrace

    ^ connection trace

    "Created: / 09-03-2018 / 10:04:20 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

currentInferiorStateSequnceNumber

    ^ inferiorStateSequenceNumber

    "Created: / 19-06-2014 / 22:22:08 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

nextCommandSequnceNumber

    commandSequenceNumber := commandSequenceNumber + 1.

    commandSequenceNumber == SmallInteger maxVal ifTrue:[ 

        commandSequenceNumber := 0.

    ].

    ^ commandSequenceNumber

    "Created: / 02-06-2014 / 23:48:19 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

nextInferiorStateSequnceNumber

    inferiorStateSequenceNumber := inferiorStateSequenceNumber + 1.

    inferiorStateSequenceNumber == SmallInteger maxVal ifTrue:[

        inferiorStateSequenceNumber := 0.

    ].

    ^ inferiorStateSequenceNumber

    "Created: / 02-06-2014 / 23:48:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

process

    "Return a (sub)instance of `GDBProcess` used but this debugger.

     This method is provided for stx:libgdbs debugging purposes and

     should not be normally used."

    ^ connection process

    "Created: / 27-03-2019 / 09:20:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

selectedThread: thread frame: frame

    selectedThread ~= thread ifTrue: [ 

        | oldSelectedInferior newSelectedInferior |

        oldSelectedInferior := self selectedInferior.

        selectedThread := thread.

        selectedFrame := frame.

        newSelectedInferior := self selectedInferior.

        oldSelectedInferior ~~ newSelectedInferior ifTrue: [ 

            self changed: #selectedInferior with: newSelectedInferior.

        ].

        self changed: #selectedThread with: selectedThread.

        self changed: #selectedFrame with: selectedFrame

    ] ifFalse: [ 

        selectedFrame ~= frame ifTrue: [

            (selectedFrame notNil and:[selectedFrame isSameAs: frame]) ifTrue: [

                selectedFrame invalidate.

                selectedFrame setAddr: frame addr.

                selectedFrame setLine: frame line.

            ] ifFalse: [ 

                selectedFrame := frame.

            ].

            self changed: #selectedFrame with: selectedFrame

        ].

    ].

    "Created: / 09-03-2021 / 14:54:42 / Jan Vrany <jan.vrany@labware.com>"

    "Modified: / 24-01-2022 / 15:59:26 / Jan Vrany <jan.vrany@labware.com>"

! !

!GDBDebugger methodsFor:'accessing-properties'!

properties

    ^ self objectAttributes

    "Modified: / 23-06-2019 / 12:22:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

propertyAt: name    

    ^ self objectAttributeAt: name

    "Created: / 31-05-2014 / 00:00:33 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 23-06-2019 / 12:22:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

propertyAt: name put: value

    self assert: name isSymbol.

    ^ self objectAttributeAt: name put: value.

    "Created: / 31-05-2014 / 00:01:10 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 23-06-2019 / 12:22:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBDebugger methodsFor:'attributes access'!

objectAttributes

    ^ properties

    "Created: / 18-06-2014 / 07:56:51 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

objectAttributes: aDictionary

    properties := aDictionary

    "Created: / 18-06-2014 / 07:57:15 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBDebugger methodsFor:'commands'!

push: event

    "Push given `event` onto debugger's event queue. Use with care!!"

    self assert: (event isKindOf: GDBEvent).

    connection pushEvent: event

    "Created: / 09-03-2021 / 11:19:05 / Jan Vrany <jan.vrany@labware.com>"

!

send: command

    "Execute given `command` and wait until it finishes and return its result.

     `command` may be either a GDBCommand or string, in which case it will

     be parsed into a GDBCommand. 

   "

    ^ self send:command andWait:true.

    "Created: / 03-06-2014 / 00:10:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 08-03-2015 / 05:50:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

send:command andWait:wait 

    "Sends given `command` to GDB. If `wait` is true, wait for

     command to finish and return the command result.  

     Otherwise, return nil immediately.

     If `wait` is true and if command results in an error GDBError

     is thrown.

     `command` may be either a GDBCommand or string, in which case it will

     be parsed into a GDBCommand.           

    "

    | blocker result |

    self assert: self isConnected.

    ^ wait ifTrue:[

"/        self 

"/            assert:Processor activeProcess ~~ connection eventDispatchProcess

"/            message:'Cannot send commands from within event dispatching process. Would deadlock'.

        blocker := GDBPortlib current newSemaphore.

        self send: command andWithResultDo: [ :r | 

            result := r.

            blocker signal

        ].

        blocker wait.

        result isError ifTrue:[

            GDBCommandFailedError raiseForResult: result.

        ].

        result.

    ]

    ifFalse:[

        | cmd |

        cmd := command.

        cmd isString ifTrue:[

            cmd := GDBCommand parse:cmd.

        ].    

        cmd token: self nextCommandSequnceNumber.

        connection pushCommand:cmd.

        nil.

    ]

    "Created: / 02-06-2014 / 23:45:43 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 26-03-2018 / 21:19:59 / jv"

    "Modified: / 28-01-2019 / 21:26:28 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 18-08-2023 / 14:17:04 / Jan Vrany <jan.vrany@labware.com>"

!

send:command andWaitFor:eventHandlers

    "Sends given `command` to GDB and then wait for events mathing 

     `eventHandlers`. 

     Params:

     `command`      may be either a GDBCommand or string, in which case it will

                    be parsed into a GDBCommand.

     `eventHandler` may be either nil or event class or one arg block or collection

                    of event classes or blocks.

                    - If nil then do not wait for anything (use nil for async send)

                    - If event class, then wait for an event of that class. Note, that

                      subclasses are handled too.

                    - If block, then wait for an event for which the block returns true.

                    - If collectio, then wait for a sequence of events, each matched as above.

     Returns:       a matching event or events (in case a collection of handlers has been passes)"

    ^ self send: command andWaitFor: eventHandlers withTimeoutMs: nil

    "Created: / 08-03-2015 / 06:03:55 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

send:command andWaitFor:eventHandlers withTimeoutMs:timeout 

    "Sends given `command` to GDB and then wait for events mathing 

     `eventHandlers`. Raise a TimeoutError if expected events don't arrive

     in specified time.

     Params:

     `command`      may be either a GDBCommand or string, in which case it will

                    be parsed into a GDBCommand.

     `eventHandler` may be either nil or event class or one arg block or collection

                    of event classes or blocks.

                    - If nil then do not wait for anything (use nil for async send)

                    - If event class, then wait for an event of that class. Note, that

                      subclasses are handled too.

                    - If block, then wait for an event for which the block returns true.

                    - If collectio, then wait for a sequence of events, each matched as above.