"

 COPYRIGHT (c) 1998 by eXept Software AG

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

IdentityDictionary subclass:#UserPreferences

	instanceVariableNames:''

	classVariableNames:'CurrentPreferences DefaultPreferences'

	poolDictionaries:''

	category:'System-Support'

!

!UserPreferences class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1998 by eXept Software AG

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    A Dictionary for user preference values.

    For non-existing keys, either a defaultValue (false),

    or the value from a defaultDictionary is returned.

    This will eventually keep track of ALL user preferences.

    For now, not all preferences are found here -

    (some of them are currently spread over the system - especially, in Class-Variables)

    - but this will change over time.

    If more prefs are added, think about adding a corresponding UI to the SystemSettingsDialog too.

    UserPreferences current at:#foo

"

! !

!UserPreferences class methodsFor:'initialization'!

initializeDefaultPreferences

    DefaultPreferences := self new.

    Color isNil "Smalltalk isStandAloneApp" ifTrue:[

        ^ self.

    ].

    #(

        #useNewChangesBrowser           false

        #useNewInspector                false

        #showClockInLauncher            true

        #autoFormatting                 false

        #syntaxColoring                 true

        #fullSelectorCheck              false

        #defaultSyntaxColor             (Color black)

        #defaultSyntaxEmphasis          normal

        #errorColor                     (Color red)

        "/ #commentColor                   (Color 12.5 12.5 100)

        "/ #constantColor                  (Color 25 0 0)

        #commentEmphasis                normal

        #methodSelectorEmphasis         bold

        #selectorEmphasis               bold

        #unimplementedSelectorColor     (Color red)

        #unimplementedSelectorEmphasis  normal

"/ I prefer red-underwave over red identifier ...

"/        #badIdentifierColor             (Color red)

        #instVarIdentifierColor         (Color 33 0 33)

"/        #jsKeywordColor                 (Color black)

        #jsKeywordEmphasis              bold

        #jsKeywordColor                 (Color 33 33 0)

        #controlFlowSelectorColor       (Color 0 0 100)

        #commentColor                   (Color 0 50 0)

        #constantColor                  (Color 64 8 8)

     ) pairWiseDo:[:k :v |

        DefaultPreferences at:k put:(v decodeAsLiteralArray).

    ].

    "/ I prefer red-underwave over red identifier ...

    DefaultPreferences at:#badIdentifierEmphasis put:(Array with:#underwave with:(#underlineColor->Color red)).

    "

     self initializeDefaultPreferences

    "

    "Modified: / 07-12-2006 / 17:08:38 / cg"

! !

!UserPreferences class methodsFor:'accessing'!

current

    CurrentPreferences isNil ifTrue:[

	CurrentPreferences := self new.

	CurrentPreferences addAll:self default.

	CurrentPreferences flyByHelpSettingChanged.

    ].

    ^ CurrentPreferences.

    "

     CurrentPreferences := nil

    "

!

default

    DefaultPreferences isNil ifTrue:[

	self initializeDefaultPreferences

    ].

    ^ DefaultPreferences.

    "

     DefaultPreferences := nil.

    "

!

reset

    "resets the CurrentPreferences to its default values"

    CurrentPreferences := nil

!

syntaxColorKeys

    "returns the keys of syntax color items"

    ^#(

	argumentIdentifierColor

	  argumentIdentifierEmphasis

	booleanConstantColor

	  booleanConstantEmphasis

	bracketColor

	  bracketEmphasis

	classVariableIdentifierColor

	  classVariableIdentifierEmphasis

	constantColor

	  constantEmphasis

	controlFlowSelectorColor

	  controlFlowSelectorEmphasis

	commentColor

	  commentEmphasis

	defaultSyntaxColor

	  defaultSyntaxEmphasis

	errorColor

	globalIdentifierColor

	  globalIdentifierEmphasis

	globalClassIdentifierColor

	  globalClassIdentifierEmphasis

	hereColor

	  hereEmphasis

	identifierColor

	  identifierEmphasis

	instVarIdentifierColor

	  instVarIdentifierEmphasis

	localIdentifierColor

	  localIdentifierEmphasis

	methodSelectorColor

	  methodSelectorEmphasis

	poolVariableIdentifierColor

	  poolVariableIdentifierEmphasis

	returnColor

	  returnEmphasis

	selectorColor

	  selectorEmphasis

	selfColor

	  selfEmphasis

	stringColor

	  stringEmphasis

	superColor

	  superEmphasis

	symbolColor

	  symbolEmphasis

	thisContextColor

	  thisContextEmphasis

	unknownIdentifierColor

	  unknownIdentifierEmphasis

	unimplementedSelectorColor

	  unimplementedSelectorEmphasis

    )

    "Modified: / 08-09-2006 / 16:06:54 / cg"

!

syntaxColorNames

    "returns the syntax colors for the settings in the launcher"

"/ warning, the strings below are presented to the user

"/ as the syntax-color boxes comboList - however, they are

"/ also used (without separators) as key into myself.

"/ Therefore, do not change the strings below.

"/ I know - this is bad coding ....

^#(

'Argument Identifier Color'

'Boolean Constant Color'

'Bracket Color'

'Class Variable Identifier Color'

'Constant Color'

'Control Flow Selector Color'

'Comment Color'

'Global Identifier Color'

'Global Class Identifier Color'

'Here Color'

'Identifier Color'

'InstVar Identifier Color'

'Local Identifier Color'

'Method Selector Color'

'Pool Variable Identifier Color'

'Return Color'

'Selector Color'

'Self Color'

'String Color'

'Super Color'

'Symbol Color'

'This Context Color'

'Unknown Identifier Color'

'Unimplemented Selector Color'

)

    "Modified: / 08-09-2006 / 16:07:36 / cg"

! !

!UserPreferences class methodsFor:'accessing defaultPrefs'!

defaultSettingsFilename

    ^ 'settings.stx'

!

fileBrowserClass

    ^ self current fileBrowserClass

    "

     UserPreferences fileBrowserClass

    "

!

systemBrowserClass

    ^ self current systemBrowserClass

    "

     UserPreferences systemBrowserClass

    "

!

versionDiffViewerClass

    ^ self current versionDiffViewerClass

    "

     UserPreferences versionDiffViewerClass

    "

! !

!UserPreferences methodsFor:'acccesing-locale'!

decimalPointCharacter

    "toDo: migrate from ClassVar in Number;

     use this for new applications"

    ^ $.

!

thousandsSeparatorCharacter

    "toDo: migrate from ClassVar elsewhere;

     use this for new applications"

    ^ $'

! !

!UserPreferences methodsFor:'accessing'!

at:key put:value

    |classNameToCheck classToCheck|

    value == true ifTrue:[

	key == #useNewVersionDiffBrowser ifTrue:[

	    classNameToCheck := #'VersionDiffBrowser'.

	].

	key == #useNewChangesBrowser ifTrue:[

	    classNameToCheck := #'NewChangesBrowser'.

	].

	key == #useNewFileBrowser ifTrue:[

	    classNameToCheck := #'FileBrowserV2'.

	].

	key == #useNewSystemBrowser ifTrue:[

	    classNameToCheck := #'Tools::NewSystemBrowser'.

	].

	key == #useNewInspector ifTrue:[

	    classNameToCheck := #'NewInspector::NewInspectorView'.

	].

    ].

    classNameToCheck notNil ifTrue:[

	classToCheck := Smalltalk at:classNameToCheck.

	classToCheck isNil ifTrue:[

	    ('UserPreferences [warning]: no class ' , classNameToCheck , ' class in system.') errorPrintCR.

	] ifFalse:[

	    Autoload autoloadFailedSignal handle:[:ex |

		'UserPreferences [warning]: autoload of ' , classNameToCheck , ' failed.' errorPrintCR.

	    ] do:[

		classToCheck autoload.

	    ]

	]

    ].

    ^ super at:key put:value

! !

!UserPreferences methodsFor:'accessing - desktop'!

editorCommand

    ^self at:#'desktop.editor-command' ifAbsent:[ nil ]

    "Created: / 11-08-2009 / 17:05:50 / Jan Vrany <vranyj1@fel.cvut.cz>"

!

editorCommand: aString

    self at:#'desktop.editor-command' put: aString

    "Created: / 11-08-2009 / 17:06:23 / Jan Vrany <vranyj1@fel.cvut.cz>"

! !

!UserPreferences methodsFor:'accessing-misc-communication'!

dotNetBridgeRunsInIDE

    ^ self at:#dotNetBridgeRunsInIDE ifAbsent:false

!

dotNetBridgeRunsInIDE:aBoolean

    ^ self at:#dotNetBridgeRunsInIDE put:aBoolean

!

dotNetBridgeVerbose

    ^ self at:#dotNetBridgeVerbose ifAbsent:false

    "

     UserPreferences current dotNetBridgeVerbose

    "

!

dotNetBridgeVerbose:aBoolean

    ^ self at:#dotNetBridgeVerbose put:aBoolean

!

smtpServerName

    ^ self at:#smtpServerName ifAbsent:nil

    "Created: / 20-09-2007 / 15:59:20 / cg"

!

smtpServerName:aHostnameString

    ^ self at:#smtpServerName put:aHostnameString

    "

     UserPreferences current smtpServerName

     UserPreferences current smtpServerName:'mailhost'

    "

    "Created: / 20-09-2007 / 15:59:58 / cg"

! !

!UserPreferences methodsFor:'accessing-pref''d tools'!

changesBrowserClass

    self useNewChangesBrowser ifTrue:[

	^ (NewChangesBrowser ? ChangesBrowser)

    ].

    ^ ChangesBrowser

    "Created: / 17.10.1998 / 14:37:46 / cg"

!

fileBrowserClass

    self useNewFileBrowser ifTrue:[

	^ (FileBrowserV2 ? FileBrowser)

    ].

    ^ FileBrowser

    "

     UserPreferences current fileBrowserClass

    "

!

flyByHelpActive

    ^ self at:#flyByHelpActive ifAbsent:true "(FlyByHelp notNil and:[FlyByHelp isActive])"

!

flyByHelpActive:aBoolean

    aBoolean ~~ self flyByHelpActive ifTrue:[

	self at:#flyByHelpActive put:aBoolean.

	self flyByHelpSettingChanged.

    ].

!

inspectorClassSetting

    self useNewInspector ifTrue:[

	^ (NewInspector::NewInspectorView ? InspectorView)

    ].

    ^ InspectorView

    "Modified: / 12.11.2001 / 15:47:35 / cg"

    "Created: / 12.11.2001 / 15:49:00 / cg"

!

showTipOfTheDayAtStartup

    ^ self at:#showTipOfTheDayAtStartup ifAbsent:false

!

showTipOfTheDayAtStartup:aBoolean

    self at:#showTipOfTheDayAtStartup put:aBoolean.

!

systemBrowserClass

    self useNewSystemBrowser ifTrue:[

	^ ((Tools::NewSystemBrowser ? NewSystemBrowser) ? SystemBrowser)

    ].

    ^ SystemBrowser

!

useNativeFileDialog

    "using native file dialog"

    ^ self at:#useNativeFileDialog ifAbsent:false

!

useNativeFileDialog:aBoolean

    "using native file dialog (if available)"

    self at:#useNativeFileDialog put:aBoolean

    "

     UserPreferences current useNativeFileDialog:true

     UserPreferences current useNativeFileDialog:false

     UserPreferences current useNativeFileDialog

    "

!

useNewChangesBrowser

    "using new or old change browser"

    ^ self at:#useNewChangesBrowser ifAbsent:false

    "Modified: / 13.10.1998 / 15:53:05 / cg"

!

useNewChangesBrowser:aBoolean

    "using new or old changeBrowser"

    self at:#useNewChangesBrowser put:aBoolean

    "

     UserPreferences current useNewChangesBrowser

    "

    "Modified: / 13.10.1998 / 15:53:21 / cg"

!

useNewFileBrowser

    "using new or old version diff viewer"