"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

AbstractTime subclass:#Time

	instanceVariableNames:'timeEncoding'

	classVariableNames:''

	poolDictionaries:''

	category:'Magnitude-General'

!

!Time class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    Instances of time represent a particular time-of-day.

    Since they only store hours, minutes and seconds within a day,

    they cannot be used to compare times across midnight 

    (i.e. they should not be used as timeStamps).

    Use instances of AbsoluteTime (and read the comment there) to do this.

    Examples:

        |t|

        t := Time now.

        Transcript showCR:t.

        |t1 t2|

        t1 := Time now.

        (Delay forSeconds:10) wait.

        t2 := Time now.

        t2 - t1   

    [author:]

        Claus Gittinger

    [see also:]

        Date AbsoluteTime AbstractTime OperatingSystem

        Filename

"

! !

!Time class methodsFor:'instance creation'!

hour:h minutes:m seconds:s

    "return an instance of Time representing the given time.

     See also Time now / Date today / AbsoluteTime now.

     Obsolete: please use #hours:minutes:seconds:"

    self obsoleteMethodWarning:'use hours:minutes:seconds:'.

    ^ self hours:h minutes:m seconds:s

    "

     Time hours:2 minutes:33 seconds:0 

     Time hours:0 minutes:0 seconds:0 

     Time hours:24 minutes:0 seconds:0 

     Time hours23 minutes:59 seconds:59 

    "

    "Modified: 19.4.1996 / 15:32:40 / cg"

!

hours:h minutes:m seconds:s

    "return an instance of Time representing the given time.

     See also Time now / Date today / AbsoluteTime now."

    ^ self basicNew setHours:h minutes:m seconds:s

    "

     Time hours:2 minutes:33 seconds:0 

     Time hours:0 minutes:0 seconds:0 

     Time hours:24 minutes:0 seconds:0 

     Time hours:23 minutes:59 seconds:59 

    "

    "Modified: 19.4.1996 / 15:32:40 / cg"

!

readFrom:aStringOrStream onError:exceptionBlock

    "return a new Time, reading a printed representation from aStream.

     If no am/pm follows the time, the string is interpreted as 

     either 24 hour format or being am."

    |newTime|

    ErrorSignal handle:[:ex |

        ^ exceptionBlock value

    ] do:[

        |str hour min sec|

        str := aStringOrStream readStream.

        hour := Integer readFrom:str.

        (hour between:0 and:24) ifFalse:[^ exceptionBlock value].

        min := 0.

        sec := 0.

        str atEnd ifFalse:[

            (str peek == $:) ifTrue:[

                str next.

                min := Integer readFrom:str.

                (min between:0 and:59) ifFalse:[^ exceptionBlock value].

                (str peek == $:) ifTrue:[

                    str next.

                    sec := Integer readFrom:str.

                    (sec between:0 and:59) ifFalse:[^ exceptionBlock value].

                ].

            ].

            [str peek == Character space] whileTrue:[str next].

            (str peek == $p or:[str peek == $P]) ifTrue:[

                str next.

                (str peek == $m or:[str peek == $M]) ifTrue:[

                    str next

                ].

                (hour <= 0 or:[hour > 12]) ifTrue:[^ exceptionBlock value].

                "pm"

                hour ~~ 12 ifTrue:[

                    hour := hour + 12

                ]

            ] ifFalse:[

                (str peek == $a or:[str peek == $A]) ifTrue:[

                    str next.

                    (str peek == $m or:[str peek == $M]) ifTrue:[

                        str next

                    ].

                    hour >= 12 ifTrue:[^ exceptionBlock value].

                    hour == 24 ifTrue:[

                        hour := 0.

                    ]

                ]

            ]

        ].

        newTime := self basicNew setHours:hour minutes:min seconds:sec

    ].

    ^ newTime

    "

     Time readFrom:'0:00'     

     Time readFrom:'2:00'     

     Time readFrom:'12:00'    

     Time readFrom:'14:00'    

     Time readFrom:'23:00'    

     Time readFrom:'24:00'    

     Time readFrom:'2:30 am'    

     Time readFrom:'2:30 pm'    

     Time readFrom:'14'    

     Time readFrom:'2 am'    

     Time readFrom:'2 pm'    

     Time readFrom:'18:22:00'    

     Time readFrom:'14:00:11'    

     Time readFrom:'7:00:11'     

     Time readFrom:'24:00:00'     

     Time readFrom:'0:00:00'     

     Time readFrom:'12:00:00'     

     Time readFrom:'0:00:00'     

     Time readFrom:'6:22:00 pm'   

     Time readFrom:'2:00:11 pm'  

     Time readFrom:'7:00:11 am'  

     Time readFrom:'12:00:00 am'  

     Time readFrom:'0:00:00 am'  

     Time readFrom:'24:00:00 am'  

     Time readFrom:'12:00:00 pm'  

     Time readFrom:'0:00:00 pm'   - invalid

     Time readFrom:'24:00:00 pm'  

    "

    "Modified: 8.10.1996 / 19:32:11 / cg"

! !

!Time methodsFor:'accessing'!

day

    "catch day access - Time does not know about it"

    ^ self shouldNotImplement

!

hours

    "return the number of hours since midnight (i.e. 0..23)"

    ^ timeEncoding // 3600

    "

     Time now hours

    "

!

minutes

    "return the number of minutes within the hour (i.e. 0..59)"

    ^ (timeEncoding \\ 3600) // 60

    "

     Time now minutes

    "

!

month 

    "catch month access - Time does not know about it"

    ^ self shouldNotImplement

!

seconds

    "return the number of seconds within the minute (i.e. 0..59)"

    ^ (timeEncoding \\ 3600) \\ 60

    "

     Time now seconds

    "

!

year

    "catch year access - Time does not know about it"

    ^ self shouldNotImplement

! !

!Time methodsFor:'comparing'!

< aTime

    "return true if the argument, aTime is before the receiver"

    ^ timeEncoding < aTime timeEncoding

!

= aTime

    "return true if the argument, aTime represents the same timeOfDay"

    aTime class == self class ifTrue:[

	^ timeEncoding == aTime timeEncoding

    ].

    (aTime species == self species) ifFalse:[^ false].

    ^ self asSeconds == aTime asSeconds

!

> aTime

    "return true if the argument, aTime is after the receiver"

    ^ timeEncoding > aTime timeEncoding

!

hash

    "return an integer useful for hashing on times"

    ^ timeEncoding

! !

!Time methodsFor:'converting'!

asAbsoluteTime

    "return an AbsoluteTime object from the receiver.

     The date components are taken from today."

    |today|

    today := Date today.

    ^ AbsoluteTime year:today year month:today month day:today day

                   hour:self hours minute:self minutes second:self seconds

    "

     Time now asAbsoluteTime

    "

    "Modified: / 13.7.1999 / 12:32:08 / stefan"

!

asSeconds

    "return the number of seconds elapsed since midnight"

    ^ timeEncoding

    "

     Time now asSeconds

    "

!

asTime

    "return a Time object from the receiver - thats the receiver."

    ^ self

! !

!Time methodsFor:'printing & storing'!

print12HourFormatOn:aStream

    "append a printed representation of the receiver to aStream.

     Format is hh:mm:ss am/pm (i.e. 12-hour american format)."

    |h m s ampm|

    h := self hours.

    "/ 0 -> 12 am

    "/ 12 -> 12 pm

    h // 12 == 0 ifTrue:[

        ampm := ' am'.

    ] ifFalse:[

        ampm := ' pm'.

    ].

    h == 0 ifFalse:[

        h := h - 1 \\ 12 + 1.

    ].

    h printOn:aStream.

    aStream nextPut:$:.

    m := self minutes.

    (m < 10) ifTrue:[aStream nextPut:$0].

    m printOn:aStream.

    aStream nextPut:$:.

    s := self seconds.

    (s < 10) ifTrue:[aStream nextPut:$0].

    s printOn:aStream.

    aStream nextPutAll:ampm

    "

     Time now print12HourFormatOn:Transcript. Transcript cr

     (Time now subtractHours:12) print12HourFormatOn:Transcript. Transcript cr

     (Time hour:24 minutes:0 seconds:0) print12HourFormatOn:Transcript. Transcript cr

     (Time hour:12 minutes:0 seconds:0) print12HourFormatOn:Transcript. Transcript cr

     (Time hour:0 minutes:0 seconds:0) print12HourFormatOn:Transcript. Transcript cr

     0 to:24 do:[:h |

         (Time hour:h minutes:0 seconds:0) print12HourFormatOn:Transcript. Transcript cr

     ]

    "

!

print24HourFormatOn:aStream

    "append a printed representation of the receiver to aStream.

     Format is hh:mm:ss (i.e. 24-hour european format)."

    |h m s|

    h := self hours.

    (h < 10) ifTrue:[aStream nextPut:$0].

    h printOn:aStream.

    aStream nextPut:$:.

    m := self minutes.

    (m < 10) ifTrue:[aStream nextPut:$0].

    m printOn:aStream.

    aStream nextPut:$:.

    s := self seconds.

    (s < 10) ifTrue:[aStream nextPut:$0].

    s printOn:aStream

    "

     Time now print24HourFormatOn:Transcript. Transcript cr

    "

!

printOn:aStream

     Format is hh:mm:ss either in 12-hour or 24-hour format.

     depending on the setting of LanguageTerritory.

     I dont know what ST-80 does here (12-hour format ?)"

    LanguageTerritory == #us ifTrue:[

        self print12HourFormatOn:aStream

    ] ifFalse:[

        self print24HourFormatOn:aStream

    ]

    "

     Time now printOn:Transcript. Transcript cr

    "

    "Modified: 22.2.1996 / 16:58:30 / cg"

!

printString12HourFormat

    "return a printed representation in 12 hour format"

    |s|                

    s := WriteStream on:(String new:11).

    self print12HourFormatOn:s.

    ^ s contents

!

printString24HourFormat

    "return a printed representation in 24 hour format"

    |s|

    s := WriteStream on:(String new:8).

    self print24HourFormatOn:s.

    ^ s contents

!

shortPrintString

    "dummy - for now"

    ^ self printString

    "Created: 20.6.1997 / 17:17:01 / cg"

! !

!Time methodsFor:'private'!

fromOSTime:osTime

    "set my time, given an osTime"

    |h m s|

    OperatingSystem computeTimePartsOf:osTime for:[

        :hours :minutes :secs :millis |

        h := hours.

        m := minutes.

        s := secs.

    ].

    self setHours:h minutes:m seconds:s

    "Modified: 1.7.1996 / 15:21:06 / cg"

!

getMilliseconds

    ^ self getSeconds * 1000

!

getSeconds

    ^ timeEncoding

!

setHours:h minutes:m seconds:s

    "set my time given individual values"

    self setSeconds:(((h\\24) * 60 * 60 ) + (m * 60) + s).

!

setMilliseconds:millis

    "set my time given milliseconds since midnight"

    self setSeconds:(millis // 1000)

!

setSeconds:secs

    "set my time given seconds since midnight"

    secs < 0 ifTrue:[

        timeEncoding := (24 * 3600) - (secs negated \\ (24 * 3600))

    ] ifFalse:[

        timeEncoding := secs

    ]

!

timeEncoding

    "the internal encoding is stricktly private, 

     and should not be used outside."

    ^ timeEncoding

!