"

 COPYRIGHT (c) 1998 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

Object subclass:#ZipArchive

	instanceVariableNames:'file mode archiveName firstEntry lastEntry'

	classVariableNames:'RecentlyUsedZipArchives ECREC_SIZE LREC_SIZE CREC_SIZE

		SIZE_CENTRAL_DIRECTORY TOTAL_ENTRIES_CENTRAL_DIR

		C_COMPRESSED_SIZE C_RELATIVE_OFFSET_LOCAL_HEADER

		C_FILENAME_LENGTH C_UNCOMPRESSED_SIZE ZipFileFormatErrorSignal

		COMPR_STORED COMPR_SHRUNK COMPR_REDUCED1 COMPR_REDUCED2

		COMPR_REDUCED3 COMPR_REDUCED4 COMPR_IMPLODED COMPR_TOKENIZED

		COMPR_DEFLATED'

	poolDictionaries:''

	category:'System-Support-FileFormats'

!

Object subclass:#ZipMember

	instanceVariableNames:'next relative_offset_local_header compressed_size

		uncompressed_size name crc32 compression_method'

	classVariableNames:''

	poolDictionaries:''

	privateIn:ZipArchive

!

!ZipArchive class methodsFor:'documentation'!

copyright 

"

 COPYRIGHT (c) 1998 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    provides access to a zip archive.

    Caveat: only uncompressed archives are supported (for now).

"

!

examples

"

                                                        [exBegin]

    |zip bytes|

    zip := ZipArchive oldFileNamed:'foo.zip'.

    bytes := zip extract:'bar'.

                                                        [exEnd]

"

! !

!ZipArchive class methodsFor:'instance creation'!

newFileNamed:name

    ^ self new name:name mode:#write

    "Created: / 29.3.1998 / 17:46:16 / cg"

!

oldFileNamed:name

    |zar f|

    f := name asFilename.

    RecentlyUsedZipArchives isNil ifTrue:[

        RecentlyUsedZipArchives := OrderedCollection new

    ].

    RecentlyUsedZipArchives keysAndValuesDo:[:i :z |

        z name = name ifTrue:[

            RecentlyUsedZipArchives removeIndex:i.

            RecentlyUsedZipArchives addLast:z.

            ^ z

        ].

    ].

    zar := self new name:f mode:#read.

    RecentlyUsedZipArchives add:zar.

    [RecentlyUsedZipArchives size > 5] whileTrue:[

        RecentlyUsedZipArchives removeFirst

    ].

    ^ zar

    "Created: / 29.3.1998 / 17:46:09 / cg"

    "Modified: / 7.4.1998 / 14:32:24 / cg"

! !

!ZipArchive class methodsFor:'class initialization'!

initialize

    ECREC_SIZE := 18.

    LREC_SIZE := 26.

    CREC_SIZE := 42.

    TOTAL_ENTRIES_CENTRAL_DIR := 10.

    SIZE_CENTRAL_DIRECTORY := 12.

    C_COMPRESSED_SIZE := 16.

    C_UNCOMPRESSED_SIZE := 20.

    C_FILENAME_LENGTH := 24.

    C_RELATIVE_OFFSET_LOCAL_HEADER := 38.

    "/ compression methods 

    COMPR_STORED          :=  0.    

    COMPR_SHRUNK          :=  1.

    COMPR_REDUCED1        :=  2.

    COMPR_REDUCED2        :=  3.

    COMPR_REDUCED3        :=  4.

    COMPR_REDUCED4        :=  5.

    COMPR_IMPLODED        :=  6.

    COMPR_TOKENIZED       :=  7.

    COMPR_DEFLATED        :=  8.

    ZipFileFormatErrorSignal := Signal new.

    "

     self initialize

    "

    "Modified: / 29.3.1998 / 20:17:18 / cg"

! !

!ZipArchive class methodsFor:'cleanup'!

lowSpaceCleanup

    RecentlyUsedZipArchives := nil

    "Created: / 6.4.1998 / 12:36:37 / cg"

! !

!ZipArchive class methodsFor:'constants'!

LREC_SIZE

    ^ LREC_SIZE

    "Created: / 29.3.1998 / 19:11:20 / cg"

! !

!ZipArchive methodsFor:'accessing'!

entries

    "return a collection of fileName entries"

    |names|

    names := OrderedCollection new.

    self zipMembersDo:[:zipd |

        names add:(zipd name)

    ].

    ^ names

    "

     (ZipArchive oldFileNamed:'/usr/lib/java/lib/classes.zip') entries

    "

    "Modified: / 29.3.1998 / 20:08:38 / cg"

!

extract:fileName

    |zmemb rawContents|

    zmemb := self findMember:fileName.

    zmemb isNil ifTrue:[^ nil].

    self openFile.

    file position:(zmemb fileStart + 1).

    rawContents := file nextBytes:(zmemb compressed_size).

    self closeFile.

    ^ self decode:rawContents method:(zmemb compression_method)

    "

     (ZipArchive oldFileNamed:'/usr/lib/java/lib/classes.zip') extract:'java/io/UTFDataFormatException.class'

    "

    "Modified: / 30.3.1998 / 18:20:08 / cg"

!

members

    "return a collection of members"

    |members|

    members := OrderedCollection new.

    self zipMembersDo:[:zipd |

        members add:zipd

    ].

    ^ members

    "

     (ZipArchive oldFileNamed:'/usr/lib/java/lib/classes.zip') members

    "

    "Created: / 29.3.1998 / 20:09:27 / cg"

    "Modified: / 29.3.1998 / 20:10:21 / cg"

!

name

    ^ archiveName

    "Created: / 6.4.1998 / 10:47:11 / cg"

! !

!ZipArchive methodsFor:'private'!

closeFile

    file close.

    file := nil.

    "Created: / 30.3.1998 / 18:18:10 / cg"

!

name:nm mode:m

    archiveName := nm asFilename name.

    mode := m.

    mode == #read ifTrue:[

        self openFile.

        self readDirectory.

        self closeFile.

    ] ifFalse:[

        "/ self openFile.

    ]

    "

     ZipArchive oldFileNamed:'/usr/lib/java/lib/classes.zip'

     (ZipArchive oldFileNamed:'/usr/lib/java/lib/classes.zip') entries

     (ZipArchive oldFileNamed:'/usr/lib/java/lib/classes.zip') extract:'java/io/UTFDataFormatException.class'

    "

    "Modified: / 30.3.1998 / 18:19:48 / cg"

!

openFile

    file isNil ifTrue:[

        mode == #read ifTrue:[

            file := archiveName asFilename readStream binary.

        ] ifFalse:[

            file := archiveName asFilename writeStream binary

        ]

    ].

    "Created: / 30.3.1998 / 18:18:48 / cg"

    "Modified: / 30.3.1998 / 18:19:26 / cg"

! !

!ZipArchive methodsFor:'private - decompression'!

decode:rawBytes method:compressionMethod

    compressionMethod == COMPR_STORED ifTrue:[

        "/ uncompressed

        ^ rawBytes

    ].

    compressionMethod == COMPR_SHRUNK ifTrue:[

        self error:'unsupported compression method: SHRUNK'.

        ^ nil

    ].

    compressionMethod == COMPR_REDUCED1 ifTrue:[

        self error:'unsupported compression method: REDUCED1'.

        ^ nil

    ].

    compressionMethod == COMPR_REDUCED2 ifTrue:[

        self error:'unsupported compression method: REDUCED2'.

        ^ nil

    ].

    compressionMethod == COMPR_REDUCED3 ifTrue:[

        self error:'unsupported compression method: REDUCED3'.

        ^ nil

    ].

    compressionMethod == COMPR_REDUCED4 ifTrue:[

        self error:'unsupported compression method: REDUCED4'.

        ^ nil

    ].

    compressionMethod == COMPR_IMPLODED ifTrue:[

        self error:'unsupported compression method: IMPLODED'.

        ^ nil

    ].

    compressionMethod == COMPR_TOKENIZED ifTrue:[

        self error:'unsupported compression method: TOKENIZED'.

        ^ nil

    ].

    compressionMethod == COMPR_DEFLATED ifTrue:[

        self error:'unsupported compression method: DEFLATED'.

        ^ nil

    ].

    self error:'unsupported compression method'.

    ^ nil

    "Created: / 29.3.1998 / 20:14:45 / cg"

    "Modified: / 29.3.1998 / 20:20:20 / cg"

! !

!ZipArchive methodsFor:'private - directory stuff'!

addMember

    "add a zipMember"

    |zmemb |

    zmemb := ZipMember new.

    (firstEntry == nil) ifTrue:[

        firstEntry := zmemb

    ] ifFalse:[ 

        lastEntry next:zmemb.

    ].

    lastEntry := zmemb.

    ^ zmemb.

    "Created: / 29.3.1998 / 18:22:25 / cg"

    "Modified: / 30.3.1998 / 17:13:20 / cg"

!

findMember:name

    "find a zipMember by name"

    self zipMembersDo:[:zipd |

        (zipd name = name) ifTrue:[^ zipd].

    ].

    ^ nil

    "Modified: / 30.3.1998 / 17:13:30 / cg"

!

readDirectory

    "read the zip directory into a linked-list of zipMembers"

    |size count_in dir_size|

    size := file fileSize.

    (size == 0) ifTrue:[

        count_in := 0.

        ^ self

    ].

    (size < (ECREC_SIZE+4)) ifTrue:[

        ^ ZipFileFormatErrorSignal raiseWith:'zipfile too short'.

    ].

    file position:(size - (ECREC_SIZE+4) + 1).

    ((file next ~~ ($P asciiValue))

    or:[file next ~~ ($K asciiValue)

    or:[file next ~~ 8r005

    or:[file next ~~ 8r006]]]) ifTrue:[

        ^ ZipFileFormatErrorSignal raiseWith:'not a valid zipfile'.

    ].

    file skip: (TOTAL_ENTRIES_CENTRAL_DIR - 4).

    count_in := file nextUnsignedShortMSB:false.        "/ Get TOTAL_ENTRIES_CENTRAL_DIR

    dir_size := file nextLongMSB:false.                 "/ Get SIZE_CENTRAL_DIRECTORY

    file position:(size - (dir_size + ECREC_SIZE+4) + 1).

    0 to:(count_in-1) do:[:i |

        |zipd filename_length|

        zipd := self addMember.

        file skip:(4+C_COMPRESSED_SIZE-4-2-2-2).

        zipd compression_method:(file nextUnsignedShortMSB:false). "/ Get compression method

        (file nextUnsignedShortMSB:false).                      "/ skip last_mod_file_time

        (file nextUnsignedShortMSB:false).                      "/ skip last_mod_file_date

        zipd crc32:(file nextLongMSB:false).                    "/ Get crc32

        zipd compressed_size:(file nextLongMSB:false).          "/ Get C_COMPRESSED_SIZE

        zipd uncompressed_size:(file nextLongMSB:false).        "/ Get C_UNCOMPRESSED_SIZE

        filename_length := (file nextUnsignedShortMSB:false).   "/ Get C_FILENAME_LENGTH

        file skip:(C_RELATIVE_OFFSET_LOCAL_HEADER-(C_FILENAME_LENGTH+2)).

        zipd relative_offset_local_header:(file nextLongMSB:false).

        zipd name:(String new:filename_length).

        file nextBytes:filename_length into:(zipd name).

    ]

    "Modified: / 30.3.1998 / 18:02:06 / cg"

!

zipMembersDo:aBlock

    "evaluate aBlock for all zipMembers"

    |zipd|

    zipd := firstEntry.

    [zipd notNil] whileTrue:[

        aBlock value:zipd.

        zipd := zipd next

    ].

    "Created: / 29.3.1998 / 19:15:15 / cg"

    "Modified: / 30.3.1998 / 17:13:47 / cg"

! !

!ZipArchive::ZipMember methodsFor:'accessing'!

compressed_size

    "return the value of the instance variable 'compressed_size' (automatically generated)"

    ^ compressed_size

    "Created: / 29.3.1998 / 18:28:03 / cg"

!

compressed_size:something

    "set the value of the instance variable 'compressed_size' (automatically generated)"

    compressed_size := something.

    "Created: / 29.3.1998 / 18:28:03 / cg"

!

compression_method

    "return the value of the instance variable 'compression_method' (automatically generated)"

    ^ compression_method

    "Created: / 29.3.1998 / 20:02:57 / cg"

!

compression_method:something

    "set the value of the instance variable 'compression_method' (automatically generated)"

    compression_method := something.

    "Created: / 29.3.1998 / 20:02:57 / cg"

!

crc32

    "return the value of the instance variable 'crc32' (automatically generated)"

    ^ crc32

    "Created: / 29.3.1998 / 20:03:00 / cg"

!

crc32:something

    "set the value of the instance variable 'crc32' (automatically generated)"

    crc32 := something.

    "Created: / 29.3.1998 / 20:03:00 / cg"

!

name

    "return the value of the instance variable 'name' (automatically generated)"

    ^ name

    "Created: / 29.3.1998 / 18:29:22 / cg"

!

name:something

    "set the value of the instance variable 'name' (automatically generated)"

    name := something.

    "Created: / 29.3.1998 / 18:29:22 / cg"

!

next

    "return the value of the instance variable 'next' (automatically generated)"

    ^ next

    "Created: / 29.3.1998 / 18:29:42 / cg"

!

next:something

    "set the value of the instance variable 'next' (automatically generated)"

    next := something.

    "Created: / 29.3.1998 / 18:29:42 / cg"

!

relative_offset_local_header

    "return the value of the instance variable 'relative_offset_local_header' (automatically generated)"

    ^ relative_offset_local_header

    "Created: / 29.3.1998 / 18:28:40 / cg"

!

relative_offset_local_header:something

    "set the value of the instance variable 'relative_offset_local_header' (automatically generated)"

    relative_offset_local_header := something.

    "Created: / 29.3.1998 / 18:28:40 / cg"

!

uncompressed_size

    "return the value of the instance variable 'uncompressed_size' (automatically generated)"

    ^ uncompressed_size

    "Created: / 29.3.1998 / 18:28:21 / cg"

!

uncompressed_size:something

    "set the value of the instance variable 'uncompressed_size' (automatically generated)"