"

 COPYRIGHT (c) 1998 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

IdentityDictionary subclass:#UserPreferences

	instanceVariableNames:''

	classVariableNames:'CurrentPreferences DefaultPreferences'

	poolDictionaries:''

	category:'System-Support'

!

!UserPreferences class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1998 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    A Dictionary for user preference values.

    For non-existing keys, either a defaultValue (false),

    or the value from a defaultDictionary is returned.

    This will eventually keep track of ALL user preferences.

    (which are currently spread over the system).

    For now, only a few preferences are found here - but this

    will change over time.

    UserPreferences current at:#foo

"

! !

!UserPreferences class methodsFor:'initialization'!

initializeDefaultPreferences

    DefaultPreferences := self new.

    #(

        #useNewChangesBrowser           false

        #useNewInspector                false

        #autoFormatting                 false

        #syntaxColoring                 true

        #fullSelectorCheck              false

        #defaultSyntaxColor             (Color black)

        #defaultSyntaxEmphasis          normal

        #errorColor                     (Color red)

        #commentColor                   (Color 12.5 12.5 100)

        #commentEmphasis                normal

        #methodSelectorEmphasis         bold

        #selectorEmphasis               bold

        #unimplementedSelectorColor     (Color red)

        #unimplementedSelectorEmphasis  normal

"/ I prefer red-underwave over red identifier ...

"/        #badIdentifierColor             (Color red)

        #constantColor                  (Color 25 0 0)

        #showClockInLauncher            true

     ) pairWiseDo:[:k :v |

        DefaultPreferences at:k put:v decodeAsLiteralArray.

    ].

"/ I prefer red-underwave over red identifier ...

    DefaultPreferences at:#badIdentifierEmphasis put:(Array with:#underwave with:(#underlineColor->Color red)).

    "

     self initializeDefaultPreferences

    "

    "Modified: / 4.2.2000 / 20:06:53 / cg"

! !

!UserPreferences class methodsFor:'accessing'!

current

    CurrentPreferences isNil ifTrue:[

        CurrentPreferences := self new.

        CurrentPreferences declareAllFrom:(self default).

    ].

    ^ CurrentPreferences.

    "Created: / 31.3.1998 / 13:43:03 / cg"

!

default

    DefaultPreferences isNil ifTrue:[

        self initializeDefaultPreferences

    ].

    ^ DefaultPreferences.

    "

     DefaultPreferences := nil.

    "

!

reset

    "resets the CurrentPreferences to its default values"

    CurrentPreferences := nil

!

syntaxColorKeys

    "returns the keys of syntax color items"

    ^#(

        argumentIdentifierColor

          argumentIdentifierEmphasis

        booleanConstantColor

          booleanConstantEmphasis

        bracketColor

          bracketEmphasis

        classVariableIdentifierColor

          classVariableIdentifierEmphasis

        constantColor

          constantEmphasis

        commentColor

          commentEmphasis

        defaultSyntaxColor

          defaultSyntaxEmphasis

        errorColor

        globalIdentifierColor

          globalIdentifierEmphasis

        globalClassIdentifierColor

          globalClassIdentifierEmphasis

        hereColor

          hereEmphasis

        identifierColor

          identifierEmphasis

        instVarIdentifierColor

          instVarIdentifierEmphasis

        localIdentifierColor

          localIdentifierEmphasis

        methodSelectorColor

          methodSelectorEmphasis

        returnColor

          returnEmphasis

        selectorColor

          selectorEmphasis

        selfColor

          selfEmphasis

        stringColor

          stringEmphasis

        superColor

          superEmphasis

        symbolColor

          symbolEmphasis

        thisContextColor

          thisContextEmphasis

        unknownIdentifierColor

          unknownIdentifierEmphasis

        unimplementedSelectorColor

          unimplementedSelectorEmphasis

    )

    "Modified: / 5.1.1980 / 00:48:09 / cg"

!

syntaxColorNames

    "returns the syntax colors for the settings in the launcher"

"/ warning, the strings below are presented to the user

"/ as the syntax-color boxes comboList - however, they are

"/ also used (without separators) as key into myself.

"/ Therefore, do not change the strings below.

"/ I know - this is bad coding ....

^#(

'Argument Identifier Color'

'Boolean Constant Color'

'Bracket Color'

'Class Variable Identifier Color'

'Constant Color'

'Comment Color'

'Global Identifier Color'

'Global Class Identifier Color'

'Here Color'

'Identifier Color'

'InstVar Identifier Color'

'Local Identifier Color'

'Method Selector Color'

'Return Color'

'Selector Color'

'Self Color'

'String Color'

'Super Color'

'Symbol Color'

'This Context Color'

'Unknown Identifier Color'

'Unimplemented Selector Color'

)

    "Modified: / 5.1.1980 / 00:48:09 / cg"

! !

!UserPreferences methodsFor:'accessing-pref''d tools'!

changesBrowserClass

    self useNewChangesBrowser ifTrue:[

        ^ NewChangesBrowser

    ].

    ^ ChangesBrowser

    "Created: / 17.10.1998 / 14:37:46 / cg"

!

inspectorClass

    self useNewInspector ifTrue:[

        ^ NewInspector::NewInspectorView

    ].

    ^ InspectorView

!

systemBrowserClass

    self useNewSystemBrowser ifTrue:[

        ^ NewSystemBrowser

    ].

    ^ SystemBrowser

!

useNewChangesBrowser

    "using new or old change browser"

    ^ self at:#useNewChangesBrowser ifAbsentPut:false

    "Modified: / 13.10.1998 / 15:53:05 / cg"

!

useNewChangesBrowser:aBoolean

    "using new or old changeBrowser"

    aBoolean ifTrue:[

        NewChangesBrowser autoload

    ].

    ^ self at:#useNewChangesBrowser put:aBoolean

    "

     UserPreferences current useNewChangesBrowser

    "

    "Modified: / 13.10.1998 / 15:53:21 / cg"

!

useNewInspector

    "using new or old inspector"

    ^ self at:#useNewInspector ifAbsentPut:false

    "

     UserPreferences current useNewInspector

    "

    "Modified: / 17.10.1998 / 14:45:12 / cg"

!

useNewInspector:aBoolean

    "using new or old inspector"

    aBoolean ifTrue:[

        NewInspector::NewInspectorView autoload

    ].

    ^ self at:#useNewInspector put:aBoolean

    "

     UserPreferences current useNewInspector

    "

!

useNewSystemBrowser

    "using new or old system browser"

    ^ self at:#useNewSystemBrowser ifAbsentPut:false

    "Modified: / 13.10.1998 / 15:53:05 / cg"

!

useNewSystemBrowser:aBoolean

    "using new or old systemBrowser"

    aBoolean ifTrue:[

        NewSystemBrowser isNil ifTrue:[

            'UserPreferences [warning]: no NewSystemBrowser class in system' infoPrintCR.

            ^ self.

        ].

        NewSystemBrowser autoload

    ].

    ^ self at:#useNewSystemBrowser put:aBoolean

    "

     UserPreferences current useNewSystemBrowser:true

    "

    "Modified: / 13.10.1998 / 15:53:21 / cg"

!

useNewVersionDiffBrowser

    "using new or old version diff viewer"

    ^ self at:#useNewVersionDiffBrowser ifAbsentPut:false

    "Modified: / 13.10.1998 / 15:53:05 / cg"

!

useNewVersionDiffBrowser:aBoolean

    "using new or old useNewVersionDiffBrowser"

    aBoolean ifTrue:[

        VersionDiffBrowser autoload

    ].

    ^ self at:#useNewVersionDiffBrowser put:aBoolean

    "

     UserPreferences current useNewVersionDiffBrowser

    "

    "Modified: / 13.10.1998 / 15:53:21 / cg"

!

versionDiffViewerClass

    self useNewVersionDiffBrowser ifTrue:[

        ^ VersionDiffBrowser

    ].

    ^ DiffTextView

! !

!UserPreferences methodsFor:'accessing-prefs'!

autoFormatting

    "return the flag which controls automatic formatting of code (in some browsers)

     Notice, the regular browser does not (yet) do automatic formating."

    ^ self at:#autoFormatting ifAbsentPut:false

    "

     UserPreferences current autoFormatting

    "

    "Created: / 4.2.2000 / 20:08:08 / cg"

    "Modified: / 5.2.2000 / 15:38:33 / cg"

!

autoFormatting:aBoolean

    "turn on/off automatic formatting of code (in some browsers);

     Notice, the regular browser does not (yet) do automatic formating."

    ^ self at:#autoFormatting put:aBoolean

    "

     UserPreferences current autoFormatting:true

     UserPreferences current autoFormatting:false

    "

    "Created: / 4.2.2000 / 20:08:26 / cg"

    "Modified: / 5.2.2000 / 15:38:20 / cg"

!

beepEnabled

    "return the flag which controls the beeper"

    ^ self at:#beepEnabled ifAbsentPut:true

    "

     UserPreferences current beepEnabled

    "

    "Modified: / 11.9.1998 / 00:09:59 / cg"

    "Created: / 3.12.1999 / 17:09:49 / ps"

!

beepEnabled:aBoolean

    "set/clear the flag which controls the beeper"

    ^ self at:#beepEnabled put:aBoolean

    "

     UserPreferences current beepEnabled:false

    "

    "Modified: / 11.9.1998 / 00:09:59 / cg"

    "Created: / 3.12.1999 / 17:10:27 / ps"

!

focusFollowsMouse

    "return the flag which controls if the keyboard focus should

     follow the mouse (as in X) - as opposed to click mode (as in MS-win).

     This only affects certain widgets (EditFields, EditTextViews and SelectionInListViews).

     The returned value has 3 states: true/false and nil, which means: as defined in styleSheet."

    ^ self at:#focusFollowsMouse ifAbsent:nil

    "

     UserPreferences current focusFollowsMouse

    "

    "Modified: / 11.9.1998 / 00:09:59 / cg"

!

focusFollowsMouse:aBooleanOrNil

    "set/clear the flag which controls if the keyboard focus should

     follow the mouse (as in X) - as opposed to click mode (as in MS-win).

     This only affects certain widgets (EditFields, EditTextViews and SelectionInListViews).

     Allowed are: true/false and nil, which means: as defined in styleSheet."

    ^ self at:#focusFollowsMouse put:aBooleanOrNil

    "

     UserPreferences current focusFollowsMouse:true

     UserPreferences current focusFollowsMouse:false

     UserPreferences current focusFollowsMouse

    "

    "Modified: / 11.9.1998 / 00:09:59 / cg"

!

functionKeySequences

    "return the collection of function-key macros.

     Thats a dictionary, which assigns code to F-keys"

    ^ self at:#functionKeySequences ifAbsentPut:[Dictionary new]

    "

     UserPreferences current functionKeySequences

    "

    "Modified: / 11.9.1998 / 00:09:59 / cg"

!

opaqueVariablePanelResizing

    "return the flag which controls if variable panel resizing should be done

     animated (opaque)"

    ^ self at:#opaqueVariablePanelResizing ifAbsentPut:false

    "

     UserPreferences current opaqueVariablePanelResizing

    "

    "Modified: / 11.9.1998 / 00:09:59 / cg"

!

opaqueVariablePanelResizing:aBoolean

    "change the flag which controls if variable panel resizing should be done

     animated (opaque)"

    ^ self at:#opaqueVariablePanelResizing put:aBoolean

    "

     UserPreferences current opaqueVariablePanelResizing:true

    "

    "Modified: / 11.9.1998 / 00:09:59 / cg"

!