"{ Package: 'stx:goodies/metacello' }"

Object subclass:#ConfigurationOf

	instanceVariableNames:'project'

	classVariableNames:''

	poolDictionaries:''

	category:'Metacello-Base'

!

!ConfigurationOf class methodsFor:'accessing'!

project

	^self new project

!

validate

	"Check the configuration for Errors, Critical Warnings, and Warnings (see class comment for MetacelloMCVersionValidator for more information). 

	Errors identify specification issues that will result in unexpected behaviour when you load the configuration. 

	Critical Warnings identify specification issues that may result in unexpected behavior when you load the configuration.

	Warnings identify specification issues that are technically correct, but are worth take a look at."

	"self validate"

	<apiDocumentation>

	self ensureMetacello.

	^ ((Smalltalk at: #MetacelloToolBox) validateConfiguration: self debug: #() recurse: false) explore

! !

!ConfigurationOf class methodsFor:'private'!

bootstrapMetacelloFrom: repositoryUrl

    "Corresponds to version 1.0-beta.32.2"

    "KEEP MetacelloConfigTemplate class>>ensureMetacelloBaseConfiguration in synch!!"

    | platformPkg |

    self ensureGoferVersion: 'Gofer-Core-lr.115' repositoryUrl: repositoryUrl.

    #('Metacello-Base-dkh.96' 'Metacello-Core-dkh.664' 'Metacello-MC-dkh.656')

        do: [ :pkg | self bootstrapPackage: pkg from: repositoryUrl ].

    platformPkg := Smalltalk

        at: #'SystemVersion'

        ifPresent: [ :cl | 

            | versionString |

            versionString := cl current version.

            (versionString beginsWith: 'Squeak')

                ifTrue: [ 

                    (versionString beginsWith: 'Squeak3')

                        ifTrue: [ 'Metacello-Platform.squeak-dkh.5' ]

                        ifFalse: [ 'Metacello-Platform.squeak-dkh.13' ] ]

                ifFalse: [ 

                    (versionString beginsWith: 'Pharo')

                        ifTrue: [ 'Metacello-Platform.pharo-dkh.27' ] ] ].

    self bootstrapPackage: platformPkg from: repositoryUrl

!

bootstrapPackage: aString from: aPath 

	| repository version |

	repository := (MCCacheRepository default includesVersionNamed: aString)

		ifTrue: [MCCacheRepository default]

		ifFalse: [MCHttpRepository

				location: aPath

				user: ''

				password: ''].

	repository

		versionReaderForFileNamed: aString , '.mcz'

		do: [:reader | 

			version := reader version.

			version load.

			version workingCopy repositoryGroup addRepository: repository]

!

ensureGoferVersion: goferVersion repositoryUrl: repositoryUrl

    "load the p=file goferVersion if Gofer isn't loaded or an earlier version of Gofer is currently loaded"

    | goferVersionNumber wc pName |

    (Smalltalk at: #'Gofer' ifAbsent: [  ]) == nil

        ifTrue: [ ^ self bootstrapPackage: goferVersion from: repositoryUrl ].

    goferVersionNumber := (goferVersion copyAfterLast: $.) asNumber.

    wc := [ ((Smalltalk at: #'GoferPackageReference') name: 'Gofer') workingCopy ]

        on: Error

        do: [ :ex | ex return: ((Smalltalk at: #'GoferPackageReference') name: 'Gofer-Core') workingCopy ].

    pName := wc ancestry ancestors first name.

    (pName copyAfterLast: $.) asNumber <= goferVersionNumber

        ifTrue: [ self bootstrapPackage: goferVersion from: repositoryUrl ]

!

ensureMetacello

    "Bootstrap Metacello and load the 'botstrap' group"

    self ensureMetacello: #('batch')

!

ensureMetacello: loadList

    "Bootstrap Metacello, retry using alternate repository, if primary repository is not accessible"

    Smalltalk

        at: #'MetacelloProject'

        ifAbsent: [ 

            | retry version error gofer |

            retry := false.

            (Array with: 'http://seaside.gemstone.com/ss/metacello' with: 'http://www.squeaksource.com/metacello')

                do: [ :repositoryUrl | 

                    [ 

                    "bootstrap Metacello"

                    self bootstrapMetacelloFrom: repositoryUrl.

                    Smalltalk

                        at: #'ConfigurationOfMetacello'

                        ifAbsent: [ 

                            gofer := (Smalltalk at: #'Gofer') new.

                            gofer

                                perform: #'url:' with: repositoryUrl;

                                perform: #'package:' with: 'ConfigurationOfMetacello';

                                perform: #'load' ].

                    version := (Smalltalk at: #'ConfigurationOfMetacello') project version: '1.0-beta.32'.	"bootstrap with 1.0-beta.32"

                    retry

                        ifTrue: [ 

                            "on retry, use #repositoryOverrides:"

                            version

                                repositoryOverrides:

                                    (Array with: (MCHttpRepository location: repositoryUrl user: '' password: '')) ].

                    version load: loadList.

                    gofer := (Smalltalk at: #'Gofer') new.

                    Smalltalk

                        at: #'ConfigurationOfMetacelloPreview'

                        ifAbsent: [ 

                            gofer

                                perform: #'url:' with: repositoryUrl;

                                perform: #'package:' with: 'ConfigurationOfMetacelloPreview';

                                perform: #'load' ].

                    version := (Smalltalk at: #'ConfigurationOfMetacelloPreview') project version: '1.0.0-beta.32.2'.	"load latest from GitHub"

                    version load: loadList.

                    ^ self ]

                        on: Error

                        do: [ :ex | 

                            error := ex.

                            Transcript

                                cr;

                                show: 'failed ensureMetacello: ';

                                show: ex description printString;

                                show: '...retrying'.	"try again"

                            retry := true.

                            ex return: nil ] ].	"shouldn't get here unless the load failed ... throw an error"

            self error: 'retry with alternate repository failed: ' , error description printString ]

! !

!ConfigurationOf class methodsFor:'unloading Metacello'!

unloadMetacello

	"Unload the classes that implement Metacello. Metacello is not needed once a project has been loaded, so it can safely be unloaded."

	"self unloadMetacello"

	<apiDocumentation>

	| gofer |

	gofer := (Smalltalk at: #Gofer) new.

	MCWorkingCopy allManagers do: [:wc |

		((wc packageName beginsWith: 'Metacello') or: [ wc packageName beginsWith: 'OB-Metacello' ])

			ifTrue: [ gofer package: wc packageName ]].

	gofer unload.

! !

!ConfigurationOf methodsFor:'accessing'!

customProjectAttributes

    "Edit to return a collection of any custom attributes e.g. for conditional loading: Array with: #'Condition1' with: #'Condition2.

	For more information see: http://code.google.com/p/metacello/wiki/CustomProjectAttrributes "

    ^ #()

!

project

    ^ project

        ifNil: [ 

            "Bootstrap Metacello if it is not already loaded"

            self class ensureMetacello.

            project := self projectClass new projectAttributes: self customProjectAttributes.	"Create the Metacello project"

            project versionNumberClass: self versionNumberClass.

            project class versionConstructorClass on: self project: project.	"Construct the project"

            project loadType: #'linear'.	"change to #atomic if desired"

            project ]

!

project: aProject

	project ifNil: [ self class ensureMetacello ].

	project := aProject

!

projectClass

    ^ MetacelloMCProject

!

versionNumberClass

    ^ MetacelloSemanticVersionNumber

! !

!ConfigurationOf methodsFor:'defaults'!

bleedingEdge 

	"override if different behavior desired.

	 Use:

		self versionDoesNotExistError: #bleedingEdge

	 if #bleedingEdge version is disallowed."

	<defaultSymbolicVersion: #bleedingEdge>

	^self defaultBleedingEdgeVersion

!

defaultBleedingEdgeVersion

	| bleedingEdgeVersion |

	bleedingEdgeVersion := (self project map values select: [ :version | version blessing == #baseline ])

		detectMax: [ :version | version ].

	bleedingEdgeVersion ifNil: [ ^#'notDefined' ].

	^ bleedingEdgeVersion versionString

! !

!ConfigurationOf methodsFor:'private'!

versionDoesNotExistError: versionStringOrSymbol

	((Smalltalk at: #MetacelloSymbolicVersionDoesNotExistError) project: self project versionString: versionStringOrSymbol) signal

! !

!ConfigurationOf class methodsFor:'documentation'!

version_SVN

    ^ '$Id::                                                                                                                        $'

! !