"{ Encoding: utf8 }"

"{ Package: 'stx:libbasic2' }"

"{ NameSpace: Smalltalk }"

HashStream subclass:#CRCStream

	instanceVariableNames:'crc generatorPolynom crcTable initValue xorOut'

	classVariableNames:''

	poolDictionaries:''

	category:'System-Crypt-Hashing'

!

CRCStream class instanceVariableNames:'crcTables'

"

 No other class instance variables are inherited by this class.

"

!

!CRCStream class methodsFor:'documentation'!

documentation

"

    abstract superclass of crc streams;

    refactored from original crc32 stream.

    For details, see https://en.wikipedia.org/wiki/Cyclic_redundancy_check

"

! !

!CRCStream class methodsFor:'initialization'!

crcTableFor:generatorPolynomInteger

    |crcTable|

    crcTables isNil ifTrue:[

        crcTables := Dictionary new

    ].    

    crcTable := (crcTables at:generatorPolynomInteger ifAbsent:nil).

    crcTable isNil ifTrue:[

        crcTable := IntegerArray new:256.

        0 to:255 do:[:count| |i|

            i := count.

            8 timesRepeat:[

                (i bitTest:1) ifTrue:[

                    i := generatorPolynomInteger bitXor:(i bitShift:-1)

                ] ifFalse:[

                    i := i bitShift:-1

                ]

            ].

            crcTable at:count+1 put:i.

        ].

        crcTables at:generatorPolynomInteger put:crcTable.

    ].

    ^ crcTable.

    "Created: / 16-03-2019 / 20:53:51 / Claus Gittinger"

! !

!CRCStream class methodsFor:'instance creation'!

generatorPolynom:anLSBInteger

    "notice, in literature, the generator polynom is usually specified as an MSB number"

    ^ self basicNew generatorPolynom:anLSBInteger

    "

       self assert:((self generatorPolynom:16r82F63B78)

                                nextPut:'123456789';

                                hashValue)    = 16rE3069283

    "

    "Modified (comment): / 16-03-2019 / 20:56:23 / Claus Gittinger"

!

generatorPolynom:anLSBInteger initValue:initValue

    "notice, in literature, the generator polynom is usually specified as an MSB number"

    ^ self basicNew generatorPolynom:anLSBInteger initValue:initValue

    "

       self assert:((self generatorPolynom:16r82F63B78)

                                nextPut:'123456789';

                                hashValue)    = 16rE3069283

    "

    "Created: / 16-03-2019 / 21:15:54 / Claus Gittinger"

!

generatorPolynom:anLSBInteger initValue:initValue xorOut:xorOut

    "notice, in literature, the generator polynom is usually specified as an MSB number"

    ^ self basicNew generatorPolynom:anLSBInteger initValue:initValue xorOut:xorOut

    "

       self assert:((self generatorPolynom:16r82F63B78)

                                nextPut:'123456789';

                                hashValue)    = 16rE3069283

    "

    "Created: / 16-03-2019 / 21:16:05 / Claus Gittinger"

! !

!CRCStream methodsFor:'accessing'!

generatorPolynom

    "answer the generator polynom (LSB)"

    ^ generatorPolynom

    "Modified (comment): / 16-03-2019 / 20:58:10 / Claus Gittinger"

!

initValue

    "answer the init value"

    ^ initValue ? 0

    "Created: / 16-03-2019 / 21:05:04 / Claus Gittinger"

!

xorOut

    "answer the xorOut value"

    ^ xorOut ? 16rFFFFFFFF

    "Created: / 16-03-2019 / 21:16:23 / Claus Gittinger"

! !

!CRCStream methodsFor:'initialization'!

generatorPolynom:polyLSB initValue:initValueArg xorOut:xorOutArg

    "answer the generator polynom (LSB)"

    generatorPolynom := polyLSB.

    crc := initValue := initValueArg.

    xorOut := xorOutArg.

    crcTable := self class crcTableFor:generatorPolynom.

    "Created: / 16-03-2019 / 21:17:12 / Claus Gittinger"

!

reset

    "reset the current crc value"

    crc := initValue.

    "Created: / 16-03-2019 / 21:25:27 / Claus Gittinger"

! !

!CRCStream methodsFor:'queries'!

hashValue

    "return the computed CRC"

    ^ crc bitXor:xorOut.

    "Modified: / 16-03-2019 / 21:27:59 / Claus Gittinger"

! !

!CRCStream methodsFor:'writing'!

nextPutBytes:count from:anObject startingAt:start

    "add the hash of anObject to the computed hash so far."

%{

    if (__bothSmallInteger(count, start)) {

        int len, offs;

        int objSize;

        unsigned char *extPtr;

        len = __intVal(count);

        offs = __intVal(start) - 1;

        if (__isExternalBytesLike(anObject)) {

            OBJ sz = __externalBytesSize(anObject);

            extPtr = (unsigned char *)__externalBytesAddress(anObject);

            if (__isSmallInteger(sz)) {

                objSize = __intVal(sz);

            } else {

                objSize = 0; /* unknown */

            }

        } else {

            int nInstVars, nInstBytes;

            OBJ oClass = __Class(anObject);

            switch (__intVal(__ClassInstPtr(oClass)->c_flags) & ARRAYMASK) {

                case BYTEARRAY:

                case WORDARRAY:

                case LONGARRAY:

                case SWORDARRAY:

                case SLONGARRAY:

                case FLOATARRAY:

                case DOUBLEARRAY:

                    break;

                default:

                    goto bad;

            }

            nInstVars = __intVal(__ClassInstPtr(oClass)->c_ninstvars);

            nInstBytes = __OBJS2BYTES__(nInstVars);

            // nInstBytes is the number of bytes occupied by pointer instance variables

            // subtract from size and add to byte-pointer

            objSize = __qSize(anObject) - OHDR_SIZE - nInstBytes;

            extPtr = (unsigned char *)__byteArrayVal(anObject)+nInstBytes;

        }

        if ((offs >= 0) && (len >= 0) && (objSize >= (len + offs))) {

            unsigned int _crc;

            unsigned int *_crcTable = __integerArrayVal( __INST(crcTable) );

            unsigned char *cp = extPtr+offs;

            unsigned int n = len;

            if (__isSmallInteger(__INST(crc))) {

                _crc = (unsigned int) (__intVal( __INST(crc) ));

            } else {

                _crc = __unsignedLongIntVal( __INST(crc) );

            }

#ifdef __LSBFIRST__

# if __POINTER_SIZE__ == 8

            if (((unsigned INT)cp & 7) == 0) {

                // longword aligned

                for ( ; n >= 8 ; n -= 8, cp += 8) {

                    unsigned INT lWord;

                    unsigned char _idx;

                    lWord = ((unsigned INT *)cp)[0];

                    _idx = (_crc ^ lWord) & 0xFF;

                    _crc = _crcTable[_idx] ^ (_crc >> 8);

                    _idx = (_crc ^ (lWord>>8)) & 0xFF;

                    _crc = _crcTable[_idx] ^ (_crc >> 8);

                    _idx = (_crc ^ (lWord>>16)) & 0xFF;

                    _crc = _crcTable[_idx] ^ (_crc >> 8);

                    _idx = (_crc ^ (lWord>>24)) & 0xFF;

                    _crc = _crcTable[_idx] ^ (_crc >> 8);

                    _idx = (_crc ^ (lWord>>32)) & 0xFF;

                    _crc = _crcTable[_idx] ^ (_crc >> 8);

                    _idx = (_crc ^ (lWord>>40)) & 0xFF;

                    _crc = _crcTable[_idx] ^ (_crc >> 8);

                    _idx = (_crc ^ (lWord>>48)) & 0xFF;

                    _crc = _crcTable[_idx] ^ (_crc >> 8);

                    _idx = (_crc ^ (lWord>>56)) & 0xFF;

                    _crc = _crcTable[_idx] ^ (_crc >> 8);

                }

            }

# endif            

            if (((unsigned INT)cp & 3) == 0) {

                // word aligned

                for ( ; n >= 4 ; n -= 4, cp += 4) {

                    unsigned int word;

                    unsigned char _idx;

                    word = ((unsigned int *)cp)[0];

                    _idx = (_crc ^ word) & 0xFF;

                    _crc = _crcTable[_idx] ^ (_crc >> 8);

                    _idx = (_crc ^ (word>>8)) & 0xFF;

                    _crc = _crcTable[_idx] ^ (_crc >> 8);

                    _idx = (_crc ^ (word>>16)) & 0xFF;

                    _crc = _crcTable[_idx] ^ (_crc >> 8);

                    _idx = (_crc ^ (word>>24)) & 0xFF;

                    _crc = _crcTable[_idx] ^ (_crc >> 8);

                }

            }

#endif

            for ( ; n >= 4 ; n -= 4, cp += 4) {

                unsigned char _idx;

                _idx = (_crc ^ cp[0]) & 0xFF;

                _crc = _crcTable[_idx] ^ (_crc >> 8);

                _idx = (_crc ^ cp[1]) & 0xFF;

                _crc = _crcTable[_idx] ^ (_crc >> 8);

                _idx = (_crc ^ cp[2]) & 0xFF;

                _crc = _crcTable[_idx] ^ (_crc >> 8);

                _idx = (_crc ^ cp[3]) & 0xFF;

                _crc = _crcTable[_idx] ^ (_crc >> 8);

            }

            while (n-- > 0) {

                unsigned char _idx = (_crc ^ *cp++) & 0xFF;

                _crc = _crcTable[_idx] ^ (_crc >> 8);

            }

            if (sizeof(INT) == 8 || _crc <= _MAX_INT)

                __INST(crc) = __MKSMALLINT(_crc);

            else {

                // this code fails with gcc 4.7.2:

                // __INST(crc) = __MKUINT(_crc); __STORESELF(crc);

                OBJ temp = __MKUINT(_crc); 

                __INST(crc) = temp; __STORESELF(crc);

            }

            // if (__unsignedLongIntVal(__INST(crc)) == 4294967295) printf("inst: %d crc: %d new: %d\n", __unsignedLongIntVal(__INST(crc)), _crc, __unsignedLongIntVal(temp));

            RETURN (count);

        }

    }

bad: ;

%}.

    self error:'invalid argument'

    "Created: / 09-01-2012 / 16:48:35 / cg"

    "Modified: / 16-03-2019 / 23:19:17 / Claus Gittinger"

! !

!CRCStream class methodsFor:'documentation'!

version_CVS

    ^ '$Header$'

! !