"{ Package: 'jv:libgdbs/tests' }"

TestCase subclass:#GDBParserTests

	instanceVariableNames:'properties prop1 prop2 prop3'

	classVariableNames:''

	poolDictionaries:'GDBCommandStatus'

	category:'GDB-Private-Tests'

!

!GDBParserTests methodsFor:'accessing'!

prop1

    ^ prop1

!

prop2

    ^ prop2

!

prop3

    ^ prop3

! !

!GDBParserTests methodsFor:'accessing-properties'!

properties

    ^ GDBObject getPropertiesOf: self.

    "Modified: / 20-06-2014 / 09:04:23 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

propertyAt: name

    ^ GDBObject getProperty: name of: self

    "Created: / 31-05-2014 / 00:00:33 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 20-06-2014 / 09:05:05 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

propertyAt: name put: value

    ^ GDBObject setProperty: name of: self to: value

    "Created: / 31-05-2014 / 00:01:10 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 20-06-2014 / 09:05:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBParserTests methodsFor:'running'!

tearDown

    properties := nil.

    "Created: / 18-06-2014 / 07:59:02 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBParserTests methodsFor:'tests - C strings'!

test_c_string_01

    self assert: (GDBParser on: '"Hello" xxx') parseCString = 'Hello'.

    self assert: (GDBParser on: '"\"Hello\"" xxx') parseCString = '"Hello"'.

    self assert: (GDBParser on: '"\H\e\l\l\o" xxx') parseCString = 'Hello'.

    self assert: (GDBParser on: '"Hel\nlo" xxx') parseCString = 'Hel

lo'.  

    self assert: (GDBParser on: '"X\xE1X" xxx') parseCString = 'XáX'.

    self assert: (GDBParser on: '"warning: File \"/home/jv/Private/Projects/SmalltalkX/sources/branches/jv1/build/stx/.gdbinit\" auto-loading has been declined by your `auto-load safe-path'' set to \"$debugdir:$datadir/auto-load\".\n"')

        parseCString = 'warning: File "/home/jv/Private/Projects/SmalltalkX/sources/branches/jv1/build/stx/.gdbinit" auto-loading has been declined by your `auto-load safe-path'' set to "$debugdir:$datadir/auto-load".

'.

    "Created: / 28-05-2014 / 00:05:31 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 03-06-2014 / 00:23:20 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBParserTests methodsFor:'tests - commands'!

test_command_break_list_01

    | parser events |

    parser := GDBParser on:'1^done,BreakpointTable={nr_rows="1",nr_cols="6",hdr=[{width="3",alignment="-1",col_name="number",colhdr="Num"},{width="14",alignment="-1",col_name="type",colhdr="Type"},{width="4",alignment="-1",col_name="disp",colhdr="Disp"},{width="3",alignment="-1",col_name="enabled",colhdr="Enb"},{width="10",alignment="-1",col_name="addr",colhdr="Address"},{width="40",alignment="2",col_name="what",colhdr="What"}],body=[bkpt={number="1",type="breakpoint",disp="keep",enabled="y",addr="0x000100d0",func="main",file="hello.c",fullname="/home/foo/hello.c",line="5",thread-groups=["i1"],times="0",ignore="3"}]}

'.

    parser token2CommandMappingBlock: [ :token | GDBMI_break_list new ].  

    events := parser parseOutput.

    self assert: events size == 1.

    self assert:  (events first result propertyAt: 'BreakpointTable') notNil.

    self assert: ((events first result propertyAt: 'BreakpointTable') at: 'body') notNil.

    "Created: / 20-06-2014 / 09:08:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_command_stack_list_frames_01

    | parser events |

    parser := GDBParser on:'1^done,stack=[frame={level="0",addr="0x00010734",func="callee4",file="../../../devo/gdb/testsuite/gdb.mi/basics.c",fullname="/home/foo/bar/devo/gdb/testsuite/gdb.mi/basics.c",line="8"},frame={level="1",addr="0x0001076c",func="callee3",file="../../../devo/gdb/testsuite/gdb.mi/basics.c",fullname="/home/foo/bar/devo/gdb/testsuite/gdb.mi/basics.c",line="17"},frame={level="2",addr="0x0001078c",func="callee2",file="../../../devo/gdb/testsuite/gdb.mi/basics.c",fullname="/home/foo/bar/devo/gdb/testsuite/gdb.mi/basics.c",line="22"},frame={level="3",addr="0x000107b4",func="callee1",file="../../../devo/gdb/testsuite/gdb.mi/basics.c",fullname="/home/foo/bar/devo/gdb/testsuite/gdb.mi/basics.c",line="27"},frame={level="4",addr="0x000107e0",func="main",file="../../../devo/gdb/testsuite/gdb.mi/basics.c",fullname="/home/foo/bar/devo/gdb/testsuite/gdb.mi/basics.c",line="32"}]

'.

    parser token2CommandMappingBlock: [ :token | GDBMI_stack_list_frames new ].  

    events := parser parseOutput.

    self assert: events size == 1.

    self assert: (events first result propertyAt: 'stack') size == 5.

    "Created: / 19-06-2014 / 22:00:15 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 20-06-2014 / 09:18:20 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBParserTests methodsFor:'tests - examples'!

test_simple_example_01

    | parser events |

    parser := GDBParser on:

'^done,bkpt={number="1",type="breakpoint",disp="keep",enabled="y",addr="0x08048564",func="main",file="myprog.c",fullname="/home/nickrob/myprog.c",line="68",thread-groups=["i1"],times="0"}

(gdb)

'.

    events := parser parseOutput.

    self assert: events size == 1.

    self assert: events first isCommandResultEvent.

    self assert: events first result status == CommandStatusDone.

    self assert: ((events first result propertyAt: 'bkpt') at: 'addr') = '0x08048564'

    "Created: / 30-05-2014 / 23:53:22 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 19-06-2014 / 21:55:08 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_simple_example_02

    | parser events |

    parser := GDBParser on:

'1234*running

1234^done

(gdb)

'.

    events := parser parseOutput.

    self assert: events size == 2.

    self assert: events first token == 1234.

    self assert: events second isCommandResultEvent.

    self assert: events second result status == CommandStatusDone.

    self assert: events second token == 1234

    "Created: / 03-06-2014 / 00:50:55 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 09-06-2014 / 21:25:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_simple_session_01

    | parser events |

    parser := GDBParser on:'~"GNU gdb (GDB) 7.5-ubuntu\n"

~"Copyright (C) 2012 Free Software Foundation, Inc.\n"

~"License GPLv3+: GNU GPL version 3 or later <http://gnu.org/licenses/gpl.html>\nThis is free software: you are free to change and redistribute it.\nThere is NO WARRANTY, to the extent permitted by law.  Type \"show copying\"\nand \"show warranty\" for details.\n"

~"This GDB was configured as \"x86_64-linux-gnu\".\nFor bug reporting instructions, please see:\n"

~"<http://www.gnu.org/software/gdb/bugs/>...\n"

~"Reading symbols from /home/jv/Private/Projects/SmalltalkX/sources/branches/jv1/build/jv/libgdbs/tests/c/factorial..."

~"done.\n"

(gdb) 

'.

    events := parser parseOutput.

    self assert: events size == 7.

    self assert: events first isConsoleOutputEvent.

    self assert: events first value = 'GNU gdb (GDB) 7.5-ubuntu

'.

    self assert: events last isConsoleOutputEvent.

    self assert: events last value = 'done.

'.

    parser := GDBParser on:'^done,bkpt={number="1",type="breakpoint",disp="keep",enabled="y",addr="0x0000000000400556",func="main",file="factorial.c",fullname="/home/jv/Private/Projects/SmalltalkX/sources/branches/jv1/build/jv/libgdbs/tests/c/factorial.c",line="12",times="0",original-location="main"}

(gdb) 

'.

    events := parser parseOutput.

    self assert: events size == 1.

    self assert: events first result status == CommandStatusDone.

    self assert: ((events first result value propertyAt: 'bkpt') at: 'addr') = '0x0000000000400556'.

    parser := GDBParser on:'~"Breakpoint 2 at 0x400527: file factorial.c, line 4.\n"

=breakpoint-created,bkpt={number="2",type="breakpoint",disp="keep",enabled="y",addr="0x0000000000400527",func="factorial",file="factorial.c",fullname="/home/jv/Private/Projects/SmalltalkX/sources/branches/jv1/build/jv/libgdbs/tests/c/factorial.c",line="4",times="0",original-location="factorial"}

^done

(gdb)

'.

    events := parser parseOutput.

    self assert: events size == 3.

    self assert: events first isConsoleOutputEvent.

    self assert: events first value = 'Breakpoint 2 at 0x400527: file factorial.c, line 4.

'.

    self assert: events second isNotificationEvent.

    self assert: events second type = 'breakpoint-created'.

    parser := GDBParser on:'&"info break\n"

~"Num     Type           Disp Enb Address            What\n"

~"1       breakpoint     keep y   0x0000000000400556 in main at factorial.c:12\n"

~"2       breakpoint     keep y   0x0000000000400527 in factorial at factorial.c:4\n"

^done

(gdb)

'.

    events := parser parseOutput.

    self assert: events size == 5.

    self assert: events first isLogOutputEvent.

    self assert: events first value = 'info break

'.

    self assert: events second isConsoleOutputEvent.

    self assert: events third isConsoleOutputEvent.

    self assert: events fourth isConsoleOutputEvent.

    self assert: events fifth isCommandResultEvent.

    parser := GDBParser on:'&"run\n"

~"Starting program: /home/jv/Private/Projects/SmalltalkX/sources/branches/jv1/build/jv/libgdbs/tests/c/factorial \n"

=thread-group-started,id="i1",pid="17240"

=thread-created,id="1",group-id="i1"

^running

*running,thread-id="all"

(gdb)

'.

    events := parser parseOutput.

    self assert: events size == 6.

    self assert: events third isNotificationEvent.

    self assert: events third type = 'thread-group-started'.

    self assert: events fifth isCommandResultEvent.

    self assert: events fifth result status == CommandStatusDone.

    self assert: events sixth isExecutionEvent.

    self assert: events sixth type = 'running'.

    parser := GDBParser on:'=library-loaded,id="/lib64/ld-linux-x86-64.so.2",target-name="/lib64/ld-linux-x86-64.so.2",host-name="/lib64/ld-linux-x86-64.so.2",symbols-loaded="0",thread-group="i1"

=library-loaded,id="/lib/x86_64-linux-gnu/libc.so.6",target-name="/lib/x86_64-linux-gnu/libc.so.6",host-name="/lib/x86_64-linux-gnu/libc.so.6",symbols-loaded="0",thread-group="i1"

=breakpoint-modified,bkpt={number="1",type="breakpoint",disp="keep",enabled="y",addr="0x0000000000400556",func="main",file="factorial.c",fullname="/home/jv/Private/Projects/SmalltalkX/sources/branches/jv1/build/jv/libgdbs/tests/c/factorial.c",line="12",times="1",original-location="main"}

~"\nBreakpoint "

~"1, main (argc=1, argv=0x7fffffffe0a8) at factorial.c:12\n"

~"12\t\tint i = 5;\n"

*stopped,reason="breakpoint-hit",disp="keep",bkptno="1",frame={addr="0x0000000000400556",func="main",args=[{name="argc",value="1"},{name="argv",value="0x7fffffffe0a8"}],file="factorial.c",fullname="/home/jv/Private/Projects/SmalltalkX/sources/branches/jv1/build/jv/libgdbs/tests/c/factorial.c",line="12"},thread-id="1",stopped-threads="all",core="1"

(gdb)

'.

    events := parser parseOutput.

    self assert: events size == 7.

    self assert: (events at:7) isExecutionEvent.

    self assert: (events at:7) type = 'stopped'.

    "Created: / 01-06-2014 / 22:57:16 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 19-06-2014 / 21:55:42 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBParserTests methodsFor:'tests - values'!

test_list_01

    | list |

    list := (GDBParser on: '[]') parseList.

    self assert: list class == Array.

    self assert: list isEmpty.

    "Created: / 18-06-2014 / 07:13:08 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_list_02

    | list |

    list := (GDBParser on: '["i1","i2"]') parseList.

    self assert: list size == 2.

    self assert: list first = 'i1'.

    self assert: list second = 'i2'.

    "Created: / 19-06-2014 / 09:24:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_list_03

    | list |

    list := (GDBParser on: '[["1","2"],"i2"]') parseList.

    self assert: list size == 2.

    self assert: list first size == 2.

    self assert: list first first = '1'.

    self assert: list first second = '2'.

    self assert: list second = 'i2'.

    "Created: / 19-06-2014 / 09:25:44 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_list_04

    | list |

    list := (GDBParser on: '[bkpt={number="1",line="2"},bkpt={number="2",line="10"}]') parseList.

    self assert: list size == 2.

    self assert: list first size == 2.

    self assert: (list first at: 'number') = '1'.

    self assert: (list first at: 'line') = '2'.

    self assert: list second size == 2.

    self assert: (list second at: 'number') = '2'.

    self assert: (list second at: 'line') = '10'.

    "Created: / 19-06-2014 / 09:29:09 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_tuple_01

    | tuple |

    tuple := (GDBParser on: '{}') parseTuple.

    self assert: tuple class == Dictionary.

    self assert: tuple isEmpty.

    "Created: / 14-06-2014 / 02:24:18 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 18-06-2014 / 07:03:58 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_tuple_02a

    | tuple |

    tuple := (GDBParser on: '{p1="XXX"}') parseTuple.

    self assert: tuple class == Dictionary.

    self assert: tuple size == 1.

    self assert: (tuple at: 'p1') = 'XXX'.

    "Created: / 18-06-2014 / 07:12:15 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_tuple_02b

    | tuple |

    tuple := (GDBParser on: '{p1=["i1","i2"]}') parseTuple.

    self assert: tuple class == Dictionary.

    self assert: tuple size == 1.

    self assert: (tuple at: 'p1') asArray = #('i1' 'i2')

    "Created: / 18-06-2014 / 07:09:25 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_tuple_02c

    | tuple |

    tuple := (GDBParser on: '{p1={x="10",y="10"}}') parseTuple.

    self assert: tuple class == Dictionary.

    self assert: tuple size == 1.

    self assert: (tuple at: 'p1') class == Dictionary.

    self assert: ((tuple at: 'p1') at: 'x') = '10'.

    self assert: ((tuple at: 'p1') at: 'y') = '10'.

    "Created: / 18-06-2014 / 07:12:00 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBParserTests methodsFor:'tests - values - typed'!

test_typed_boolean

    self assert:(GDBParser on:'"y"') parseValueAsBoolean == true.

    self assert:(GDBParser on:'"n"') parseValueAsBoolean == false.

    self assert:(GDBParser on:'"no"') parseValueAsBoolean = 'no'.

    self assert:(GDBParser on:'"12xyz"') parseValueAsBoolean = '12xyz'.

    "Created: / 18-06-2014 / 23:38:08 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_typed_integer

    self assert:(GDBParser on:'"123"') parseValueAsInteger == 123.

    self assert:(GDBParser on:'"0"') parseValueAsInteger == 0.

    self assert:(GDBParser on:'"no"') parseValueAsInteger = 'no'.

    self assert:(GDBParser on:'"12xyz"') parseValueAsInteger = '12xyz'.

    "Created: / 19-06-2014 / 09:39:48 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_typed_list_01a

    | object |

    object := (GDBParser on:'["123","456"]') parseValueAsListOf:Integer.

    self assert:object size == 2.

    self assert:object first == 123.

    self assert:object second == 456.

    "Created: / 19-06-2014 / 09:40:55 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_typed_list_02a

    | object |

    object := (GDBParser on:'["123","456"]') parseValueAsListOf:String.

    self assert:object size == 2.

    self assert:object first = '123'.

    self assert:object second = '456'.

    "Created: / 19-06-2014 / 09:41:15 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_typed_object_01a

    | descriptor  object |

    descriptor := GDBObjectValueDescriptor forClass:self class.

    descriptor define:#prop1 as:Integer.

    descriptor define:#prop2 as:Boolean.

    object := (GDBParser on:'{prop1="123",prop2="y"}') 

            parseValueAsInstanceOf:self class

            describedBy:descriptor.

    self assert:object class == self class.

    self assert:object prop1 == 123.

    self assert:object prop2.

    self assert:object properties isEmptyOrNil

    "Created: / 18-06-2014 / 09:01:14 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 18-06-2014 / 23:20:09 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

test_typed_object_01b

    | descriptor  object |

    descriptor := GDBObjectValueDescriptor forClass:self class.

    descriptor define:#prop1 as:Array of: Integer.

    object := (GDBParser on:'{prop1=["123"]}') parseValueAsInstanceOf:self class describedBy:descriptor.

    self assert:object class == self class.

    self assert:object prop1 size == 1.

    self assert:object prop1 first = 123.

    self assert:object properties isEmptyOrNil

    "Created: / 19-06-2014 / 09:42:52 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GDBParserTests class methodsFor:'documentation'!

version_HG

    ^ '$Changeset: <not expanded> $'

! !