"

 COPYRIGHT (c) 2006 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

"{ NameSpace: Smalltalk }"

ProjectDefinition subclass:#ApplicationDefinition

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	category:'System-Support-Projects'

!

!ApplicationDefinition class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2006 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    subclasses provide the info on the contents of a package/project and

    how to build executables and class libraries and how to load/unload packages.

    Actually, subclasses MUST be subclasses of the two abstract classes LibraryDefinition or

    ApplicationDefinition. These two know how to generate all required help files for the

    make/build/load process.

    File creation is driven by file templates which are expanded using strings from the file mappings.

    Concrete definition classes MUST redefine:

        classNamesAndAttributes

                                list of classes which are part of the dll/exe

        extensionMethodNames

                                list of extension methods

        startupClassName / startupSelector

                                class and selector with which the show starts

        buildTarget             name of the generated exe-file

    should redefine:

        preRequisites           list of required packages

        iconFileName            name of a .ico file containing the applications icon

        companyName             name of your company - will be shown by windows explorer

                                as attribute of a .dll or .exe

        description             short description; shown by windows explorer

        legalCopyright          copyright message; shown by windows explorer

        productName             product name; shown by windows explorer

        applicationName         app name; shown by windows explorer

    might redefine:    

        isConsoleApplication    if true, windows-build generates a console app.

        isGUIApplication        if true, the GUI framework is linked in

                                (as opposed to a non-GUI server-like executable)

    The above info might be outdated a bit - see stx_projects_smalltalk as a concrete example.

    [author:]

        Felix Madrid

        Claus Gittinger

    [see also:]

        stx_projects_smalltalk

        stx_libbasic

        stx_libbasic2

"

! !

!ApplicationDefinition class methodsFor:'accessing'!

appSourcesProjects

    "Returns only the application projects (which are included in the application module)"

    ^ self effectivePreRequisites

        select:[:each |

            (self moduleFor: each) = self module

        ].

    "

     bosch_dapasx_application appSourcesProjects

    "

!

startupClass

    "the class, but only if loaded"

    |cls|

    Error 

        handle:[:ex | 

            cls := nil

        ] 

        do:[

            |clsName|

            clsName := self startupClassName.

            cls := Smalltalk classNamed:clsName.

        ].

    ^ cls

    "Created: / 20-07-2012 / 16:37:36 / cg"

    "Modified: / 28-11-2017 / 14:02:11 / cg"

!

stxSourcesProjects

    "Returns only the required STX projects (which are included in the STX module)"

    ^ self effectivePreRequisites select:[:each | 

        (self moduleFor: each) = (self moduleFor: #stx)

    ].

    "

        bosch_dapasx_application stxSourcesProjects

    "

    "

    #(

       'libbasic' 

       'libbasic2' 

       'libcomp' 

       'libview' 

       'libview2'

       'libwidg' 

       'libwidg2' 

       'libtool' 

       'libtool2' 

       'libhtml' 

       'libui'

    )

    "

! !

!ApplicationDefinition class methodsFor:'code generation'!

forEachMethodsCodeToCompileDo:aTwoArgBlock ignoreOldDefinition:ignoreOldDefinition

    "redefined to add application stuff, such as definitions for the app-icon, 

     startup class and installation directory"

    |spec1 spec2|

    super forEachMethodsCodeToCompileDo:aTwoArgBlock ignoreOldDefinition:ignoreOldDefinition.

    spec1 := #().

    self isGUIApplication ifTrue:[

        spec1 := 

            #(

                (applicationIconFileNameWindows applicationIconFileNameWindows_code 'description - project information')

                (applicationIconFileNameLinux applicationIconFileNameLinux_code 'description - project information')

                (applicationIconFileNameOSX applicationIconFileNameOSX_code 'description - project information')

            )

    ].

    spec2 := 

        #(

            "/ Not needed, done in ProjectDefinition>>forEachMethodsCodeToCompileDo:ignoreOldDefinition:

            "/ (subProjects subProjects_code 'description')

            (productInstallDirBaseName productInstallDirBaseName_code 'description - project information')

            (startupClassName startupClassName_code 'description - startup')

            (startupSelector startupSelector_code 'description - startup')

        ).

    (spec1 , spec2) triplesDo:[:selector :codeMethodSelector :category|

        (self class includesSelector:selector) ifFalse:[

            aTwoArgBlock

                value: (self perform:codeMethodSelector)

                value: category.

        ].

    ].

    "Created: / 10-08-2006 / 16:35:47 / cg"

    "Modified: / 30-08-2006 / 19:03:48 / cg"

    "Modified: / 25-11-2013 / 13:51:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

startupClassName_code

    "generate code that answers the startupClass."

    |classes startClasses mainClasses appClasses|

    classes := self classNamesAndAttributes 

                collect:[:nmOrPair | 

                            |nm| 

                            nm := nmOrPair isArray ifTrue:[nmOrPair first] ifFalse:[nmOrPair].

                            Smalltalk classNamed:nm

                        ] 

                thenSelect:[:cls | cls notNil and:[cls isProjectDefinition not ]].

    mainClasses := classes select:[:each | each theMetaclass includesSelector:#main ].

    mainClasses size == 1 ifTrue:[

        ^ self startupClassName_codeFor:(mainClasses first name)

    ].

    mainClasses isEmpty ifTrue:[

        startClasses := classes select:[:each | each theMetaclass includesSelector:#start ].

        startClasses size == 1 ifTrue:[

            ^ self startupClassName_codeFor:(startClasses first name)

        ].

        startClasses isEmpty ifTrue:[

            appClasses := classes select:[:each | each isSubclassOf:ApplicationModel ].

            appClasses size == 1 ifTrue:[

                ^ self startupClassName_codeFor:(appClasses first name)

            ].

        ]

    ].

    ^ 

'startupClassName

    "the name of the class which starts the show in its <startupSelector> method.

     Usually, the name of a subclass of StandAloneStartup."

    self error:''undefined startupClass''.

    ^ ''<name of class here>''

'

    "Modified: / 27-12-2006 / 11:43:34 / cg"

!

startupClassName_codeFor:aClassName

    "code that answers aClassName as the startupClass."

    ^ 

'startupClassName

    "the class that starts the show in its startupSelector method"

    ^ ''',aClassName,'''

'

    "Created: / 05-09-2006 / 13:40:32 / cg"

!

startupSelector_code

    "generate code that answers the startupSelector.

     Checks if #open or #start are to be used for the startupClass."

    |cls sel|

    cls := self startupClass.

    sel := #start.

    cls notNil ifTrue:[

        (cls respondsTo:#open) ifTrue:[

            sel := #open

        ].

    ].

    ^ self startupSelector_codeFor:sel

    "Modified (comment): / 28-11-2017 / 14:01:56 / cg"

!

startupSelector_codeFor:aSelector

    "generate code that answers aSelector as the startupSelector."

    ^ 

'startupSelector

    "the message that is sent to the startupClass to start the show"

    ^ #''',aSelector,'''        

'

    "Created: / 05-09-2006 / 13:41:01 / cg"

    "Modified: / 15-12-2006 / 14:10:11 / cg"

!

subProjects_code        

    "generate code which returns a collection of subproject names."

    |subProjects|

    subProjects := 

        (self siblingsAreSubProjects)

            ifTrue:[ self searchForSiblingProjects ]

            ifFalse:[ self searchForSubProjects ].

    subProjects removeAll: self excludedFromSubProjects.

    ^ String streamContents:[:s |

        s nextPutLine:'subProjects'.

        s nextPutLine:'    "list packages which are known as subprojects.'.

        s nextPutLine:'     This method is generated automatically; however, when generating automatically,'. 

        s nextPutLine:'     packages are only added - never removed, unless listed in #excludedFromSubProjects."'.

        s nextPutLine:''.

        s nextPutLine:'    ^ #('.

        subProjects do:[:eachPackageID |    

            s nextPutLine:eachPackageID asString storeString

        ].      

        s nextPutLine:')'

    ].

    "

     bosch_dapasx subProjects_code

     stx_goodies subProjects_code

     exept_expecco subProjects_code

    "

    "Modified: / 08-08-2006 / 19:24:34 / fm"

    "Created: / 17-08-2006 / 21:26:51 / cg"

! !

!ApplicationDefinition class methodsFor:'defaults'!

buildTarget

    "which target in the Makefile should be built by default?

     For now, reasonable return values are 'exe', which builds the executable(s),

     and 'ALL', which builds everything, including an installable package.

     Here, 'ALL' is returned.

     There is usually no need to redefine this default - we at exept do it for the

     stx package only to speed up our own build, as we seldom need new install packages,

     put often build new executables..."

     ^ 'ALL'

!

extraTargets

    "extra targets to be built when creating the exe"

     self needResources ifTrue:[

        ^ #('RESOURCEFILES')

     ].

     ^ #()

!

guiClassFileNames_unix

    ^ self guiClasses_unix 

        collect:[:cls | (cls classBaseFilename asFilename withSuffix:'so') baseName].

    "Created: / 14-09-2006 / 18:13:22 / cg"

    "Modified: / 12-10-2006 / 15:50:39 / cg"

!

guiClassFileNames_win32

    ^ self guiClasses_win32 

        collect:[:cls | (cls classBaseFilename asFilename withSuffix:'dll') baseName].

    "Created: / 07-09-2006 / 17:23:13 / cg"

    "Modified: / 12-10-2006 / 15:50:42 / cg"

!

guiClasses_unix

    ^ #()

    "Created: / 14-09-2006 / 18:12:58 / cg"

!

guiClasses_win32

    ^ #()

    "/ ^ Array with:XWorkstation

    "Created: / 07-09-2006 / 17:22:27 / cg"

    "Modified: / 14-09-2006 / 18:12:35 / cg"

!

needResources

    "answer true, if this application

     needs resources to be installed. This is normally true.

     Even non-GUI apps need some (libbasic/resources)"

    ^ true 

! !

!ApplicationDefinition class methodsFor:'description'!

additionalFilesToInstall_osx

    "Each entry gives a pattern of a file to be copied and a destination directory.

     Can be redefined in subclasses to install additional files under the Contents/MacOS folder;

     to get to a parent folder, pass in a string like '../Library/...'

     (keeping OSX specific stuff away from general things, like expecco libs)."

    ^ #()

    "Created: / 21-02-2017 / 15:17:33 / cg"

!

additionalFilesToInstall_unix

    "application-specific files to be installed.

     Each entry gives a pattern of a file to be copied and a destination directory.

     Can be redefined in subclasses."

    ^ #()

    "Created: / 01-03-2007 / 20:02:21 / cg"

!

additionalFilesToInstall_win32

    "application-specific files to be installed.

     Each line defines an entry in the NSI file, for a pattern of a file to be copied.

     Can be redefined in subclasses."

    ^ #()

    "Created: / 01-03-2007 / 20:02:21 / cg"

!

additionalResourceTargets

    "application-specific additional resource targets to be invoked.

     Can be redefined in subclasses."

    ^ #()

!

additionalTargetDirectoriesToMakeForInstall_osx

    "Each entry gives an additional target library to be created under the Contents/MacOS folder;

     to get aadditional parent folder, pass in strings like '../Library/...'"

    ^ #()

    "Created: / 21-02-2017 / 18:00:02 / cg"

!

applicationIconFileName

    "answer the base-name of the application icon (i.e. 'app' in <app>.ico).

     Subclasses MUST redefine this to either return the name of the icon file or

     nil, if they do not have one.

     We NO LONGER SUPPORT THE PREVIOUS APPNAME-DEFAULT,

     because users tend to forget to add the icon file and then get a failing build. "

    ^ self subclassResponsibility.

!

applicationInstallIconFileName

    "answer the base-name of the installer icon (i.e. 'app' in <app>.ico).

     Default is the same as the application icon"

    ^ self applicationIconFileNameWindows.

    "Modified: / 24-09-2018 / 12:46:07 / Claus Gittinger"

!

applicationName

    "answer the name of the application.

     This is also the name of the generated .exe file.

     Subclasses may redefine this"

    ^ self applicationNameFromPackage

    "

     bosch_dapasx_application applicationName

     stx_projects_smalltalk applicationName

    "

    "Created: / 08-08-2006 / 20:25:39 / fm"

    "Modified: / 30-08-2006 / 19:29:25 / cg"

!

documentExtensions

    "list extensions which should be registered with the application.

     Results in the application to be started when double-clicking on such a file (win32)"

    ^ #()

    "Created: / 15-10-2006 / 12:44:14 / cg"

!

includedInPreRequisites

    "list packages which are to be implicitely included in the prerequisites list,

     even if not found by the automatic search.

     Redefine this, if classes from other packages are referred to via reflection