"{ Package: 'stx:goodies/cypress' }"

CypressStructure subclass:#CypressClassStructure

	instanceVariableNames:'instanceMethods classMethods comment isClassExtension'

	classVariableNames:''

	poolDictionaries:''

	category:'Cypress-Structure'

!

CypressClassStructure comment:'Main comment stating the purpose of this class and relevant relationship to other classes.

Possible useful expressions for doIt or printIt.

Structure:
 instVar1		type -- comment about the purpose of instVar1
 instVar2		type -- comment about the purpose of instVar2

Any further useful comments about the general approach of this implementation.'

!

!CypressClassStructure class methodsFor:'instance creation'!

fromClassDefinition: classDefinition

	^self new

		fromClassDefinition: classDefinition;

		yourself

! !

!CypressClassStructure methodsFor:'accessing'!

category

	^self packageStructure packageName

!

classInstanceVariableNames

	^self properties at: 'classinstvars' ifAbsent: ['']

!

classInstanceVariableNames: aString

	^self properties at: 'classinstvars' put: aString

!

classMethods

	classMethods ifNil: [ classMethods := Dictionary new ].

	^classMethods

!

className

	^self name

!

comment

	comment ifNil: [ comment := '' ].

	^comment

!

comment: aString

	comment := aString

!

instanceMethods

	instanceMethods ifNil: [ instanceMethods := Dictionary new ].

	^instanceMethods

!

instanceVariableNames

	^self properties at: 'instvars' ifAbsent: ['']

!

instanceVariableNames: aString

	^self properties at: 'instvars' put: aString

!

isClassExtension

        isClassExtension ifNil: [ isClassExtension := true ].

        ^isClassExtension

!

isClassExtension: aBoolean

	isClassExtension := aBoolean

!

name

	^self properties at: 'name'

!

name: aString

	self properties at: 'name' put: aString

!

properties: classPropertiesDict

	properties _ classPropertiesDict

!

superclassName

	^self properties at: 'super'

!

superclassName: aString

	^self properties at: 'super' put: aString

! !

!CypressClassStructure methodsFor:'converting'!

asCypressClassDefinition

	self isClassExtension ifTrue: [ ^nil ].

	^CypressClassDefinition

		name: self className

		superclassName: self superclassName

		category: self category 

		instVarNames: self instanceVariableNames

		classInstVarNames: self classInstanceVariableNames

		comment: self comment

!

changesOn:aStream

    | def |

    isClassExtension ifFalse:[

        def := ClassDefinitionChange new.

        def superClassName: (properties at: #super).

        def className: (properties at: #name).

        def instanceVariableNames: (String streamContents:[:s|((properties at: #instvars ifAbsent:[#()])) do:[:i|s nextPutAll:i; space]]).

        def classInstanceVariableNames: (String streamContents:[:s|((properties at: #classinstvars ifAbsent:[#()]) ) do:[:i|s nextPutAll:i; space]]).

        def classVariableNames: (String streamContents:[:s|((properties at: #classvars ifAbsent:[#()] ) ) do:[:i|s nextPutAll:i; space]]).

        aStream nextPut: def.

    ].

    instanceMethods ? #() do:[:each|each changesOn: aStream].

    classMethods ? #()  do:[:each|each changesOn: aStream].

! !

!CypressClassStructure methodsFor:'initialization'!

fromClassDefinition: classDefinition

	self isClassExtension: false.

	self name: classDefinition name.

	self comment: classDefinition comment.

  	self superclassName: classDefinition superclassName.

	self instanceVariableNames: classDefinition instVarNames.

	self classInstanceVariableNames: classDefinition classInstVarNames.

!

fromJs: jsObject

	properties := jsObject at: 'properties.json'.

	(jsObject at: 'class' ifAbsent: [#()]) do: [:jsMethodObject |  | methodNameParts |

		methodNameParts := self splitMethodNameFor: jsMethodObject.

		(self classMethodNamed: (methodNameParts at: 1)) 

			packageStructure: self packageStructure;

			classStructure: self;

			isMetaclass: true;

			fromJs: jsMethodObject named: methodNameParts ].

	(jsObject at: 'instance' ifAbsent: [#()]) do: [:jsMethodObject |  | methodNameParts |

		methodNameParts := self splitMethodNameFor: jsMethodObject.

		(self instanceMethodNamed: (methodNameParts at: 1)) 

			packageStructure: self packageStructure;

			classStructure: self;

			fromJs: jsMethodObject named: methodNameParts ].	

	comment := jsObject at: 'README.md' ifAbsent: ['']

! !

!CypressClassStructure methodsFor:'private'!

splitMethodName: methodName

	| ext  |

	ext := '.json'.

	(   '*' , ext match: methodName)

		ifFalse: [

			ext := '.st'.

			('*' , ext match: methodName)

				ifFalse: [ self error: 'invalid structure element: ', methodName ] ].

	^{methodName copyFrom: 1 to: (methodName size - ext size). ext}

!

splitMethodNameFor: jsMethodObject

	^self splitMethodName: (jsMethodObject at: 'name')

! !

!CypressClassStructure methodsFor:'querying'!

classMethodNamed: methodName

	^self classMethods 

		at: methodName 

		ifAbsent: [ self classMethods at: methodName put: (CypressMethodStructure new name: methodName) ]

!

instanceMethodNamed: methodName

	^self instanceMethods 

		at: methodName 

		ifAbsent: [ self instanceMethods at: methodName put: (CypressMethodStructure new name: methodName) ]

! !

!CypressClassStructure methodsFor:'writing'!

writeJsonOn: aStream  indent: startIndent

        | indent methods |

        indent := startIndent.

        aStream 

                tab: indent;

                nextPutAll: '{';

                cr.

        indent := indent + 1.

        aStream

                tab: indent;

                nextPutAll: '"name"';

                nextPutAll: ' : ';

                nextPutAll: '"', self name, (self isClassExtension ifTrue: [ '.extension' ] ifFalse: [ '.class' ]), '",';

                cr.

        aStream

                tab: indent;

                nextPutAll: '"instance" : [';

                cr;

                yourself.

        methods := self instanceMethods values asArray asSortedCollection: [:a :b | a selector <= b selector].

        1 to: methods size do: [:index | | methodStructure | 

                methodStructure := methods at: index.

                methodStructure writeJsonOn: aStream indent: indent + 1.

                index < methods size ifTrue: [ aStream nextPutAll: ','; cr ]].

        aStream

                tab: indent;

                nextPutAll: '],';

                cr;

                yourself.

        aStream

                tab: indent;

                nextPutAll: '"class" : [';

                cr;

                yourself.

        methods := self classMethods values asArray asSortedCollection: [:a :b | a selector <= b selector].

        1 to: methods size do: [:index | | methodStructure | 

                methodStructure := methods at: index.

                methodStructure writeJsonOn: aStream indent: indent + 1.

                index < methods size ifTrue: [ aStream nextPutAll: ','; cr ]].

        aStream

                tab: indent;

                nextPutAll: ']'.

        self isClassExtension

                ifFalse: [ 

                        aStream

                                nextPutAll: ',';

                                cr;

                                tab: indent;

                                nextPutAll: '"README.md" : ';

                                yourself.

                        self comment writeCypressJsonOn: aStream forHtml: true indent: indent ].

        aStream

                nextPutAll: ',';

                cr;

                tab: indent;

                nextPutAll: '"properties.json" : ';

                yourself.

        self properties writeCypressJsonOn: aStream forHtml: true indent: indent.

        indent := indent - 1.

        aStream

                cr;

                tab: indent;

                nextPutAll: ' }'

    "Modified: / 30-08-2012 / 14:50:41 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!CypressClassStructure class methodsFor:'documentation'!

version_SVN

    ^ '$Id::                                                                                                                        $'

! !