"{ Package: 'stx:goodies/monticello' }"

MCRepository subclass:#MCFileBasedRepository

	instanceVariableNames:'cache allFileNames'

	classVariableNames:''

	poolDictionaries:''

	category:'Monticello-Repositories'

!

!MCFileBasedRepository class methodsFor:'as yet unclassified'!

flushAllCaches

	self allSubInstancesDo: [:ea | ea flushCache]

! !

!MCFileBasedRepository methodsFor:'as yet unclassified'!

allFileNames

	self subclassResponsibility

!

allFileNamesForVersionNamed: aString

	^ self filterFileNames: self readableFileNames forVersionNamed: aString

!

allFileNamesOrCache

	^ allFileNames ifNil: [self allFileNames]

!

allVersionNames

	^ self readableFileNames collect: [:ea | self versionNameFromFileName: ea]

!

basicStoreVersion: aVersion

	self

		writeStreamForFileNamed: aVersion fileName

		do: [:s | aVersion fileOutOn: s].

	aVersion isCacheable ifTrue: [

		cache ifNil: [cache _ Dictionary new].

		cache at: aVersion fileName put: aVersion].

!

cache

	^ cache ifNil: [cache _ Dictionary new]

!

cacheAllFileNamesDuring: aBlock

	allFileNames _ self allFileNames.

	^ aBlock ensure: [allFileNames _ nil]

!

cachedFileNames

	^cache == nil

		ifTrue: [#()]

		ifFalse: [cache keys]

!

canReadFileNamed: aString

	| reader |

	reader _ MCVersionReader readerClassForFileNamed: aString.

	^ reader notNil

!

closestAncestorVersionFor: anAncestry ifNone: errorBlock

	^ self cacheAllFileNamesDuring:

		[super closestAncestorVersionFor: anAncestry ifNone: errorBlock]

!

filterFileNames: aCollection forVersionNamed: aString

	^ aCollection select: [:ea | (self versionNameFromFileName: ea) = aString] 

!

flushCache

	cache _ nil

!

includesVersionNamed: aString

	^ self allVersionNames includes: aString

!

loadVersionFromFileNamed: aString

	^ self versionReaderForFileNamed: aString do: [:r | r version]

!

loadVersionInfoFromFileNamed: aString

	^ self versionReaderForFileNamed: aString do: [:r | r info]

!

maxCacheSize

	^ 8

!

morphicOpen: aWorkingCopy

	(MCFileRepositoryInspector repository: self workingCopy: aWorkingCopy)

		show

!

notifyList

	| list |

	(self allFileNames includes: 'notify') ifFalse: [^ #()].

	^ self readStreamForFileNamed: 'notify' do:

		[:s |

		s upToEnd withSqueakLineEndings findTokens: (String with: Character cr)]

!

possiblyNewerVersionsOfAnyOf: someVersions

	| pkgs |

	pkgs := Dictionary new.

	someVersions do: [:aVersionInfo |

		pkgs at: (aVersionInfo name copyUpToLast: $-)

			put: (aVersionInfo name copyAfterLast: $.) asNumber].

	^[self allVersionNames select: [:each |

		(pkgs at: (each copyUpToLast: $-) ifPresent: [:verNumber |

			verNumber < (each copyAfterLast: $.) asNumber

				or: [verNumber = (each copyAfterLast: $.) asNumber

					and: [someVersions noneSatisfy: [:v | v name = each]]]]) == true]

	] on: Error do: [:ex | ex return: #()]

!

readableFileNames

	| all cached new |

	all := self allFileNamesOrCache.	"from repository"

	cached := self cachedFileNames.	"in memory"

	new := all difference: cached.

	^ (cached asArray, new)

		select: [:ea | self canReadFileNamed: ea]

!

resizeCache: aDictionary

	[aDictionary size <= self maxCacheSize] whileFalse:

		[aDictionary removeKey: aDictionary keys atRandom]

!

versionFromFileNamed: aString

	| v |

	v := self cache at: aString ifAbsent: [self loadVersionFromFileNamed: aString].

	self resizeCache: cache.

	(v notNil and: [v isCacheable]) ifTrue: [cache at: aString put: v].

	^ v

!

versionInfoFromFileNamed: aString

	self cache at: aString ifPresent: [:v | ^ v info].

	^ self loadVersionInfoFromFileNamed: aString

!

versionNameFromFileName: aString

	^ (aString copyUpToLast: $.) copyUpTo: $(

!

versionReaderForFileNamed: aString do: aBlock

	^ self

		readStreamForFileNamed: aString

		do: [:s |

			(MCVersionReader readerClassForFileNamed: aString) ifNotNilDo:

				[:class | aBlock value: (class on: s fileName: aString)]]

!

versionWithInfo: aVersionInfo ifAbsent: errorBlock

	| version |

	(self allFileNamesForVersionNamed: aVersionInfo name) do:

		[:fileName |

		version _ self versionFromFileNamed: fileName.

		version info = aVersionInfo ifTrue: [^ version]].

	^ errorBlock value

!

writeStreamForFileNamed: aString do: aBlock

	^ self writeStreamForFileNamed: aString replace: false do: aBlock

! !

!MCFileBasedRepository class methodsFor:'documentation'!

version

    ^ '$Header: /cvs/stx/stx/goodies/monticello/MCFileBasedRepository.st,v 1.1 2006-11-22 13:22:23 cg Exp $'

! !