"{ Encoding: utf8 }"

"

 COPYRIGHT (c) 2012-2014 by Jan Vrany & eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic' }"

"{ NameSpace: Smalltalk }"

Object subclass:#MiniLogger

	instanceVariableNames:''

	classVariableNames:'ALL DEBUG ENTER ERROR FATAL INFO Instance LEAVE LogFormat

		LogOnStderr LogOnTranscript NONE Severities TRACE TRACE0 TRACE1

		TRACE2 TRACE3 Threshold ThresholdPerClass ThresholdPerPackage

		TimestampFormat WARN WARNING'

	poolDictionaries:''

	category:'System-Debugging-Support'

!

Magnitude subclass:#Severity

	instanceVariableNames:'name value'

	classVariableNames:''

	poolDictionaries:''

	privateIn:MiniLogger

!

!MiniLogger class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2012-2014 by Jan Vrany & eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    A very simple logger for Smalltalk/X. This one is always present.

    It mimics the protocol of the loggers found in stx:goodies/loggia,

    which can be activated by setting the global 'Logger' to an instance of

    one of them.

    All

        'Transcript show: 'Processor [info]: xxx'

    should be rewritten over time to use the Logger.

    'Object infoPrint' and 'Object debugPrint' have been changed to

    forward their messages to the global 'Logger' if not nil.

    Usage:

        Logger info: 'Hello world'.

        Logger debug: 'Hello world'.

        Logger warning: 'Hello world'.

        Logger error: 'Hello world'.

    to disable logging:

        MiniLogger logOnTranscript:false.

        MiniLogger logOnStderr:false.

    for selective logging:

        Logger loggingThreshold: Logger severityALL.

        Logger loggingThreshold: Logger severityINFO.

        Logger loggingThreshold: Logger severityNONE.

    ALL > FATAL > ERROR > WARN > INFO > DEBUG > TRACE0 > TRACE3 > NONE

    The following keywords are expanded in the message:

        'LINE'      linenumber in the sending method

        'RECEIVER'  printstring of receiver in sending context

        'CLASS'     class of receiver in sending context

        'MCLASS'    class of sendig method

        'SELECTOR'  selector of sending method

        'WHO'       who-string of sending method

        'WHERE'     who-string plus linenumber of sending method

    i.e.

        Logger info:'%(WHERE) - some message here'

    For more examples, see #examples.

    [author:]

        Jan Vrany <jan.vrany@fit.cvut.cz>

    [instance variables:]

    [class variables:]

    [see also:]

        Loggia logging framework (stx:goodies/loggia)

"

!

examples

"

    Simple logging (make sure logging threshold is lower or equal then

    Logger severityDEBUG, see #loggingThreshold:)

                                                                        [exBegin]

        Logger debug: 'Hello world!!'

                                                                        [exEnd]

    You may use #<severity>:with:with: utility to format log message:

                                                                        [exBegin]

        |hostname port|

        hostname := 'www.google.com'.

        port := 80.

        Logger error: 'Cannot connect to %1:%2' with: hostname with: port

                                                                        [exEnd]

    and even automatically include a lineNumber:

                                                                        [exBegin]

        Logger info: '[%(CLASS)>>%(SELECTOR):%(LINE)] Hello world!!'

                                                                        [exEnd]

"

! !

!MiniLogger class methodsFor:'initialization'!

initialize

    LogOnStderr := true.

    LogOnTranscript := true.

    ALL := Severity new initializeWithName:#all value:0.

    ENTER := Severity new initializeWithName:#enter value:10.

    LEAVE := Severity new initializeWithName:#leave value:10.

    TRACE3 := Severity new initializeWithName:#trace3 value:20.

    TRACE2 := Severity new initializeWithName:#trace2 value:30.

    TRACE1 := Severity new initializeWithName:#trace1 value:40.

    TRACE0 := Severity new initializeWithName:#trace0 value:50.

    TRACE := Severity new initializeWithName:#trace value:50.

    DEBUG := Severity new initializeWithName:#debug value:60.

    INFO := Severity new initializeWithName:#info value:70.

    WARN := Severity new initializeWithName:#warn value:88.

    WARNING := Severity new initializeWithName:#warning value:88.

    ERROR := Severity new initializeWithName:#error value:99.

    FATAL := Severity new initializeWithName:#fatal value:100.

    NONE := Severity new initializeWithName:#none value:65535.

    Severities := {ENTER. LEAVE. TRACE3. TRACE2. TRACE1. TRACE0. TRACE. DEBUG. INFO. WARN. WARNING. ERROR. FATAL.}.

    Threshold := InfoPrinting ifTrue:[INFO] ifFalse:[WARN].

    (Smalltalk at:#Logger) isNil ifTrue:[

        Smalltalk at:#Logger put:self

    ].

    "Modified: / 13-08-2014 / 14:36:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!MiniLogger class methodsFor:'accessing-log format'!

logFormat

    "will be used for the log message as:

        %1 [%2] (%3): %4

    with %1: facility (area)

    with %2: secerity (area)

    with %3: timestamp 

    with %4: caller/originator 

    with %5: message"

    ^ LogFormat ? '%3 %1 [%2]: %5'

    "

     MiniLogger logFormat:'%1 [%2]: %5'.

     'hello' errorPrintCR.

     MiniLogger logFormat:'%3 %1 [%2]: %5'.

     'hello' errorPrintCR.

     MiniLogger logFormat:nil.

     'hello' errorPrintCR.

    "

!

logFormat:aFormatString

    "will be used for the log message as:

        %1 [%2] (%3): %4

            with %1: facility (area)

            with %2: secerity (area)

            with %3: timestamp 

            with %4: caller/originator 

            with %5: message.

     Pass anil argument to return to the default format.        

    "

    LogFormat := aFormatString

    "

     MiniLogger logFormat:'%1 [%2]: %5'.

     'hello' errorPrintCR.

     MiniLogger logFormat:'%3 %1 [%2]: %5'.

     'hello' errorPrintCR.

     MiniLogger logFormat:nil.

     'hello' errorPrintCR.

    "

!

logOnStderr 

    ^ LogOnStderr

!

logOnStderr:aBoolean

    "enable/disable logging on stderr"

    LogOnStderr := aBoolean

    "

     MiniLogger logOnStderr:false

     MiniLogger logOnTranscript:false

     MiniLogger logOnStderr:true

     MiniLogger logOnTranscript:true

    "

    "Modified (comment): / 25-01-2018 / 12:13:53 / mawalch"

!

logOnTranscript

    ^ LogOnTranscript 

!

logOnTranscript:aBoolean

    "enable/disable logging on the Transcript"

    LogOnTranscript := aBoolean

    "

     MiniLogger logOnStderr:false

     MiniLogger logOnTranscript:false

     MiniLogger logOnStderr:true

     MiniLogger logOnTranscript:true

    "

    "Modified (comment): / 25-01-2018 / 12:13:36 / mawalch"

!

timestampFormat

    "will be used for the log message"

    ^ TimestampFormat ? '%(year)-%(mon)-%(day) %h:%m:%s.%i'.

    "

     Timestamp now printStringFormat:(self timestampFormat)

    "

!

timestampFormat:aTimestampFormatString

    "will be used for the log message"

    TimestampFormat := aTimestampFormatString

! !

!MiniLogger class methodsFor:'accessing-severities'!

severities

    "ALL > FATAL > ERROR > WARN > INFO > DEBUG > TRACE0 > TRACE3 > NONE"

    ^ Severities.

    "Modified (comment): / 06-02-2019 / 18:17:15 / Claus Gittinger"

!

severityDEBUG

    "ALL > FATAL > ERROR > WARN > INFO > DEBUG > TRACE0 > TRACE3 > NONE"

    ^ DEBUG

    "Created: / 13-08-2014 / 14:15:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 06-02-2019 / 18:18:21 / Claus Gittinger"

!

severityENTER

    "ALL > FATAL > ERROR > WARN > INFO > DEBUG > TRACE0 > TRACE3 > NONE"

    ^ ENTER

    "Created: / 13-08-2014 / 14:14:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 06-02-2019 / 18:18:24 / Claus Gittinger"

!

severityERROR

    "setting this as treshold will print errors"

    "ALL > FATAL > ERROR > WARN > INFO > DEBUG > TRACE0 > TRACE3 > NONE"

    ^ ERROR

    "Created: / 13-08-2014 / 14:15:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 06-02-2019 / 18:18:30 / Claus Gittinger"

!

severityFATAL

    "ALL > FATAL > ERROR > WARN > INFO > DEBUG > TRACE0 > TRACE3 > NONE"

    ^ FATAL

    "Created: / 13-08-2014 / 14:15:45 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 06-02-2019 / 18:18:33 / Claus Gittinger"

!

severityINFO

    "ALL > FATAL > ERROR > WARN > INFO > DEBUG > TRACE0 > TRACE3 > NONE"

    ^ INFO

    "Created: / 13-08-2014 / 14:15:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 06-02-2019 / 18:18:37 / Claus Gittinger"

!

severityLEAVE

    "ALL > FATAL > ERROR > WARN > INFO > DEBUG > TRACE0 > TRACE3 > NONE"

    ^ LEAVE

    "Created: / 13-08-2014 / 14:14:19 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 06-02-2019 / 18:18:40 / Claus Gittinger"

!

severityTRACE

    "ALL > FATAL > ERROR > WARN > INFO > DEBUG > TRACE0 > TRACE3 > NONE"

    ^ TRACE

    "Created: / 13-08-2014 / 14:15:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 06-02-2019 / 18:18:43 / Claus Gittinger"

!

severityTRACE0

    "ALL > FATAL > ERROR > WARN > INFO > DEBUG > TRACE0 > TRACE3 > NONE"

    ^ TRACE0

    "Created: / 13-08-2014 / 14:14:59 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 06-02-2019 / 18:18:45 / Claus Gittinger"

!

severityTRACE1

    "ALL > FATAL > ERROR > WARN > INFO > DEBUG > TRACE0 > TRACE3 > NONE"

    ^ TRACE1

    "Created: / 13-08-2014 / 14:14:56 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (format): / 06-02-2019 / 18:18:51 / Claus Gittinger"

!

severityTRACE2

    "ALL > FATAL > ERROR > WARN > INFO > DEBUG > TRACE0 > TRACE3 > NONE"

    ^ TRACE2

    "Created: / 13-08-2014 / 14:14:53 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 06-02-2019 / 18:18:54 / Claus Gittinger"

!

severityTRACE3

    "ALL > FATAL > ERROR > WARN > INFO > DEBUG > TRACE0 > TRACE3 > NONE"

    ^ TRACE3

    "Created: / 13-08-2014 / 14:14:48 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 06-02-2019 / 18:18:57 / Claus Gittinger"

!

severityWARN

    "setting this as treshold will print warnings and errors"

    "ALL > FATAL > ERROR > WARN > INFO > DEBUG > TRACE0 > TRACE3 > NONE"

    ^ WARN

    "Created: / 13-08-2014 / 14:15:30 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 06-02-2019 / 18:19:01 / Claus Gittinger"

! !

!MiniLogger class methodsFor:'accessing-severities-special'!

severityALL

    "setting this as treshold will print all"

    ^ ALL

    "Created: / 13-08-2014 / 14:14:00 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 06-02-2019 / 18:14:48 / Claus Gittinger"

!

severityNONE

    "setting this as treshold will suppress all logging"

    ^ NONE

    "Created: / 13-08-2014 / 14:15:53 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 06-02-2019 / 18:14:40 / Claus Gittinger"

! !

!MiniLogger class methodsFor:'configuration'!

loggingThreshold

    "Return the logging threshold. 

     No messages with severity lower than threshold will be logged.

     The default is 

        InfoPrinting ifTrue:[INFO] ifFalse:[WARN]

     meaning that by default, no trace and debug logs are generated."

    ^ Threshold

    "

     self loggingThreshold:INFO.

     self trace:'blabla'.

     self loggingThreshold:TRACE.

     self trace:'blabla'.

     self loggingThreshold:INFO.

    "

    "Created: / 13-08-2014 / 14:36:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

loggingThreshold:severity 

    "Sets logging threshold. 

     All severities higher or equal to the given one will be logged.

     Use `Logger severityNONE` to suppress logging completely 

     or `Logger severityALL` to log all messages.

     ALL > FATAL > ERROR > WARN > INFO > DEBUG > TRACE0 > TRACE3 > NONE"

    (

        (Severities includes:severity) 

        or:[ severity == ALL or:[ severity == NONE ] ]

    ) ifFalse:[

        self error:'Invalid severity. Use of Logger severityXXX'.

        ^ self.

    ].

    Threshold := severity

    "

    Logger loggingThreshold: Logger severityALL.

    Logger loggingThreshold: Logger severityINFO.

    Logger loggingThreshold: Logger severityDEBUG.  -- only debug, warnings and errors 

    Logger loggingThreshold: Logger severityWARN.   -- only warnings and errors 

    Logger loggingThreshold: Logger severityERROR.  -- only errors

    Logger loggingThreshold: Logger severityNONE.

    "

    "Created: / 13-08-2014 / 14:34:16 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 26-08-2014 / 08:23:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 09-10-2014 / 09:35:23 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 01-03-2017 / 10:42:31 / cg"

    "Modified (comment): / 06-02-2019 / 18:17:57 / Claus Gittinger"

!

loggingThreshold:aLimitOrNil forClass:aClass

    "allows individual per-class setting of the threshold (useful during debugging).

     With a nil limit, the default is reinstalled for that class.

     ALL > FATAL > ERROR > WARN > INFO > DEBUG > TRACE0 > TRACE3 > NONE"

    "/ the original scheme asked the class;

    "/ but that required adding a getter to debugged classes, which

    "/ is easily forgotten and checked in.

    "/ Better keep that nfo here, so wemight even provide a GUI for it some time in the future...

    "/ remember the class name - in case it is reloaded/changes identity etc.

    aLimitOrNil isNil ifTrue:[

        ThresholdPerClass notNil ifTrue:[

            ThresholdPerClass removeKey:(aClass theNonMetaclass name) ifAbsent:[].

            ThresholdPerClass isEmpty ifTrue:[

                ThresholdPerClass := nil.

            ].

        ].

        ^ self

    ].    

    ThresholdPerClass isNil ifTrue:[

        ThresholdPerClass := Dictionary new.

    ].

    ThresholdPerClass at:aClass theNonMetaclass name put:aLimitOrNil.