"{ Package: 'stx:goodies/libcairo' }"

"{ NameSpace: Smalltalk }"

DeviceHandle subclass:#CairoGraphicsContextHandle

	instanceVariableNames:'parentId drawableType cr'

	classVariableNames:''

	poolDictionaries:''

	category:'Cairo-Compatibility'

!

!CairoGraphicsContextHandle class methodsFor:'documentation'!

documentation

"

    Strictly internal!! Instances of CairoGraphicsContextHandle are used as

    executors for CairoGraphicsContext - do not use!!

    [author:]

        Jan Vrany <jan.vrany@fit.cvut.cz>

    [instance variables:]

    [class variables:]

    [see also:]

"

! !

!CairoGraphicsContextHandle methodsFor:'accessing'!

parentId

    ^ parentId

! !

!CairoGraphicsContextHandle methodsFor:'finalization'!

finalize

    "Called the view or pixmap for which I am a handle was collected - release system resources"

    drawableId notNil ifTrue:[

        Logger debug: 'Finalizing drawable %1#%2' with: drawableId with: drawableId identityHash.

        cr notNil ifTrue:[

            | surfaceToDestroy crToDestroy |

            crToDestroy := cr.

            surfaceToDestroy := cr surface.

            cr := nil.

            crToDestroy release.

            surfaceToDestroy release.    

        ].

        drawableType == #window ifTrue:[ 

            [

                (device viewIdKnown:drawableId) ifTrue:[

    "/ 'Display [info]: recycled view (' infoPrint. v infoPrint. ') not destroyed: ' infoPrint.

    "/ drawableId displayString infoPrintCR.

                    drawableId := nil.

                ] ifFalse:[

                    |id|

                    (id := gcId) notNil ifTrue:[

                        gcId := nil.

                        device deviceIOErrorSignal handle:[:ex |

                        ] do:[

                            device destroyGC:id.

                        ]

                    ].

                    id := drawableId.

                    drawableId := nil.

                    device deviceIOErrorSignal handle:[:ex |

                    ] do:[

                        device destroyView:nil withId:id.

                    ].

                    "When a window ist destroyed, all its subwindows are also destroyed.

                     Unregister all the subwindows, to avoid destroying of reused windoeIds

                     later."

                    DeviceGraphicsContext cleanupLobbyForChildrenOfViewWithDevice:device id:id.

                ]

            ] valueUninterruptably.

        ] ifFalse:[ 

            | id |

            (id := gcId) notNil ifTrue:[

                gcId := nil.

                device destroyGC:id.

            ].

            id := drawableId.

            drawableId := nil.

            device destroyPixmap:id.    

        ].

    ].

    "Created: / 03-03-2016 / 23:21:19 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!CairoGraphicsContextHandle methodsFor:'private-accessing'!

setDevice:aDevice id:aDrawableId gcId:aGCId

    self shouldNeverBeSent

    "Created: / 03-03-2016 / 23:19:47 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

setDevice:deviceArg id:drawableIdArg gcId:gcIdArg parentId: parentIdArg type: drawableTypeArg cr: crArg

    device := deviceArg.

    drawableId := drawableIdArg.

    gcId := gcIdArg.

    parentId :=  parentIdArg.

    drawableType := drawableTypeArg.

    cr := crArg.

    "Created: / 04-03-2016 / 00:08:37 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !