"

 COPYRIGHT (c) 2006 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

ProjectDefinition subclass:#ApplicationDefinition

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	category:'System-Support-Projects'

!

!ApplicationDefinition class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2006 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    subclasses provide the info on the contents of a package/project and

    how to build executables and class libraries and how to load/unload packages.

    Actually, subclasses MUST be subclasses of the two abstract classes LibraryDefinition or

    ApplicationDefinition. These two know how to generate all required help files for the

    making/building/loading processa.

    The makefile creation is driven by file templates which are expanded using strings from the file mappings.

    Concrete definition classes MUST redefine:

        classNamesAndAttributes

                                list of classes which are part of the dll/exe

        extensionMethodNames

                                list of extension methods

        startupClassName / startupSelector

                                class and selector with which the show starts

        buildTarget             name of the generated exe-file

    should redefine:

        preRequisites           list of required packages

        iconFileName            name of a .ico file containing the applications icon

        companyName             name of your company - will be shown by windows explorer

                                as attribute of a .dll or .exe

        description             short description; shown by windows explorer

        legalCopyright          copyright message; shown by windows explorer

        productName             product name; shown by windows explorer

        applicationName         app name; shown by windows explorer

    might redefine:    

        isConsoleApplication    if true, windows-build generates a console app.

        isGUIApplication        if true, the GUI framework is linked in

                                (as opposed to a non-GUI server-like executable)

    The above info might be outdated a bit - see stx_projects_smalltalk as a concrete example.

    [author:]

        Felix Madrid

        Claus Gittinger

    [see also:]

        stx_projects_smalltalk

        stx_libbasic

        stx_libbasic2

"

! !

!ApplicationDefinition class methodsFor:'accessing'!

appSourcesProjects

    "Returns only the application projects (which are included in the application module)"

    ^ self effectivePreRequisites select:[:each | 

        (self moduleFor: each) = self module

    ].

    "

        bosch_dapasx_application appSourcesProjects

    "

!

startupClass

    "the class, but onlz of loaded"

    |cls|

    Error 

        handle:[:ex | ] 

        do:[

            |clsName|

            clsName := self startupClassName.

            cls := Smalltalk classNamed:clsName.

        ].

    ^ cls

    "Created: / 20-07-2012 / 16:37:36 / cg"

!

stxSourcesProjects

    "Returns only the required STX projects (which are included in the STX module)"

    ^ self effectivePreRequisites select:[:each | 

        (self moduleFor: each) = (self moduleFor: #stx)

    ].

    "

        bosch_dapasx_application stxSourcesProjects

    "

    "

    #(

       'libbasic' 

       'libbasic2' 

       'libcomp' 

       'libview' 

       'libview2'

       'libwidg' 

       'libwidg2' 

       'libtool' 

       'libtool2' 

       'libhtml' 

       'libui'

    )

    "

! !

!ApplicationDefinition class methodsFor:'code generation'!

forEachMethodsCodeToCompileDo:aTwoArgBlock ignoreOldDefinition:ignoreOldDefinition

    super forEachMethodsCodeToCompileDo:aTwoArgBlock ignoreOldDefinition:ignoreOldDefinition.

    #(

        (applicationIconFileName applicationIconFileName_code 'description - project information')

        (subProjects subProjects_code 'description')

        (productInstallDirBaseName productInstallDirBaseName_code 'description - project information')

        (startupClassName startupClassName_code 'description - startup')

        (startupSelector startupSelector_code 'description - startup')

    ) triplesDo:[:selector :codeMethodSelector :category|

        (self class includesSelector:selector) ifFalse:[

            aTwoArgBlock

                value: (self perform:codeMethodSelector)

                value: category.

        ].

    ].

    "Created: / 10-08-2006 / 16:35:47 / cg"

    "Modified: / 30-08-2006 / 19:03:48 / cg"

!

startupClassName_code

    |classes startClasses mainClasses appClasses|

    classes := self classNamesAndAttributes 

                collect:[:nm | Smalltalk classNamed:nm] 

                thenSelect:[:cls | cls notNil and:[cls isProjectDefinition not ]].

    mainClasses := classes select:[:each | each theMetaclass includesSelector:#main ].

    mainClasses size == 1 ifTrue:[

        ^ self startupClassName_codeFor:(mainClasses first name)

    ].

    mainClasses isEmpty ifTrue:[

        startClasses := classes select:[:each | each theMetaclass includesSelector:#start ].

        startClasses size == 1 ifTrue:[

            ^ self startupClassName_codeFor:(startClasses first name)

        ].

        startClasses isEmpty ifTrue:[

            appClasses := classes select:[:each | each isSubclassOf:ApplicationModel ].

            appClasses size == 1 ifTrue:[

                ^ self startupClassName_codeFor:(appClasses first name)

            ].

        ]

    ].

    ^ 

'startupClassName

    "the name of the class which starts the show in its <startupSelector> method.

     Usually, the name of a subclass of StandAloneStartup."

    self error:''undefined startupClass''.

    ^ ''<name of class here>''

'

    "Modified: / 27-12-2006 / 11:43:34 / cg"

!

startupClassName_codeFor:aClassName

    ^ 

'startupClassName

    "the class that starts the show in its startupSelector method"

    ^ ''',aClassName,'''

'

    "Created: / 05-09-2006 / 13:40:32 / cg"

!

startupSelector_code

    "generate a the code that answers the startupSelector.

     try #open and #start."

    |clsName cls sel|

    Error 

        handle:[:ex | ] 

        do:[

            clsName := self startupClassName.

            cls := Smalltalk classNamed:clsName.

        ].

    sel := #start.

    cls notNil ifTrue:[

        (cls respondsTo:#open) ifTrue:[

            sel := #open

        ].

    ].

    ^ self startupSelector_codeFor:sel

    "Modified: / 27-12-2006 / 11:45:38 / cg"

!

startupSelector_codeFor:aSelector

    ^ 

'startupSelector

    "the message that is sent to the startupClass to start the show"

    ^ #''',aSelector,'''        

'

    "Created: / 05-09-2006 / 13:41:01 / cg"

    "Modified: / 15-12-2006 / 14:10:11 / cg"

!

subProjects_code        

    |subProjects|

    subProjects := 

        (self siblingsAreSubProjects)

            ifTrue:[ self searchForSiblingProjects ]

            ifFalse:[ self searchForSubProjects ].

    subProjects removeAll: self excludedFromSubProjects.

    ^ String streamContents:[:s |

        s nextPutLine:'subProjects'.

        s nextPutLine:'    "list packages which are known as subprojects.'.

        s nextPutLine:'     This method is generated automatically; however, when generating automatically,'. 

        s nextPutLine:'     packages are only added - never removed, unless listed in #excludedFromSubProjects."'.

        s nextPutLine:''.

        s nextPutLine:'    ^ #('.

        subProjects do:[:eachPackageID |    

            s nextPutLine:eachPackageID asString storeString

        ].      

        s nextPutLine:')'

    ].

    "

     bosch_dapasx subProjectsGeneratedString

     stx_goodies subProjectsGeneratedString

    "

    "Modified: / 08-08-2006 / 19:24:34 / fm"

    "Created: / 17-08-2006 / 21:26:51 / cg"

! !

!ApplicationDefinition class methodsFor:'defaults'!

buildTarget

    "which target in the Makefile should be built by default?

     For now, reasonable return values are 'exe', which builds the executable(s),

     and 'ALL', which builds everything, including an installable package.

     Here, 'ALL' is returned.

     There is usually no need to redefine this default - we at exept do it for the

     stx package only to speed up our own build, as we seldom need new install packages,

     put often build new executables..."

     ^ 'ALL'

!

extraTargets

    "extra targets to be built when creating the exe"

     self needResources ifTrue:[

        ^ #('RESOURCEFILES')

     ].

     ^ #()

!

guiClassFileNames_unix

    ^ self guiClasses_unix 

        collect:[:cls | (cls classBaseFilename asFilename withSuffix:'so') baseName].

    "Created: / 14-09-2006 / 18:13:22 / cg"

    "Modified: / 12-10-2006 / 15:50:39 / cg"

!

guiClassFileNames_win32

    ^ self guiClasses_win32 

        collect:[:cls | (cls classBaseFilename asFilename withSuffix:'dll') baseName].

    "Created: / 07-09-2006 / 17:23:13 / cg"

    "Modified: / 12-10-2006 / 15:50:42 / cg"

!

guiClasses_unix

    ^ #()

    "Created: / 14-09-2006 / 18:12:58 / cg"

!

guiClasses_win32

    ^ #()

    "/ ^ Array with:XWorkstation

    "Created: / 07-09-2006 / 17:22:27 / cg"

    "Modified: / 14-09-2006 / 18:12:35 / cg"

!

needResources

    "answer true, if this application

     needs resources to be installed. This is normally true.

     Even non-GUI apps need some (libbasic/resources)"

    ^ true 

! !

!ApplicationDefinition class methodsFor:'description'!

additionalFilesToInstall

    "application-specific files to be installed.

     Can be redefined in subclasses."

    ^ #()

    "Created: / 01-03-2007 / 20:02:21 / cg"

!

additionalResourceTargets

    "application-specific additional resource targets to be invoked.

     Can be redefined in subclasses."

    ^ #()

!

applicationIconFileName

    "answer the base-name of the application icon (i.e. 'app' in <app>.ico).

     Subclasses MUST redefine this to either return the name of the icon file or

     nil, if they dont have one.

     We NO LONGER SUPPORT THE PREVIOUS APPNAME-DEFAULT,

     because users tend to forget to add the icon file and then get a failing build. "

    self subclassResponsibility.

!

applicationInstallIconFileName

    "answer the base-name of the installer icon (i.e. 'app' in <app>.ico).

     Default is the same as the application icon"

    ^ self applicationIconFileName.

!

applicationName

    "answer the name of the application.

     This is also the name of the generated .exe file.

     Subclasses may redefine this"

    ^ self applicationNameFromPackage

    "

     bosch_dapasx_application applicationName     

     stx_projects_smalltalk applicationName     

    "

    "Created: / 08-08-2006 / 20:25:39 / fm"

    "Modified: / 30-08-2006 / 19:29:25 / cg"

!

documentExtensions

    "list extensions which should be registered with the application.

     Results in the application to be started when double-clicking on such a file (win32)"

    ^ #()

    "Created: / 15-10-2006 / 12:44:14 / cg"

!

includedInPreRequisites

    "list packages which are to be explicitely included in the prerequisites list,

     even if not found by the automatic search.

     Redefine this, if classes from other packages are referred to via reflection

     or by constructing names dynamically (i.e. the search cannot find it)"

    ^ self isGUIApplication ifTrue:[

        #(

            #'stx:libcomp'   "/ to read the rc file

            #'stx:libbasic2' "/ UI framework

            #'stx:libview'   "/ UI framework

            #'stx:libview2'  "/ UI framework

            #'stx:libwidg'   "/ UI framework

            #'stx:libwidg2'  "/ UI framework

            #'stx:libui'     "/ UI framework

        )

    ] ifFalse:[

        #(

            #'stx:libcomp'   "/ to read the rc file

        )

    ].

!

initiallyLoadedPreRequisites

   "Prereqisites packages that are not to be loaded at application startup, but

    that maybe loaded later by the application.

    This is used for a fast startup in case that the application wants to only inform

    an already running application to e.g. open an additional window."

    ^ nil       "the default, nil means: all prerequisites should be loaded initially"

"/    ^ #(

"/        #'stx:libbasic'  

"/        #'stx:libbasic2'   

"/        #'stx:libcomp'

"/    )

!

isConsoleApplication

    "Used with WIN32 only (i.e. affects bc.mak).

     Return true, if this is a console application. 

     Console applications have stdout and stderr and open up a command-window

     when started. Only console applications can interact with the user in the

     command line window.

     By default, GUI apps are compiled as non-console apps.

     If you need both (as in expecco), redefine this as true AND in addition redefine 

     makeConsoleApplication to return true."

    ^ self isGUIApplication not

    "Created: / 20-09-2006 / 11:29:24 / cg"

!

isGUIApplication

    "Return true, if this is a GUI app. 

     Redefine to return false for non-GUI applications (affects inclusion of Display classes)."

    ^true

    "Created: / 08-08-2006 / 11:15:01 / fm"

    "Modified: / 17-08-2006 / 19:47:36 / cg"

!

isSingleThreadedApplication

    "Return true, if this should be started without multiple threads. 

     (not possible with gui applications)"

    ^false