"{ Package: 'stx:goodies/xtreams/transforms/tests' }"!

!Xtreams::CollectionReadingWritingTest methodsFor:'tests - transforming'!

testReadRejecting

	self output write: #[ 1 2 3 4 5 6 7 8 9 ].

	self assert: ((self input rejecting: [ :e | e even ]) read: 5) = #[ 1 3 5 7 9 ]

! !

!Xtreams::CollectionReadingWritingTest methodsFor:'tests - transforming'!

testReadSelecting

	self output write: #[ 1 2 3 4 5 6 7 8 9 ].

	self assert: ((self input selecting: [ :e | e even ]) read: 4) = #[ 2 4 6 8 ]

! !

!Xtreams::CollectionReadingWritingTest methodsFor:'tests - transforming'!

testWriteRejecting

	(self output rejecting: [ :e | e even ] ) write: #[ 1 2 3 4 5 6 7 8 9 ]; close.

	self assert: (self input read: 5) = #[ 1 3 5 7 9 ]

! !

!Xtreams::CollectionReadingWritingTest methodsFor:'tests - transforming'!

testWriteSelecting

	(self output selecting: [ :e | e even]) write: #[ 1 2 3 4 5 6 7 8 9 ]; close.

	self assert: (self input read: 4) = #[ 2 4 6 8 ]

! !

!Xtreams::CollectionReadingWritingTest methodsFor:'tests - transforming'!

testWriteTransformHexToByte

	| hex2Byte decoder result |

	decoder := [ :char | ('0123456789ABCDEF' indexOf: char asUppercase) - 1 ].

	hex2Byte :=

		self output transforming: [ :in :out |

			out put: (((decoder value: in get) bitShift: 4) + (decoder value: in get)) ].

	hex2Byte buffer: (ElasticBuffer on: (ByteString new: 16)).

	hex2Byte write: 'ab'.

	hex2Byte write: 'cdef'.

	hex2Byte close.

	self assert: self input get = 16rAB.

	result := self input read: 2.

	self assert: result = #[16rcd 16ref].

! !

!Xtreams::FiniteReadingWritingTests methodsFor:'tests - interpreting'!

testInterpretingDoubles

	| doubles result |

	doubles := (1 to: 10) reading collect: [ :i | i reciprocal asDouble ].

	(self output interpreting: #double) write: doubles; close.

	result := (self input interpreting: #double) rest.

	self assert: result = doubles asArray

! !

!Xtreams::FiniteReadingWritingTests methodsFor:'tests - transforming'!

testWriteTransformingOverLimitingPastEnd

	| limited transferred |

	limited := (self output limiting: 10) transforming: [ :in :out | out put: in get ].

	self assert: (

		[       limited write: (ByteArray withAll: (1 to: 20)).

			false

		] on: Incomplete do: [ :ex | ex count = 11 ] ).

	transferred := self input read: 10.

	self assert: transferred = (ByteArray withAll: (1 to: 10))

! !

!Xtreams::FiniteReadingWritingTests methodsFor:'tests - transforming'!

testWriteTransformingPastEnd

	| count transformed |

	count := 1.

	transformed := self output transforming: [:in :out |

		count = 2 ifTrue: [Incomplete zero raise].

		out put: in get.

		count := count + 1].

	self assert: (

		[       transformed write: #[ 1 2 3 ].

			false

		] on: Incomplete do: [ :ex | ex count = 1 ]).

	transformed close.

	self assert: self input get = 1.

	self should: [self input get] raise: Incomplete.

	self should: [self input get] raise: Incomplete

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testCharacters

	(self output encoding: #ascii)

		setLineEndTransparent;

		backspace; bell; cr; delete; ff; lf; q; qq; space; tab; vtab; escape;

		close.

	self assert: (self input read: 12) = #[8 7 13 127 12 10 39 34 32 9 11 27]

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testDoing

	| outing inning |

	outing := ByteArray new writing.

	(self output doing: [:each | outing put: each]) write: #[ 1 2 3 4 5 ].

	self assert: outing contents = #[ 1 2 3 4 5 ].

	inning := ByteArray new writing.

	self assert: ((self input doing: [:each | inning put: each]) read: 5) = #[ 1 2 3 4 5 ].

	self assert: inning contents = #[ 1 2 3 4 5 ]

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - interpreting'!

testInterpretingPoints

	| points result |

	points := (Random new reading transforming: [ :in :out | out put: in get @ in get ]) read: 5.

	(self output interpreting: [ :b :i :o | b doubleAt: i put: o x. b doubleAt: i + 8 put: o y ] size: 16 )

		write: points;

		close.

	result := (self input interpreting: [ :b :i | (b doubleAt: i) @ (b doubleAt: i + 8) ] size: 16 cacheSize: 5) read: points size.

	self assert: points = result

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - interpreting'!

testMarshaling

	| object result in out |

	object := Object new.

	out := self output marshaling.

	in := self input marshaling.

	2 timesRepeat:

		[out put: ((1 to: 11) collect: [:each | (1 to: 11) collect: [:ea | object]]).

		result := in get.

		self assert: result size = 11.

		self assert: (result allSatisfy: [:each | each allSatisfy: [:ea | ea == result first first]])]

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testReadCollecting

	| data |

	data := #[ 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 ].

	self output write: data.

	self assert: ((self input collecting: [:e | e * e]) read: data size) = (ByteArray withAll: (data collect: [:e | e * e]))

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testReadCollectingContentsSpeciesChanged

	| data result |

	data := ByteArray withAll: ((1 to: 16) collect: [:index | 65]).

	self output write: data.

	result :=

		(self input collecting: [:e | Character codePoint: e])

			contentsSpecies: String;

			read: data size.

	self assert: result = (String withAll: (data asArray collect: [:e | Character codePoint: e]))

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - encoding'!

testReadDecodingBase64

	(self output encoding: #ascii)

		write:

'TWFuIGlzIGRpc3Rpbmd1aXNoZWQsIG5vdCBvbmx5IGJ5IGhpcyByZWFzb24sIGJ1dCBieSB0aGlz

IHNpbmd1bGFyIHBhc3Npb24gZnJvbSBvdGhlciBhbmltYWxzLCB3aGljaCBpcyBhIGx1c3Qgb2Yg

dGhlIG1pbmQsIHRoYXQgYnkgYSBwZXJzZXZlcmFuY2Ugb2YgZGVsaWdodCBpbiB0aGUgY29udGlu

dWVkIGFuZCBpbmRlZmF0aWdhYmxlIGdlbmVyYXRpb24gb2Yga25vd2xlZGdlLCBleGNlZWRzIHRo

ZSBzaG9ydCB2ZWhlbWVuY2Ugb2YgYW55IGNhcm5hbCBwbGVhc3VyZS4=';

		close.

	self assert: (((self input encoding: #ascii) encodingBase64 encoding: #ascii) read: 269) = 'Man is distinguished, not only by his reason, but by this singular passion from other animals, which is a lust of the mind, that by a perseverance of delight in the continued and indefatigable generation of knowledge, exceeds the short vehemence of any carnal pleasure.'

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - encoding'!

testReadDecodingCRLF

	| result |

	self output write: #[104 101 108 108 111 13 10 119 111 114 108 100 10 13 13 10 10 ]; close.

	result := (self input encoding: #ascii) read: 15.

	self assert: result = 'hello\world\\\\' withCRs

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - encoding'!

testReadDecodingTransparent

	| result bytes |

	bytes := #[104 101 108 108 111 13 10 119 111 114 108 100 13 10 13 10 13 10 ].

	self output write: bytes; close.

	result := (self input encoding: #ascii) setLineEndTransparent read: bytes size.

	self assert: result = (String withAll: (bytes asArray collect: [ :e | e asCharacter ]))

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - encoding'!

testReadDecodingUTF16

	| result bytes |

	bytes := #[0 72 0 101 0 108 0 108 0 111 0 32 0 87 0 111 0 114 0 108 0 100 0 33].

	self output write: bytes; close.

	result := (self input encoding: #utf16) read: 12.

	self assert: result = 'Hello World!!'

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - encoding'!

testReadDecodingUTF8

        | result bytes text |

        text := 'Příliš žluťoučký kůň úpěl ďábelské ódy'.

        bytes := #[80 197 153 195 173 108 105 197 161 32 197 190 108 117 197 165 111 117 196 141 107 195 189 32 107 197 175 197 136 32 195 186 112 196 155 108 32 196 143 195 161 98 101 108 115 107 195 169 32 195 179 100 121].

        self output write: bytes; close.

        result := (self input encoding: #utf8) read: 38.

        self assert: result = text

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testReadDuplicating

	| copy contents |

	contents := Array withAll: (0 to: 15).

	copy := Array new writing.

	self assert: (contents reading duplicating: copy) rest = contents.

	self assert: copy conclusion = contents

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testReadInjecting

	self output write: #[ 1 2 3 4 ].

	self assert: ((self input injecting: 0 into: [:all :each | all + each]) read: 4) = #[ 1 3 6 10 ]

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testReadRejecting

	self output write: #[ 1 2 3 4 5 6 7 8 9 ].

	self assert: ((self input rejecting: #even) read: 5) = #[ 1 3 5 7 9 ]

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testReadSelecting

	self output write: #[ 1 2 3 4 5 6 7 8 9 ].

	self assert: ((self input selecting: #even) read: 4) = #[ 2 4 6 8 ]

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testReadTransforming1into2

	| result |

	self output write: #[ 1 2 3 ].

	result :=

		(self input transforming: [:in :out | | x | x := in get. out put: x; put: x])

			read: 6.

	self assert: result = #[ 1 1 2 2 3 3 ]

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testReadTransforming2into1

	| result |

	self output write: #[ 1 2 3 4 ].

	result :=

		(self input transforming: [:in :out | in get. out put: in get])

			read: 2.

	self assert: result = #[ 2 4 ]

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testReadTransformingPastEnd

	| count transformed |

	count := 1.

	self output write: #[ 1 2 3 ]; close.

	transformed := self input transforming: [:in :out |

		count = 2 ifTrue: [Incomplete zero raise].

		out put: in get.

		count := count + 1].

	self assert: transformed get = 1.

	self should: [transformed get] raise: Incomplete.

	self should: [transformed get] raise: Incomplete

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - interpreting'!

testReadUnsignedShortEndianness

	self output write: #[ 16rFF 16r00 16rFF 00]; close.

	self assert: (self input interpreting: #unsignedShort_le) get = 16rFF.

	self assert: (self input interpreting: #unsignedShort_be) get = 16rFF00.

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testWriteCollecting

	| data |

	data := 1 to: 15.

	(self output collecting: [:e | e * e]) write: data.

	self assert: (self input read: data size) = (ByteArray withAll: (data collect: [:e | e * e]))

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testWriteCollectingIncompatibleContentSpecies

	| data |

	data := (1 to: 15) collect: [ :x | x @ 0 ].

	(self output collecting: [:e | e x ]) write: data.

	self assert: (self input read: data size) = (ByteArray withAll: (data collect: [:e | e x]))

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testWriteCollectingMultipleBufferSize

	| data |

	data := (1 to: DefaultBufferSize + 500) collect: [ :i | i \\ 16 ].

	self timeout: 1 seconds

		server:

			[(self output collecting: [:e | e * e])

				write: data;

				close.

			true]

		client: [(self input read: data size) = (ByteArray withAll: (data collect: [:e | e * e]))]

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testWriteDuplicating

	| original copy contents |

	contents := Array withAll: (0 to: 15).

	original := Array new writing.

	copy := Array new writing.

	(original duplicating: copy) write: contents.

	self assert: original conclusion = contents.

	self assert: copy conclusion = contents

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - encoding'!

testWriteEncodingBase64

	((self output encoding: #ascii) encodingBase64 encoding: #ascii)

		write: 'Man is distinguished, not only by his reason, but by this singular passion from other animals, which is a lust of the mind, that by a perseverance of delight in the continued and indefatigable generation of knowledge, exceeds the short vehemence of any carnal pleasure.';

		close.

	self assert: ((self input encoding: #ascii) read: 360) = 'TWFuIGlzIGRpc3Rpbmd1aXNoZWQsIG5vdCBvbmx5IGJ5IGhpcyByZWFzb24sIGJ1dCBieSB0aGlzIHNpbmd1bGFyIHBhc3Npb24gZnJvbSBvdGhlciBhbmltYWxzLCB3aGljaCBpcyBhIGx1c3Qgb2YgdGhlIG1pbmQsIHRoYXQgYnkgYSBwZXJzZXZlcmFuY2Ugb2YgZGVsaWdodCBpbiB0aGUgY29udGludWVkIGFuZCBpbmRlZmF0aWdhYmxlIGdlbmVyYXRpb24gb2Yga25vd2xlZGdlLCBleGNlZWRzIHRoZSBzaG9ydCB2ZWhlbWVuY2Ugb2YgYW55IGNhcm5hbCBwbGVhc3VyZS4='

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - encoding'!

testWriteEncodingCRLF

        | result isCRLF |

        (self output encoding: #ascii)

                write: 'hello\world\\\' withCRs;

                close.

        isCRLF := OperatingSystem isMSWINDOWSlike.

        result := self input read: (isCRLF ifTrue: [18] ifFalse: [14]).

        self assert: result = (isCRLF

                ifTrue: [#[104 101 108 108 111 13 10 119 111 114 108 100 13 10 13 10 13 10 ] ]

                ifFalse: [#[104 101 108 108 111 10 119 111 114 108 100 10 10 10 ] ])

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - encoding'!

testWriteEncodingTransparent

	| data result bytes |

	bytes := #[104 101 108 108 111 13 10 119 111 114 108 100 13 10 13 10 13 10 ].

	data := String withAll: (bytes asArray collect: [ :e | e asCharacter ]).

	(self output encoding: #ascii)

		setLineEndTransparent;

		write: data;

		close.

	result := self input read: data size.

	self assert: result = bytes

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - encoding'!

testWriteEncodingUTF16

	| result bytes |

	bytes := #[0 72 0 101 0 108 0 108 0 111 0 32 0 87 0 111 0 114 0 108 0 100 0 33].

	(self output encoding: #utf16) write: 'Hello World!!'; close.

	result := self input read: 24.

	self assert: result = bytes

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - encoding'!

testWriteEncodingUTF8

        | result bytes text |

        text := 'Příliš žluťoučký kůň úpěl ďábelské ódy'.

        bytes := #[80 197 153 195 173 108 105 197 161 32 197 190 108 117 197 165 111 117 196 141 107 195 189 32 107 197 175 197 136 32 195 186 112 196 155 108 32 196 143 195 161 98 101 108 115 107 195 169 32 195 179 100 121].

        (self output encoding: #utf8) write: text; close.

        result := self input read: bytes size.

        self assert: result = bytes

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testWriteInjecting

	(self output injecting: 0 into: [:all :each | all + each])

		write: #[ 1 2 3 4 ]; close.

	self assert: (self input read: 4) = #[ 1 3 6 10 ]

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testWriteRejecting

	(self output rejecting: #even) write: #[ 1 2 3 4 5 6 7 8 9 ]; close.

	self assert: (self input read: 5) = #[ 1 3 5 7 9 ]

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testWriteSelecting

	(self output selecting: #even) write: #[ 1 2 3 4 5 6 7 8 9 ]; close.

	self assert: (self input read: 4) = #[ 2 4 6 8 ]

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testWriteTransformHexToByte

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testWriteTransforming1into2

	| result |

	(self output transforming: [:in :out | | x | x := in get. out put: x; put: x])

		write: #[ 1 2 3 ];

		close.

	result := (self input read: 6).

	self assert: result = #[ 1 1 2 2 3 3 ]

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - transforming'!

testWriteTransforming2into1

	| result |

	(self output transforming: [:in :out | in get. out put: in get])

		write: #[ 1 2 3 4 ];

		close.

	result := self input read: 2.

	self assert: result = #[ 2 4 ]

! !

!Xtreams::ReadingWritingTest methodsFor:'tests - interpreting'!

testWriteUnsignedShortEndianness

	(self output interpreting: #unsignedShort_le) put: 16rFF.

	(self output interpreting: #unsignedShort_be) put: 16rFF00.

	self output close.

	self assert: (self input read: 4) = #[ 16rFF 16r00 16rFF 00]

! !

!stx_goodies_xtreams_transforms_tests class methodsFor:'documentation'!

extensionsVersion_HG

    ^ '$Changeset: <not expanded> $'

! !