"

 COPYRIGHT (c) 2006 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

ProjectDefinition subclass:#ApplicationDefinition

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	category:'System-Support-Projects'

!

!ApplicationDefinition class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2006 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    subclasses provide the info on how to build executables and class libraries.

    Actually, subclasses must be subclasses of either LibraryDefinition or

    ApplicationDefinition.

    These know how to generate all required help files for make-building.

    Concrete definition classes must redefine:

        classNamesAndAttributes

                                list of classes which are part of the dll/exe

        extensionMethodNames

                                list of extension methods

        startupClassName / startupSelector

                                class and selector with which the show starts

        buildTarget             name of the generated exe-file

    should redefine:

        preRequisites           list of required packages

        iconFileName            name of a .ico file containing the applications icon

        companyName             name of your company - will be shown by windows explorer

                                as attribute of a .dll or .exe

        description             short description; shown by windows explorer

        legalCopyright          copyright message; shown by windows explorer

        productName             product name; shown by windows explorer

        applicationName         app name; shown by windows explorer

    might redefine:    

        isConsoleApplication    if true, windows-build generates a console app.

        isGUIApplication        if true, the GUI framework is linked in

                                (as opposed to a non-GUI server-like executable)

    The above info might be outdated a bit - see stx_projects_smalltalk as a concrete example.

    [author:]

        Felix Madrid

        Claus Gittinger

    [see also:]

        stx_projects_smalltalk

        stx_libbasic

        stx_libbasic2

"

! !

!ApplicationDefinition class methodsFor:'accessing'!

allPreRequisites

    |setOfAllPreRequisites setOfExcludedPreRequisites setOfExcludedSubProjects allPreRequisites toAdd|

    setOfExcludedPreRequisites := self excludedFromPreRequisites asSet.

    setOfExcludedSubProjects := self excludedFromSubProjects asSet.

    setOfAllPreRequisites := Set new.

    allPreRequisites := OrderedCollection new.

    toAdd := OrderedCollection new.

    toAdd addAll:(self preRequisites).

    toAdd addAll:(self subProjects ).

    [toAdd notEmpty] whileTrue:[

        |aPreRequisiteProjectID def|

        aPreRequisiteProjectID := toAdd removeFirst.

        (setOfAllPreRequisites includes:aPreRequisiteProjectID) ifFalse:[

            (setOfExcludedPreRequisites includes:aPreRequisiteProjectID) ifFalse:[

                (setOfExcludedSubProjects includes:aPreRequisiteProjectID) ifFalse:[

                    allPreRequisites add:aPreRequisiteProjectID.

                    setOfAllPreRequisites add:aPreRequisiteProjectID.

                    def := ProjectDefinition definitionClassForPackage:aPreRequisiteProjectID.

                    def isNil ifTrue:[

                        Transcript showCR:'ProjectDefinition ',aPreRequisiteProjectID,' is missing - cannot find its preRequisites.'.

                    ] ifFalse:[

                        def preRequisites 

                            select:[:eachSubPreRequisite | (setOfAllPreRequisites includes:eachSubPreRequisite) not]

                            thenDo:[:eachSubPreRequisite | 

                                        Transcript showCR:(aPreRequisiteProjectID,' requires ',eachSubPreRequisite).

                                        toAdd add:eachSubPreRequisite ].

                        def subProjects 

                            select:[:eachSubSubRequisite | (setOfAllPreRequisites includes:eachSubSubRequisite) not]

                            thenDo:[:eachSubSubRequisite | 

                                        Transcript showCR:(aPreRequisiteProjectID,' hasSub ',eachSubSubRequisite).

                                        toAdd add:eachSubSubRequisite ].

                    ].

                ]        

            ]        

        ]        

    ].

    ^ allPreRequisites.

    "

     exept_expeccoNET_application allPreRequisites   

    "

!

appSourcesProjects

    "Returns only the application projects (which are included in the application module)"

    ^self preRequisites select:[:each | 

        (self moduleFor: each) = self module

    ].

    "

        bosch_dapasx_application appSourcesProjects

    "

!

stxSourcesProjects

    "Returns only the required STX projects (which are included in the STX module)"

    ^self preRequisites select:[:each | 

        (self moduleFor: each) = (self moduleFor: #'stx')

    ].

    "

        bosch_dapasx_application stxSourcesProjects

    "

    "

    #(

       'libbasic' 

       'libbasic2' 

       'libcomp' 

       'libview' 

       'libview2'

       'libwidg' 

       'libwidg2' 

       'libtool' 

       'libtool2' 

       'libhtml' 

       'libui'

    )

    "

! !

!ApplicationDefinition class methodsFor:'code generation'!

forEachMethodsCodeToCompileDo:aTwoArgBlock ignoreOldDefinition:ignoreOldDefinition

    super forEachMethodsCodeToCompileDo:aTwoArgBlock ignoreOldDefinition:ignoreOldDefinition.

    aTwoArgBlock 

        value:self subProjects_code

        value:'description'.

    aTwoArgBlock 

        value:self preRequisites_code

        value:'description'.

    (self class implements:#startupClassName) ifFalse:[

        aTwoArgBlock 

            value:self startupClassName_code

            value:'description - startup'.

    ].

    (self class implements:#startupSelector) ifFalse:[

        aTwoArgBlock 

            value:self startupSelector_code

            value:'description - startup'.

    ].

    "Created: / 10-08-2006 / 16:35:47 / cg"

    "Modified: / 30-08-2006 / 19:03:48 / cg"

!

startupClassName_code

    |classes startClasses mainClasses appClasses cls|

    classes := self classNamesAndAttributes 

                collect:[:nm | Smalltalk classNamed:nm] 

                thenSelect:[:cls | cls notNil and:[cls isProjectDefinition not ]].

    mainClasses := classes select:[:each | each theMetaclass implements:#main ].

    mainClasses size == 1 ifTrue:[

        ^ self startupClassName_codeFor:(mainClasses first name)

    ].

    mainClasses isEmpty ifTrue:[

        startClasses := classes select:[:each | each theMetaclass implements:#start ].

        startClasses size == 1 ifTrue:[

            ^ self startupClassName_codeFor:(startClasses first name)

        ].

        startClasses isEmpty ifTrue:[

            appClasses := classes select:[:each | each isSubclassOf:ApplicationModel ].

            appClasses size == 1 ifTrue:[

                ^ self startupClassName_codeFor:(appClasses first name)

            ].

        ]

    ].

    ^ 

'startupClassName

    self error:''undefined startupClass''.

    ^ ''<name of class here>''

'

    "Modified: / 27-12-2006 / 11:43:34 / cg"

!

startupClassName_codeFor:aClassName

    ^ 

'startupClassName

    ^ ''',aClassName,'''

'

    "Created: / 05-09-2006 / 13:40:32 / cg"

!

startupSelector_code

    |clsName cls sel|

    Error 

        handle:[:ex | ] 

        do:[

            clsName := self startupClassName.

            cls := Smalltalk classNamed:clsName.

        ].

    sel := #'start'.

    cls notNil ifTrue:[

        (cls respondsTo:#open) ifTrue:[

            sel := #'open'

        ] ifFalse:[

            (cls respondsTo:#main) ifTrue:[

                sel := #'main'

            ]

        ].

    ].

    ^ self startupSelector_codeFor:sel

    "Modified: / 27-12-2006 / 11:45:38 / cg"

!

startupSelector_codeFor:aSelector

    ^ 

'startupSelector

    ^ #''',aSelector,'''        

'

    "Created: / 05-09-2006 / 13:41:01 / cg"

    "Modified: / 15-12-2006 / 14:10:11 / cg"

!

subProjects_code        

    |subProjects|

    subProjects := 

        (self siblingsAreSubProjects)

            ifTrue:[ self searchForSiblingProjects ]

            ifFalse:[ self searchForSubProjects ].

    subProjects removeAll: self excludedFromSubProjects.

    ^ String streamContents:[:s |

        s nextPutLine:'subProjects'.

        s nextPutLine:'    ^ #('.

        subProjects do:[:eachPackageID |    

            s nextPutLine:eachPackageID asString storeString

        ].      

        s nextPutLine:')'

    ].

    "

     bosch_dapasx subProjectsGeneratedString

     stx_goodies subProjectsGeneratedString

    "

    "Modified: / 08-08-2006 / 19:24:34 / fm"

    "Created: / 17-08-2006 / 21:26:51 / cg"

! !

!ApplicationDefinition class methodsFor:'defaults'!

buildTarget

    "which target in the Makefile should be built by default?

     For now, reasonable return values are 'exe', which builds the executable(s),

     and 'ALL', which builds everything, including an installable package.

     Here, 'ALL' is returned.

     There is usually no need to redefine this default - we at exept do it for the

     stx package only to speed up our own build, as we seldom need new install packages,

     put often build new executables..."

     ^ 'ALL'

!

guiClassFileNames_unix

    ^ self guiClasses_unix 

        collect:[:cls | (cls classBaseFilename asFilename withSuffix:'so') baseName].

    "Created: / 14-09-2006 / 18:13:22 / cg"

    "Modified: / 12-10-2006 / 15:50:39 / cg"

!

guiClassFileNames_win32

    ^ self guiClasses_win32 

        collect:[:cls | (cls classBaseFilename asFilename withSuffix:'dll') baseName].

    "Created: / 07-09-2006 / 17:23:13 / cg"

    "Modified: / 12-10-2006 / 15:50:42 / cg"

!

guiClasses_unix

    ^ #()

    "Created: / 14-09-2006 / 18:12:58 / cg"

!

guiClasses_win32

    ^ #()

    "/ ^ Array with:XWorkstation

    "Created: / 07-09-2006 / 17:22:27 / cg"

    "Modified: / 14-09-2006 / 18:12:35 / cg"

!

needResources

    "answer true, if this application

     needs resources to be installed. This is normally true.

     Even non-GUI apps need some (libbasic/resources)"

    ^ true 

! !

!ApplicationDefinition class methodsFor:'description'!

additionalFilesToInstall

    "application-specific files to be installed.

     Can be redefined in subclasses."

    ^ #()

    "Created: / 01-03-2007 / 20:02:21 / cg"

!

applicationIconFileName

    "answer the base-name of the application icon (i.e. 'app' in <app>.ico)

     Subclasses may redefine this"

    ^ self applicationName

!

applicationName

    "answer the name of the application.

     This is also the name of the generated .exe file.

     Subclasses may redefine this"

    ^ self applicationNameFromPackage

    "

     bosch_dapasx_application applicationName     

     stx_projects_smalltalk applicationName     

    "

    "Created: / 08-08-2006 / 20:25:39 / fm"

    "Modified: / 30-08-2006 / 19:29:25 / cg"

!

applicationNameConsole

    ^ self applicationName,'_debug'

!

applicationNameFromPackage

    "answer the name of the application.

     This is also the name of the generated .exe file.

     Subclasses may redefine this"

    |m path|

    m := self moduleDirectory.

    path := m subStrings:$/.

    path last = 'application' ifTrue:[

        path size > 1 ifTrue:[

            path := path copyWithoutLast:1.

        ].

    ].

    ^ path last

    "

     bosch_dapasx_application applicationName     

     stx_projects_smalltalk applicationName     

    "

    "Created: / 08-08-2006 / 20:25:39 / fm"

    "Modified: / 30-08-2006 / 19:29:25 / cg"

!

applicationNameNoConsole

    ^ self applicationName

!

commonFilesToInstall

    "files installed for applications.

     Do not redefine - see additionalFilesToInstall for a redefinable variant of this"

    ^ #(

        '"*.dll"'

        '"symbols.stc"'

        '"*.stx"'

        '"*.rc"'

        '/r "resources"'

    )

    "Created: / 01-03-2007 / 20:05:40 / cg"

!

documentExtensions

    "list extensions which should be registered with the application.

     Results in the application to be started when double-clicking on such a file (win32)"

    ^ #()

    "Created: / 15-10-2006 / 12:44:14 / cg"

!

isConsoleApplication

    "Return true, if this is a console application (used with win32 only). 

     Console applications have stdout and stderr and open up a command-window

     when started. Only console applications can interact with the user in the

     command line window.

     By default, GUI apps are compiled as non-console apps."

    ^ self isGUIApplication not

    "Created: / 20-09-2006 / 11:29:24 / cg"

!

isGUIApplication

    "Return true, if this is a GUI app. 

     Redefine to return false for non-GUI applications (affects inclusion of Display classes)."

    ^true

    "Created: / 08-08-2006 / 11:15:01 / fm"

    "Modified: / 17-08-2006 / 19:47:36 / cg"

!

isSingleThreadedApplication

    "Return true, if this should be started without multiple threads. 

     (not possible with gui applications)"

    ^false