"{ NameSpace: SmallSense }"

AbstractSearchDialog subclass:#PackageSearchDialog

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	category:'SmallSense-Core-Interface-Search'

!

!PackageSearchDialog methodsFor:'accessing - private'!

matchingObjectForString: aString

    "Creates a new object from given string. Called only when

     #canCreateMatchingObjectFromString: returns true"

    ^ aString asSymbol

    "Created: / 23-06-2014 / 15:25:19 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!PackageSearchDialog methodsFor:'queries'!

canCreateMatchingObjectFromString:string 

    "Return true, a new object can be created with given string value"

    ^ string allSatisfy:[:c | c isLetterOrDigit or:[ '_:/' includes:c ] ]

    "Created: / 23-06-2014 / 15:15:28 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

canSelect:selection

    ^ selection askFor: #isSmallSensePackagePO

    "Created: / 05-05-2014 / 23:50:44 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!PackageSearchDialog methodsFor:'searching'!

matchingObjectPOsFor:objects

    objects sort: [ :a :b | a < b ].

    ^ objects collect:[ :e | PO forPackage: e ].

    "Created: / 05-05-2014 / 23:54:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 19-06-2014 / 12:04:08 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

matchingObjectsForPattern:pattern inEnvironment:environment relax: level

    | packages |

    packages := Set new.

    environment allClassesDo: [ :cls |

        | pkg |

        pkg := cls package.

        ((pkg notNil and:[ pkg ~~ PackageId noProjectID and:[ pkg ~= '__temporary__'] ])

            and:[(filter isNil or:[ filter value: pkg ])

            and:[pattern isNil or:[pattern match: pkg relax: level]]]) ifTrue:[ packages add: pkg ].

    ].

    environment allMethodsDo:[ :mth |

        | pkg |

        pkg := mth package.

        ((pkg notNil and:[ pkg ~~ PackageId noProjectID ])

            and:[(filter isNil or:[ filter value: pkg ])

            and:[pattern isNil or:[pattern match: pkg relax: level]]]) ifTrue:[ packages add: pkg ].

    ].

    ^ packages asArray.

    "Created: / 20-06-2014 / 21:17:59 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !