"

 COPYRIGHT (c) 1988 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

String subclass:#Symbol

       instanceVariableNames:''

       classVariableNames:''

       poolDictionaries:''

       category:'Collections-Text'

!

Symbol comment:'

COPYRIGHT (c) 1988 by Claus Gittinger

              All Rights Reserved

Symbols represent unique strings - every symbol with same printString

exists exactly once in the system; Symbols are used for selectors, global

variable-keys etc.

'!

!Symbol class methodsFor:'instance creation'!

XXXbasicNew:size

    "catch instance creation - symbols are not created with new"

    self error:'symbols may not be created with new:'

! 

basicNew:size

    "redefined to return a string instead of a symbol -

     this allows all copy methods inherited from String to

     return strings containing the symbols characters.

     Real symbols are only created with intern: or asSymbol."

    ^ String new:size

!

new:size

    "redefined to return a string instead of a symbol -

     this allows all copy methods inherited from String to

     return strings containing the symbols characters.

     Real symbols are only created with intern: or asSymbol."

    ^ String new:size

!

intern:aString

    "return a unique symbol with printname taken from the String-argument"

%{  /* NOCONTEXT */

    if (__isSymbol(aString)) {

        RETURN (aString);

    }

    if (__isString(aString)) {

        RETURN ( _MKSYMBOL(_stringVal(aString), (OBJ *)0, __context) );

    }

%}

.

    ^ self mustBeString

!

internCharacter:aCharacter

    "return a unique symbol with printname taken from the Character-argument"

    ^ self intern:(aCharacter asString)

! !

!Symbol class methodsFor:'queries'!

hasInterned:aString ifTrue:trueBlock

    "for ST-80 compatibility - if the argument, aString is known

     as Symbol, evaluate the block with the corresponding symbol

     as argument and return true; otherwise return false"

    aString knownAsSymbol ifTrue:[

        trueBlock value:(aString asSymbol).

        ^ true

    ].

    ^ false

! !

!Symbol methodsFor:'accessing'!

basicAt:index put:something

    "report an error - symbols may not be changed"

    self error:'symbols may not be changed'

!

at:index put:something

    "report an error - symbols may not be changed"

    self error:'symbols may not be changed'

! !

!Symbol methodsFor:'copying'!

deepCopyUsing:aDictionary

    "return a copy of myself

     - reimplemented here since symbols are unique"

     ^ self

!

deepCopy

    "return a copy of myself

     - reimplemented here since symbols are unique"

     ^ self

!

simpleDeepCopy

    "return a copy of myself

     - reimplemented here since symbols are unique"

     ^ self

! !

!Symbol methodsFor:'converting'!

asString

    "return a string with printname taken from mine"

    ^ self printString

!

asSymbol

    "I am a symbol - just return myself"

    ^ self

! !

!Symbol methodsFor:'misc'!

species

    ^ String

! !

!Symbol class methodsFor:'binary storage'!

binaryDefinitionFrom: stream manager: manager

    ^ self intern: (super binaryDefinitionFrom: stream manager: manager)

! !

!Symbol methodsFor:'printing & storing'!

printString

%{

    RETURN ( _MKSTRING(_stringVal(self) COMMA_CON) );

%}

!

printOn:aStream

    "aStream nextPut:$#."

!

displayString

    "return a string for displaying the receiver"

    ^ self storeString

!

storeString

    "return a String for storing the receiver"

    (self at:1) isLetter ifTrue:[

        2 to:self size do:[:index |

            (self at:index) isAlphaNumeric ifFalse:[

                ^ '#''' , self , ''''

            ].

        ].

        ^ '#' , self

    ].

    ^ '#''' , self , ''''

!

storeOn:aStream

    "store myself on a stream"

    aStream nextPutAll:(self storeString)

! !