"

 COPYRIGHT (c) 1999 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

Stream subclass:#HashStream

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	category:'System-Crypt-Streams'

!

!HashStream class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1999 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    Abstract class. Subclasses generate hash values used as checksums

    or for generating cryptographic signatures.

    [author:]

        Stefan Vogel

    [see also:]

        SHA1Stream MD5Stream

"

! !

!HashStream class methodsFor:'instance creation'!

hashValueOf:aStringOrByteArry

    ^ self hashValueOfStream:(aStringOrByteArry readStream)

    "

     MD5Stream hashValueOf:'BlaBlaBla'

    "

!

hashValueOfFile:aFilename

    ^ self hashValueOfStream:(aFilename asFilename readStream)

    "

     MD5Stream hashValueOfFile:'Makefile'

    "

!

hashValueOfStream:inStream

    |hashStream|

    hashStream := self new.

    inStream binary.

    inStream copyToEndInto:hashStream.

    inStream close.

    ^ hashStream hashValue

    "

     MD5Stream hashValueOfStream:('Makefile' asFilename readStream)

     MD5Stream hashValueOfStream:('BlaBla' readStream)

    "

! !

!HashStream methodsFor:'accessing'!

contents

    "return the entire contents of the stream

     - this is our hashValue."

    ^ self hashValue

    "Created: / 17.3.1999 / 15:10:03 / stefan"

! !

!HashStream methodsFor:'not implemented'!

next

    ^ self shouldNotImplement

    "Created: / 17.3.1999 / 15:11:03 / stefan"

! !

!HashStream methodsFor:'queries'!

blockSize

    "the class knows about the basic block size"

    ^ self class blockSize

    "Created: / 18.3.1999 / 10:17:02 / stefan"

!

hashSize

    "the class knows about the basic hash size"

    ^ self class hashSize

    "Created: / 18.3.1999 / 10:17:12 / stefan"

    "Modified: / 15.10.1999 / 11:53:20 / stefan"

!

isReadable

    "return true, if reading is supported by the recevier.

     Always return false here"

    ^ false

    "Modified: / 17.3.1999 / 15:06:09 / stefan"

!

isWritable

    "return true, if writing is supported by the recevier.

     Always return true here"

    ^ true

    "Created: / 17.3.1999 / 15:05:49 / stefan"

! !

!HashStream methodsFor:'testing'!

atEnd

    "return true if the end of the stream has been reached;

    this is never reached"

    ^ false

    "Created: / 17.3.1999 / 15:08:55 / stefan"

! !

!HashStream methodsFor:'writing'!

nextPutAll:aCollection

    "Hash streams handle Strings and ByteArrays in nextPut:"

    aCollection class isBytes ifTrue:[

        self nextPut:aCollection.

    ] ifFalse:[

        super nextPutAll:aCollection

    ].

    "Created: / 14.10.1999 / 11:22:50 / stefan"

! !

!HashStream class methodsFor:'documentation'!

version

! !