"

 COPYRIGHT (c) 2002 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic2' }"

ByteArray variableByteSubclass:#UUID

	instanceVariableNames:''

	classVariableNames:'NextSeqNr'

	poolDictionaries:''

	category:'System-Communication-Support'

!

AbsoluteTime variableByteSubclass:#UTCTime

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:UUID

!

Object variableByteSubclass:#UUIDRandom

	instanceVariableNames:''

	classVariableNames:'rand_m rand_ia rand_ib rand_irand'

	poolDictionaries:''

	privateIn:UUID

!

!UUID class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2002 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

! !

!UUID class methodsFor:'instance creation'!

fromBytes:aByteArray msb:msb

    |uuid d1 d2 d3|

    uuid := self new.

    uuid replaceFrom:1 to:16 with:aByteArray.

    msb ifTrue:[

        d1 := aByteArray unsignedLongAt:1 bigEndian:msb.

        uuid unsignedLongAt:1 put:d1 bigEndian:false.

        d2 := aByteArray unsignedShortAt:1+4 bigEndian:msb.

        uuid unsignedShortAt:1+4 put:d2 bigEndian:false.

        d3 := aByteArray unsignedShortAt:1+4+2 bigEndian:msb.

        uuid unsignedShortAt:1+4+2 put:d3 bigEndian:false.

    ].

    ^ uuid

    "

     UUID fromBytes:#[16r01 16r02 16r03 16r04

                      16r05 16r06 16r07 16r08

                      16r09 16r10 16r11 16r12

                      16r13 16r14 16r15 16r16] msb:false. 

    "

    "

     UUID fromBytes:#[16r01 16r02 16r03 16r04

                      16r05 16r06 16r07 16r08

                      16r09 16r10 16r11 16r12

                      16r13 16r14 16r15 16r16] msb:true.    

    "

!

fromString:aString

    |d offs s uuid t byte|

    s := aString readStream.

    uuid := self new.

    offs := 1.

    s skipSeparators.

    s peek == ${ ifTrue:[s next].

    s skipSeparators.

    t := s next:8.

    d := Integer readFrom:t radix:16.

    uuid unsignedLongAt:1 put:d bigEndian:false.

    offs := offs + 4.

    s next.

    1 to:2 do:[:i |

        t := s next:4.

        d := Integer readFrom:t radix:16.

        uuid unsignedShortAt:offs put:d bigEndian:false.

        offs := offs + 2.

        s next.

    ].

    t := s next:4.

    d := Integer readFrom:t radix:16.

    uuid unsignedShortAt:offs put:d bigEndian:true.

    offs := offs + 2.

    s next.

    1 to:6 do:[:i |

        t := s next:2.

        byte := Integer readFrom:t radix:16.

        uuid at:offs put:byte.

        offs := offs + 1.

    ].

    ^ uuid

    "

     UUID fromString:'5ab2e9b4-3d48-11d2-9ea4-80c5140aaa77' 

    "

!

genUUID

    ^ self new genUUID

!

new

    ^ super new:16

!

new:size

    self shouldNotImplement

! !

!UUID class methodsFor:'defaults'!

uuidVersion

    ^ 1

! !

!UUID methodsFor:'converting'!

asBytesMSB:msb

    |bytes d1 d2 d3|

    bytes := ByteArray new:16.

    bytes replaceFrom:1 to:16 with:self.

    msb ifTrue:[

        d1 := self unsignedLongAt:1 bigEndian:false.

        d2 := self unsignedShortAt:1+4 bigEndian:false.

        d3 := self unsignedShortAt:1+4+2 bigEndian:false.

        bytes unsignedLongAt:1 put:d1 bigEndian:true.

        bytes unsignedShortAt:1+4 put:d2 bigEndian:true.

        bytes unsignedShortAt:1+4+2 put:d3 bigEndian:true.

    ].

    ^ bytes

! !

!UUID methodsFor:'generating uuids'!

genUUID

    |macBytes utcTime length byte uuidClockSeq|

    NextSeqNr isNil ifTrue:[

        NextSeqNr := 1.                Socket new

    ].

    macBytes := self getValidMACAdress.

    macBytes isNil ifTrue:[ ^ nil].

    self replaceFrom:16-6+1 to:16 with:macBytes startingAt:1.

    "/ use 60 bit 100ns ticks since 00:00:00 15.oct 1582 (sigh)

    utcTime := UTCTime now.

    length := utcTime digitLength.

    "/ time_low bytes 1-4

    1 to: 4 do:[ : el |

        byte := utcTime digitAt:(length - el + 1).

        self at:el + 1 put:byte.

    ].

    "/ time_mid bytes 5-6

    5 to: 6 do:[ : el |

        byte := utcTime digitAt:(length - el + 1).

        self at:el put:byte.

    ].

    "/ time_high bytes 6-7 multiplexed with version

    7 to: 8 do:[ : el |

        byte := utcTime digitAt:(length - el + 1).

        (el == 6) ifTrue:[

            byte := byte bitOr:(self class uuidVersion bitShift:4).

        ].

        self at:el put:byte.

    ].

    "/ clock_seq bytes 8-9 

    uuidClockSeq := UUIDRandom getUuidRandom.

    9 to: 10 do:[ : el |

        byte := uuidClockSeq digitAt:2 - el + 9.

        self at:el put:byte.

    ].

    "

    self genUUID.

    "

    "

    1 to: 100 do:[ : el |

        Transcript show:el.

        Transcript show:': '.

        Transcript showCR:(UUID genUUID).

    ].

    "

!

getValidMACAdress

    | macBytes dictOfIf |

    dictOfIf := OperatingSystem getNetworkMACAdresses.

    dictOfIf keysAndValuesDo:[ : key : el |

        ((el value select:([:e | e ~= 0] )) notEmpty) ifTrue:[

            macBytes := el value.

            ^ macBytes

        ].

    ].

    ^ nil

! !

!UUID methodsFor:'printing'!

displayString

    ^ self printString

!

printOn:aStream

    |offs d byte|

    offs := 1.

    d := self unsignedLongAt:1 bigEndian:false.

    offs := offs + 4.

    aStream nextPutAll:((d printStringRadix:16) asLowercase leftPaddedTo:8 with:$0).

    aStream nextPut:$-.

    2 timesRepeat:[

        d := self unsignedShortAt:offs bigEndian:false.

        offs := offs + 2.

        aStream nextPutAll:((d printStringRadix:16) asLowercase leftPaddedTo:4 with:$0).

        aStream nextPut:$-.

    ].

    d := self unsignedShortAt:offs bigEndian:true.

    offs := offs + 2.

    aStream nextPutAll:((d printStringRadix:16) asLowercase leftPaddedTo:4 with:$0).

    aStream nextPut:$-.

    6 timesRepeat:[

        byte := self at:offs.

        offs := offs + 1.

        aStream nextPutAll:((byte printStringRadix:16) asLowercase leftPaddedTo:2 with:$0).

    ].

! !

!UUID::UTCTime class methodsFor:'constants'!

baseTimeDiff

"

 return the constant designation difference in Unix and DTSS base times in 100 nsec intervals

 DTSS UTC base time is October 15, 1582.

 Unix base time is January 1, 1970.

"

    ^ 16r01B21DD213814000

! !

!UUID::UTCTime class methodsFor:'instance creation'!

now

    | utcTime |

    utcTime := super now.

    ^ utcTime getMilliseconds * 10000 + self baseTimeDiff.

! !

!UUID::UUIDRandom class methodsFor:'defaults'!

rand_ia_init

    ^ 11113

!

rand_ib_init

    ^ 104322

!

rand_irand_init

    ^ 4181

!

rand_m_init

    ^ 971

! !

!UUID::UUIDRandom class methodsFor:'instance creation'!

getUuidRandom

    | utcTime length seed retValue|

    rand_m isNil ifTrue:[

        rand_m := self rand_m_init.

    ].

    rand_ia isNil ifTrue:[

        rand_ia := self rand_ia_init.

    ].

    rand_ib isNil ifTrue:[

        rand_ib := self rand_ib_init.

    ].

    rand_irand isNil ifTrue:[

        rand_irand := self rand_irand_init.

        utcTime := UUID::UTCTime now.

        length := utcTime digitLength.

        seed := 0.

        1 to: length do:[ : el |

            seed := seed bitXor:(utcTime digitAt:el).

        ].

        rand_irand := rand_irand + seed + OperatingSystem getProcessId.        

    ].

    rand_m := rand_m + 7.

    rand_ia := rand_ia + 1907.

    rand_ib := rand_ib + 73939.

    (rand_m >= 9973) ifTrue:[ rand_m := rand_m - 9871 ].

    (rand_ia >= 99991) ifTrue:[ rand_ia := rand_ia - 89989 ].

    (rand_ib >= 224729) ifTrue:[ rand_ib := rand_ib - 96233 ].

    rand_irand := (rand_irand * rand_m) + rand_ia + rand_ib.

    retValue := ((rand_irand bitShift:-16) bitXor:(rand_irand bitAnd:16r3fff)).

    ^ retValue

"/ self getUuidRandom

! !

!UUID class methodsFor:'documentation'!

version

    ^ '$Header: /cvs/stx/stx/libbasic2/UUID.st,v 1.1 2003-04-28 12:09:08 cg Exp $'

! !