"{ Package: 'jv:libllvms' }"

"{ NameSpace: Smalltalk }"

LLVMFunction subclass:#LLVMStXMethod

	instanceVariableNames:''

	classVariableNames:'SelectorSpecialCharMappingTable'

	poolDictionaries:''

	category:'LLVM-StX'

!

!LLVMStXMethod class methodsFor:'initialization'!

initialize

    "Invoked at system start or when the class is dynamically loaded."

    "/ please change as required (and remove this comment)

    SelectorSpecialCharMappingTable := Dictionary withKeysAndValues:

                #($+ 'pl'

                  $- 'mi'

                  $* 'mu'

                  $/ 'di'

                  $, 'co'

                  $@ 'at'

                  $< 'le'

                  $> 'gr'

                  $= 'eq'

                  $~ 'ne'

                  $| 'pi'

                  $\ 'mo'

                  $& 'am').

    "Modified: / 11-07-2015 / 09:24:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!LLVMStXMethod class methodsFor:'utilities'!

llvmFunctionNameForClass: class selector: selector      

    "For given class name and selector, returns the name 

     used by LLVM"

    ^ String streamContents:[ :s|

        s nextPutAll: '__M_L_'.

        s nextPutAll: (class name copyReplaceAll: $: with: $_).

        s nextPut: $_.

        selector isBinarySelector ifTrue:[ 

            selector do:[:c |     

                s nextPutAll: (SelectorSpecialCharMappingTable at: c)

            ].

        ] ifFalse:[ 

            selector do:[:c |  

                c isAlphaNumeric ifTrue:[ 

                    s nextPut: c 

                ] ifFalse:[

                    c == $: ifTrue:[ 

                        s nextPut: $_

                    ] ifFalse:[  

                        s nextPut: $_.

                        c codePoint printOn: s.

                    ]

                ].

            ]

        ].

    ].

    "

    LLVMStXMethod llvmFunctionNameForClass: LLVMStXMethod selector: #llvmFunctionNameForClass:selector: 

    LLVMStXMethod llvmFunctionNameForClass: SmallInteger selector: #+

    LLVMStXMethod llvmFunctionNameForClass: Object selector: #~=

    "

    "Created: / 11-07-2015 / 09:26:48 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!LLVMStXMethod methodsFor:'accessing'!

numArgs

    ^ super numArgs - 4

    "Created: / 11-07-2015 / 09:42:30 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parameterAt: index

    ^ super parameterAt: 4 + index.

    "Created: / 11-07-2015 / 09:39:33 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!LLVMStXMethod methodsFor:'initialization'!

initialize

    super initialize.

    "Assign human readable names to parameters"

    (super parameterAt: 1) name: 'self'.

    (super parameterAt: 2) name: 'selector'.

    (super parameterAt: 3) name: 'searchClass'.

    (super parameterAt: 4) name: 'pIlc'.

    1 to: self numArgs do:[:numArg | 

        (super parameterAt: 4+numArg) name: 'marg', numArg printString.

    ].

    "Created: / 11-07-2015 / 09:41:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

LLVMStXMethod initialize!