"{ Encoding: utf8 }"

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

"{ NameSpace: Smalltalk }"

PeekableStream subclass:#PositionableStream

	instanceVariableNames:'collection position readLimit writeLimit'

	classVariableNames:'ZeroPosition InvalidPositionErrorSignal'

	poolDictionaries:''

	category:'Streams'

!

!PositionableStream class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    Instances of PositionableStream allow positioning the read pointer.

    The PositionableStream class also adds methods for source-chunk reading

    and writing, and for filing-in/out of source code.

    This is an abstract class.

    Compatibility Notice:

        In previous versions of ST/X, streams started with a 1-position (i.e. as in collections),

        while ST-80 has always been using 0-based postions for streams and 1-based positions for collections.

        THIS CERTAINLY IS BAD.

        Although this is confusing ST/X has been changed to now also uses 0-based stream positioning.

    [caveat:]

        Basing capabilities like readability/writability/positionability/peekability on inheritance makes

        the class hierarchy ugly and leads to strange and hard to teach redefinitions (aka. NonPositionableStream

        below PositionableStream or ExternalReadStream under WriteStream)

    [author:]

        Claus Gittinger

"

! !

!PositionableStream class methodsFor:'initialization'!

initialize

    ZeroPosition := 0.        "/ changed with stx rel5.1; 

                              "/ rel6.2: no longer used (i.e. 0 has now ben hardcoded)

                              "/ class variable to be eliminated.

    InvalidPositionErrorSignal isNil ifTrue:[

        InvalidPositionErrorSignal := PositionOutOfBoundsError.

        InvalidPositionErrorSignal notifierString:'position out of bounds: '.

    ]

! !

!PositionableStream class methodsFor:'instance creation'!

on:aCollection

    "return a new PositionableStream streaming on aCollection"

    ^ (self basicNew) on:aCollection

!

on:aCollection from:first to:last

    "return a new PositionableStream streaming on aCollection

     from first to last"

    ^ (self basicNew) on:aCollection from:first to:last

!

with:aCollection

    "return a new PositionableStream streaming on aCollection,

     the stream is positioned to the end of the collection."

    ^ (self basicNew) with:aCollection

! !

!PositionableStream class methodsFor:'Signal constants'!

invalidPositionErrorSignal

    "return the signal raised if positioning is attempted to an

     invalid position (i.e. before the begin of the stream or after

     the end)"

    ^ PositionOutOfBoundsError

! !

!PositionableStream class methodsFor:'constants'!

zeroPosition

    "return the number, which marks the initial position.

     Compatibility Notice:

        In previous versions of ST/X, streams started with a 1-position (i.e. as in collections),

        while ST-80 has always been using 0-based postions for streams and 1-based positions for collections.

     Although this is confusing ST/X has been changed to now also use 0-based stream positioning.

    "

    ^ 0

    "Modified: / 13-07-2006 / 20:36:54 / cg"

! !

!PositionableStream class methodsFor:'testing'!

isAbstract

    ^ self == PositionableStream

! !

!PositionableStream methodsFor:'Compatibility-Dolphin'!

endChunk

    self nextPutChunkSeparator

! !

!PositionableStream methodsFor:'Compatibility-ST/V'!

skipTo:anElement

    "ST/V compatibility:

     skip for the element given by the argument, anElement;

     return nil if not found, self otherwise. 

     On a successful match, the next read will return the element after anElement."

    ^ self skipThrough:anElement

    "

     |s|

     s := ReadStream on:'12345678901234567890'.

     s skipTo:$5.

     s copyFrom:1 to:(s position).    

     s upToEnd      

    "

! !

!PositionableStream methodsFor:'Compatibility-Squeak'!

back

        "Go back one element and return it."

        self position == 0 ifTrue: [self positionError].

        self skip: -1.

        ^ self peek

    "Created: / 03-10-2014 / 03:06:31 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

peekBack

        "Return the element at the previous position, without changing position.  Use indirect messages in case self is a StandardFileStream."

        | element |

        element := self back.

        self skip: 1.

        ^ element

    "Created: / 03-10-2014 / 03:06:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!PositionableStream methodsFor:'accessing'!

collection

    "return the underlying collection buffer.

     Notice, that this buffer may become invalid after being retrieved,

     if more data is written to the stream (because a bigger buffer might be

     allocated). Therefore, it should be only used in special situations,

     where an already filled buffer needs to be backpatched later

     (eg. before being sent out to some external stream or socket)"

    ^ collection

    "Modified (comment): / 02-01-2018 / 19:54:37 / stefan"

!

contents

    "return the entire contents of the stream"

    ^ collection

!

peekForAll:aCollection

    "return true and advance if the next elements are the same

     as aCollection. 

     otherwise stay and let the position unchanged"

    |oldPos|

    oldPos := self position.

    (self next:(aCollection size)) = aCollection ifTrue:[

	^ true

    ].

    self position:oldPos.

    ^ false

    "Created: 1.3.1997 / 15:11:25 / cg"

!

readLimit

    "return the read-limit; that's the position at which EOF is returned"

    ^ readLimit

    "Created: / 30.10.1998 / 16:47:04 / cg"

!

readLimit:aNumber

    "set the read-limit; that's the position at which EOF is returned"

    readLimit := aNumber

!

setCollection:newCollection

    collection := newCollection

!

writeLimit:aNumber

    "set the writeLimit; that's the position after which writing is prohibited"

    writeLimit := aNumber

    "

     |s|

     s := WriteStream on:String new.

     s nextPutAll:'hello world'.

     s contents.

     |s|

     s := WriteStream on:String new.

     s writeLimit:5.

     s nextPutAll:'hello world'.

     s contents.

    "

    "Modified: / 04-06-2007 / 17:21:55 / cg"

! !

!PositionableStream methodsFor:'comparing'!

endsBeforePositionWith:aSequenceableCollection

    "answer true, if the elements in aSequenceableCollection

     are at the current end of the stream up to position."

    |sz pos|

    sz := aSequenceableCollection size.

    pos := self position.

    pos < sz ifTrue:[

        ^ false.

    ].

    self contentsSpecies == collection class ifTrue:[

        ^ collection sameContentsFrom:pos+1-sz to:pos as:aSequenceableCollection startingAt:1.

    ].

    self position:pos-sz.

    ^ (self next:sz) = aSequenceableCollection.

    "

        ('' writeStream nextPutAll:'Hello World') endsBeforePositionWith:'World'

        ('' writeStream nextPutAll:'Hello World') endsBeforePositionWith:'Hello World'

        ('' writeStream nextPutAll:'Hello World') endsBeforePositionWith:'Hello Worldx'

        ('' writeStream nextPutAll:'Hello World') endsBeforePositionWith:'Bla'

        ('' writeStream) endsBeforePositionWith:'Bla'

        ('' writeStream) endsBeforePositionWith:''

        ''  endsWith:''

    "

!

isContentsEqualTo:aSequenceableCollection

    "answer true, if the contents of myself from the current position

     to the end is equal to aStringOrByteArray." 

    |sz pos|

    sz := aSequenceableCollection size.

    self remainingSize ~= sz ifTrue:[

        ^ false.

    ].

    self contentsSpecies == collection class ifTrue:[

        pos := self position.

        ^ collection sameContentsFrom:pos+1-sz to:pos as:aSequenceableCollection startingAt:1.

    ].

    ^ super isContentsEqualTo:aSequenceableCollection.

    "Created: / 18-11-2019 / 16:04:59 / Stefan Vogel"

! !

!PositionableStream methodsFor:'non homogenous reading'!

nextBytes:numBytes into:aCollection startingAt:initialIndex

    "return the next numBytes from the stream. If the end is

     reached before, only that many bytes are copied into the

     collection.

     Returns the number of bytes that have been actually read.

     The receiver must support reading of binary bytes.

     Notice: this method is provided here for protocol completeness

             with externalStreams - it is normally not used with other

             streams."

    |max|

    (collection isSingleByteCollection

     and:[aCollection class == collection class or:[aCollection isSingleByteCollection]]

    ) ifTrue:[

        "do it the fast way"

        max := (readLimit - position) min: numBytes.

        aCollection

            replaceBytesFrom:initialIndex

            to:(initialIndex + max - 1)

            with:collection

            startingAt:position+1.

        position := position + max.

        ^ max

    ].

    "do it the hard way"

    ^ super nextBytes:numBytes into:aCollection startingAt:initialIndex

    "

     |s n buffer|

     buffer := ByteArray new:10.

     s := ReadStream on:#[1 2 3 4 5 6 7 8 9].

     s next:3.

     n := s nextBytes:9 into:buffer startingAt:1.

     Transcript showCR:('n = %1; buffer = <%2>' bindWith:n with:buffer)

    "

    "Modified (comment): / 29-01-2018 / 14:44:20 / mawalch"

! !

!PositionableStream methodsFor:'obsolete positioning'!

position0Based

    <resource: #obsolete>

    "return the read position 0-based"

    ^ self position

!

position1Based

    <resource: #obsolete>

    "return the read position 1-based"

    ^ self position + 1

! !

!PositionableStream methodsFor:'positioning'!

backStep

    "move backward read position by one"

    self position:(self position - 1)

!

match: subCollection

    "Set the access position of the receiver to be past the next occurrence of the subCollection. 

     Answer whether subCollection is found.  

     No wildcards, and case does matter."

    | pattern startMatch |

    pattern := ReadStream on: subCollection.

    startMatch := nil.

    [pattern atEnd] whileFalse: [

        self atEnd ifTrue: [^ false].

        (self next) = (pattern next) 

            ifTrue: [pattern position == 1 ifTrue: [startMatch := self position]]

            ifFalse: [

                pattern position: 0.

                startMatch ifNotNil: [

                    self position: startMatch.

                    startMatch := nil

                ]

            ]

    ].

    ^ true

    "

     'abc def ghi' readStream match:'def'; upToEnd

    "

!

position

    "return the read position (0-based)"

    ^ position

!

position0Based:index0Based

    <resource: #obsolete>

    "set the read (or write) position"

    self position:index0Based

!

position1Based:index1Based

    <resource: #obsolete>

    "set the read (or write) position"

    self position:(index1Based - 1)

    "

     |s|

     s := '1234567890' readStream.

     s next:5.

     s position:1.

     s next:7.       

    "

    "

     |s|

     s := '' writeStream.

     s nextPutAll:'1234567890'.

     s position:5.

     s nextPutAll:'abcdefg'.

     s contents 

    "

    "

     |s|

     s := '' writeStream.

     s nextPutAll:'1234567890'.

     s position:0.

     s nextPutAll:'abcdefg'.

     s contents 

    "

!

position:index0Based

    "set the read (or write) position"

    ((index0Based > readLimit) or:[index0Based < 0]) ifTrue: [^ self positionError:index0Based].

    position := index0Based

!

reset

    "set the read position to the beginning of the collection"

    position := 0.

    "

     |s|

     s := 'hello world' readStream.

     Transcript showCR:(s next:5).

     s reset.

     Transcript showCR:(s next:10).

    "

!

resetPosition

    <resource: #obsolete>

    "set the read position to the beginning of the collection"

    position := 0

    "

     |s|

     s := 'hello world' readStream.

     Transcript showCR:(s next:5).