"{ Package: 'jv:vdb/application' }"

"{ NameSpace: Smalltalk }"

StandaloneStartup subclass:#VDBStartup

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	category:'VDB-UI'

!

!VDBStartup class methodsFor:'constants & defaults'!

applicationRegistryPath

    "the key under which this application stores its process ID in the registry

     as a collection of path-components.

     i.e. if #('foo' 'bar' 'baz') is returned here, the current applications ID will be stored

     in HKEY_CURRENT_USER\Software\foo\bar\baz\CurrentID.

     (would also be used as a relative path for a temporary lock file under unix).

     Used to detect if another instance of this application is already running."

    ^ #('vdb')

    "Modified: / 21-09-2014 / 01:29:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

applicationUUID

    "answer an application-specific unique uuid.

     This is used as the name of some exclusive OS-resource, which is used to find out,

     if another instance of this application is already running.

     Under win32, a mutex is used; under unix, an exclusive file in the tempDir could be used.

     If redefined, please return a real UUID (i.e. UUID fromString:'.....') and not a string or

     similar possibly conflicting identifier.

     You can paste a fresh worldwide unique id via the editor's more-misc-paste UUID menuFunction."

    ^ UUID fromString:'57b09330-4126-11e4-a80f-606720e43e2c'

    "Modified: / 21-09-2014 / 01:29:30 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!VDBStartup class methodsFor:'defaults'!

allowDebugOption

    "enable/disable the --debug startup option.

     Can be redefined in subclasses to enable it"

    ^ true

    "Created: / 08-09-2014 / 19:30:40 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!VDBStartup class methodsFor:'private'!

loadPreferenceFile: file

    "Created: / 07-06-2017 / 09:49:58 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!VDBStartup class methodsFor:'queries'!

applicationName

    ^ 'vdb'

    "Created: / 06-06-2017 / 22:50:44 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!VDBStartup class methodsFor:'startup'!

main:argv

    "Application entry point. `argv` is the array of command arguments (as Array of Strings)"

    | optparser positional settingsFile settingsSuppressed programExecutable programArgs programPid attach debugger |

    settingsSuppressed := false.

    attach := false.

    "/ Parse options...

    optparser := CmdLineParser new

                    ignoreUnknownOptions: true;

                    on: #('--help') do:[

                        self usage

                    ];

                    on: #('--preferences') do:[:filename |

                        | file |

                        file := filename asFilename.

                        file isReadable ifFalse:[

                            self error: 'preference file does not exists or not readable: ' , filename.

                        ].

                        file isRegularFile ifFalse:[

                            self error: 'preference file is not a regular file: ' , filename.

                        ].

                        settingsFile := file.

                    ];

                    on: #('--no-preferences') do:[

                        settingsSuppressed := true

                    ];

                    yourself.

    [

        positional := optparser parse:argv.

    ] on: CmdLineOptionError do:[:ex |

        self error: ex description.

    ].

    "/ Now validate and process options

    settingsSuppressed ifFalse:[

        | settings |

        settingsFile notNil ifTrue:[

            settingsFile exists ifFalse:[

                self error: 'preference file does not exist: ', settingsFile pathName

            ].

            settingsFile isDirectory ifTrue:[

                self error: 'preference file is not a regular file: ', settingsFile pathName

            ].

            settingsFile isReadable ifFalse:[

                self error: 'preference file is not a readable (check permissions): ', settingsFile pathName

            ].

            settings := UserPreferences loadSettingsFrom: settingsFile.

        ] ifFalse:[

            settings := UserPreferences loadSettings.

        ].

        UserPreferences setCurrent: settings.

    ].

    "/ Parse positional arguments - there are two forms:

    "/

    "/   vdb [OPTIONS] [PROGRAM [ARGS]]

    "/   vdb [OPTIONS] [PID]

    "/

    "/ [OPTIONS] have already been processed, the rest is in `positional`

    "/ variable

    positional notEmpty ifTrue:[

        programExecutable := positional first.

        programExecutable asFilename exists ifFalse:[

            programExecutable := OperatingSystem pathOfCommand: programExecutable.

        ].

        programPid := Integer fromString: positional first onError: [ nil ].

        programArgs := positional copyFrom: 2.

        "/ If * programExecutable does not exists

        "/    * AND programPid is not nil (i.e., first positional argument can be converted to an integer)

        "/    * AND programArguments are empty

        "/ then interpret positional argument as PID and attach to it.

        "/ Otherwise, interpret positional arguments

        (programExecutable asFilename exists not and: [ programPid notNil and: [ programArgs isEmpty ]]) ifTrue:[

            attach := true.

        ] ifFalse:[

            programExecutable asFilename exists ifFalse:[

                self error: 'cannot find program executable: ', programExecutable.

            ].

        ].

    ].

    Debugger := DebugView ? MiniDebugger.

    Inspector := InspectorView ? MiniInspector.

    debugger := GDBDebugger new.

    attach ifTrue:[

        debugger attach: programPid

    ] ifFalse:[

        programExecutable notNil ifTrue:[

            debugger executable: programExecutable arguments: programArgs.

        ].

    ].

    Smalltalk openDisplay.

    VDBDebuggerApplication openFor: debugger.

    "

        VDBStartup main: #()

        VDBStartup main: #('ls')

        VDBStartup main: #('/bin/ls' '/tmp')

    "

    "Modified: / 13-09-2017 / 12:54:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

usage

    Stdout nextPutAll:'usage: '; nextPutAll: self applicationName; nextPutAll: ' [OPTIONS] [PROGRAM [ARGS][ '; cr.

    Stdout nextPutAll:'       '; nextPutAll: self applicationName; nextPutAll: ' [OPTIONS] [PID]'; cr.

                                                                          "|"

    Stdout nextPutLine:'

options:

 --preference FILE ............ read user settings from FILE

 --no-preferences ............. do not read user settings at all

 --help ....................... output this message

'.

    Smalltalk exitIfStandalone: 0.

    "Modified: / 13-09-2017 / 22:12:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!VDBStartup class methodsFor:'documentation'!

version_HG

    ^ '$Changeset: <not expanded> $'

! !