"{ Package: 'jv:smallsense' }"

"{ NameSpace: SmallSense }"

CompletionEngine subclass:#AbstractJavaCompletionEngine

	instanceVariableNames:'class method'

	classVariableNames:''

	poolDictionaries:''

	category:'SmallSense-Java-Abstract'

!

!AbstractJavaCompletionEngine class methodsFor:'queries'!

isAbstract

    "Return if this class is an abstract class.

     True is returned here for myself only; false for subclasses.

     Abstract subclasses must redefine again."

    ^ self == SmallSense::AbstractJavaCompletionEngine.

! !

!AbstractJavaCompletionEngine methodsFor:'completion-individual'!

addClassesStartingWith: prefix

    ^ self addClassesStartingWith: prefix fullName: false

    "Created: / 03-10-2013 / 11:16:08 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 15-05-2014 / 07:25:24 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

addClassesStartingWith: prefixArg fullName: matchFullName

    | prefix |

    prefix := prefixArg.

    matchFullName ifTrue:[

        prefix := prefix copyReplaceAll: $. with: $/.

    ].

    context environment allClassesDo: [:cls |

        cls isJavaClass ifTrue:[

            | name i |

            matchFullName ifTrue:[

                (cls binaryName startsWith: prefix) ifTrue:[

                    result add: (ClassPO new subject: cls; showPrefix: true; yourself).

                ].

            ] ifFalse:[

                name := cls lastName.

                i := name lastIndexOf: $/.

                ((name size >= (i + prefix size))

                    and:[(name at: i + 1) == prefix first

                    and:[(name at: i + prefix size) == prefix last

                    and:[(2 to: prefix size - 1) allSatisfy:[:o| (name at: i + o) == (prefix at: o)]]]])

                    ifTrue:[

                        result add: (ClassPO new subject: cls).

                    ].

            ].

        ].

    ].

    "Created: / 15-05-2014 / 07:24:20 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

addConstructorsForClass: aJavaClass fullName: showFullName

    aJavaClass selectorsAndMethodsDo:[:selector :method |

        (selector first == $< and:[ selector startsWith: '<init>' ]) ifTrue:[ 

            result add: ((JavaConstructorPO name: selector class: aJavaClass) showPrefix: showFullName)

        ].

    ].

    "Created: / 15-05-2014 / 12:05:20 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

addImportsStartingWith: prefix

    | packages |

    packages := Set new.

    "/ Class imports...

    context environment allClassesDo: [:cls |

        cls isJavaClass ifTrue:[

            | name |

            name := cls javaName.

            (cls isPublic and:[name startsWith: prefix]) ifTrue:[

                result add: (JavaImportPO new subject: name; klass: cls; yourself).

                packages add: cls javaPackage.

            ].

        ]

    ].

    "/ Package imports...

    packages do:[:each |

        result add: (JavaImportPO new subject: (each , '.*'))

    ].

    "Created: / 19-10-2013 / 17:54:25 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (format): / 14-05-2014 / 12:48:59 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

addMethodsStartingWith: prefix

    ^ self addMethodsStartingWith: prefix stripOff: nil filter: [:m | m isJavaMethod ]

    "Created: / 03-10-2013 / 18:01:40 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 08-04-2014 / 21:37:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !