"{ Package: 'stx:goodies/cypress' }"

CypressStructure subclass:#CypressPackageStructure

	instanceVariableNames:'classes extensions'

	classVariableNames:''

	poolDictionaries:''

	category:'Cypress-Structure'

!

CypressPackageStructure comment:'Main comment stating the purpose of this class and relevant relationship to other classes.

Possible useful expressions for doIt or printIt.

Structure:
 instVar1		type -- comment about the purpose of instVar1
 instVar2		type -- comment about the purpose of instVar2

Any further useful comments about the general approach of this implementation.'

!

!CypressPackageStructure class methodsFor:'instance creation'!

fromJson: aJsonString

	^self fromJs: (CypressJsonParser parse: aJsonString)

!

fromPackage: aCypressPackageDefinition

	^(self new) 

		fromPackage: aCypressPackageDefinition;

		yourself

! !

!CypressPackageStructure methodsFor:'accessing'!

classes

	classes ifNil: [ classes := OrderedCollection new ].

	^classes

!

extensions

	extensions ifNil: [ extensions := OrderedCollection new ].

	^extensions

!

packageExtension

	^self properties at: 'extension' ifAbsent: ['.package' ]

!

packageName

	^self name copyFrom: 1 to: (self name size - self packageExtension size)

!

packageStructure

	^self

! !

!CypressPackageStructure methodsFor:'converting'!

changesOn:aStream

    "superclass CypressStructure says that I am responsible to implement this method"

    classes ? #() do:[:cls | cls changesOn: aStream ].

    extensions ? #() do:[:ext | ext changesOn: aStream ].

    "Modified: / 03-09-2012 / 10:57:42 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!CypressPackageStructure methodsFor:'initialization'!

fromJs: jsObject

	name := jsObject at: 'name'.

	(jsObject at: 'contents') do: [:jsClassObject| | classStructure objectName |

		classStructure := (CypressClassStructure new)

                		packageStructure: self;

				yourself.

                (  '*.extension' match:(objectName := jsClassObject at: 'name') )

			ifTrue: [ 

				classStructure isClassExtension: true.

				self extensions add: classStructure ]

			ifFalse: [

				( '*.class' match: objectName)

					ifTrue: [ 

						classStructure isClassExtension: false.

						self classes add: classStructure ]].

		classStructure fromJs: jsClassObject].

	properties := jsObject at: 'properties.json'

!

fromPackage: aCypressPackageDefinition

        | snapshot classMap classDefinitions classStructure |

        snapshot := aCypressPackageDefinition snapshot.

        name := (aCypressPackageDefinition name copy

                    replaceAll: $: with:$_;

                    replaceAll: $/ with:$_;

                    yourself)

                    , '.package'.

        properties := Dictionary new.

        properties at: '_stx_name' put: aCypressPackageDefinition name.

        classDefinitions := Set new.

        classMap := Dictionary new.

        snapshot definitions do: [:definition |  

                        definition 

                                classDefinition: [:classDefinition |  classDefinitions add: classDefinition ] 

                                methodDefinition: [:methodDefinition | 

                                        (classMap 

                                                at: methodDefinition className 

                                                ifAbsent: [classMap at: methodDefinition className put: Set new]) 

                                                        add: methodDefinition. ]].

        classDefinitions do: [:classDefinition |

                classStructure := (CypressClassStructure fromClassDefinition: classDefinition)

                        packageStructure: self.

                (classMap removeKey: classDefinition className ifAbsent: [#()]) do: [:methodDefinition | | methodStructure |

                        methodStructure := (CypressMethodStructure fromMethodDefinition: methodDefinition)

                                packageStructure: self;

                                classStructure: classStructure.

                        (methodDefinition

                                instanceMethod: [:instanceMethod | classStructure instanceMethods ] 

                                classMethod: [:classMethod | classStructure classMethods ])

                                        at: methodDefinition selector

                                        put: methodStructure ].

                self classes add: classStructure ].

        classMap keysAndValuesDo: [:className :methods |

                classStructure := (CypressClassStructure new name: className)

                        packageStructure: self.

                methods do: [:methodDefinition | | methodStructure |

                        methodStructure := (CypressMethodStructure fromMethodDefinition: methodDefinition)

                                packageStructure: self;

                                classStructure: classStructure.

                        (methodDefinition

                                instanceMethod: [:instanceMethod | classStructure instanceMethods ] 

                                classMethod: [:classMethod | classStructure classMethods ])

                                        at: methodDefinition selector

                                        put: methodStructure ].

                self extensions add: classStructure ].

    "Modified: / 31-08-2012 / 19:56:41 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!CypressPackageStructure methodsFor:'snapshotting'!

snapshot

        | definitions |

        definitions := OrderedCollection new.

        self classes do: [:classStructure |

                definitions add: classStructure asCypressClassDefinition.

                (classStructure instanceMethods values asArray asSortedCollection: [:a :b | a selector <= b selector]) do: [:methodStructure |

                        definitions add: methodStructure asCypressMethodDefinition ].

                (classStructure classMethods values asArray asSortedCollection: [:a :b | a selector <= b selector]) do: [:methodStructure |

                        definitions add: methodStructure asCypressMethodDefinition ]].

        self extensions do: [:classStructure |

                (classStructure instanceMethods values asArray asSortedCollection: [:a :b | a selector <= b selector]) do: [:methodStructure |

                        definitions add: methodStructure asCypressMethodDefinition ].

                (classStructure classMethods values asArray asSortedCollection: [:a :b | a selector <= b selector]) do: [:methodStructure |

                        definitions add: methodStructure asCypressMethodDefinition ]].

        ^ CypressSnapshot definitions: definitions

    "Modified: / 30-08-2012 / 13:31:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!CypressPackageStructure methodsFor:'writing'!

writeJsonOn: aStream  indent: startIndent

        | indent |

        indent := startIndent.

        aStream 

                tab: indent;

                nextPutAll: '{';

                cr.

        indent := indent + 1.

        aStream

                tab: indent;

                nextPutAll: '"name"';

                nextPutAll: ' : ';

                nextPutAll: '"', self name, '",'.

        aStream

                cr;

                tab: indent;

                nextPutAll: '"contents" : [';

                cr;

                yourself.

        1 to: self classes size do: [:index | | classStructure | 

                classStructure := self classes at: index.

                classStructure writeJsonOn: aStream indent: indent + 1.

                (self extensions size > 0 or: [ index < self classes size]) ifTrue: [ aStream nextPutAll: ','; newLine. ]].

        1 to: self extensions size do: [:index | | classStructure | 

                classStructure := self extensions at: index.

                classStructure writeJsonOn: aStream indent: indent + 1.

                index < self extensions size ifTrue: [ aStream nextPutAll: ','; newLine.] ].

        aStream

                cr;

                tab: indent;

                nextPutAll: '],';

                cr;

                tab: indent;

                nextPutAll: '"properties.json" : '.

        self properties writeCypressJsonOn: aStream forHtml: true indent: indent.

        indent := indent - 1.

        aStream 

                cr;

                tab: indent;

                nextPutAll: '}'

    "Modified: / 30-08-2012 / 14:49:49 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!CypressPackageStructure class methodsFor:'documentation'!

version_SVN

    ^ '$Id::                                                                                                                        $'

! !