"

 COPYRIGHT (c) 1992 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

NonPositionableExternalStream subclass:#Socket

       instanceVariableNames:'domain socketType protocol port serviceName

			      peerName'

       classVariableNames:''

       poolDictionaries:''

       category:'Streams-External'

!

!Socket class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1992 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

version

!

documentation

"

    This class provides access to (unix-)sockets for interprocess communication.

    The message protocol is preliminary, until someone tells me how

    other smalltalk's socket interfaces look like.

    Also, currently there is almost no support for other than IP 

    sockets - this will be added in the future.

    Due to historic reasons (I started this class, before I got hold of some

    code using ST-80 Sockets i.e. RemoteInvocation), there is some old interface

    still provided. 

    This will vanish; use the family:type: or newTCPxxx and newUDPxxx interface,

    together with the bind/listen and accept calls,

    which are meant to be compatible to ST-80's UnixSocketAccessor interface.

    ST/X does not use IPSocketAddress, UDSocketAddress erc; all addressing

    is done by passing appropriate string- or byteArray objects containing

    the addresses. This may change, too.

    TODO: cleanup historic leftovers, implement other than inet domain stuff.

"

!

examples

"

    example (get help info from an nntp server):

	|sock host|

	host := OperatingSystem getEnvironment:'NNTPSERVER'.

	sock := Socket newTCPclientToHost:host port:'nntp'.

	Transcript showCr:sock nextLine.

	sock buffered:false.

	sock nextPutAll:'HELP'; cr.

	[:exit |

	    |line|

	    line := sock nextLine.

	    line = '.' ifTrue:[exit value:nil].

	    Transcript showCr:line.

	] loopWithExit.

	sock close

    example (connect to an ftp server):

	|sock host|

	host := OperatingSystem getHostName.

	sock := Socket newTCPclientToHost:host port:'ftp'.

	sock buffered:false.

	Transcript showCr:sock nextLine.

	sock nextPutAll:('USER ' , 'anonymous'); cr.

	Transcript showCr:sock nextLine.

	sock nextPutAll:('PASS ' , 'fooBar'); cr.

	Transcript showCr:sock nextLine.

	sock nextPutAll:'LIST'; cr.

	Transcript showCr:sock nextLine.

	sock close.

	'dont know enough of the ftp protocol to continue here ...'

    example (connect to an snmp server [UDP]):

	|sock port|

	sock := Socket newUDP.

	port := Socket portOfService:'snmp'.

	sock connectTo:(OperatingSystem getHostName) port:port.

	sock buffered:false.

	Transcript showCr:'got it'.

	sock close.

    example (await connection from a client and read some data):

	|connectSock sock|

	connectSock := Socket newTCPserverAtPort:9998.  

	connectSock isNil ifTrue:[

	    Transcript showCr:'socket setup failed.'.

	] ifFalse:[

	    Transcript showCr:'listen ..'.

	    (connectSock listenFor:5) ifFalse:[

		Transcript showCr:'listen failed.'.

	    ] ifTrue:[

		Transcript showCr:'wait'.

		connectSock readWait.  

		Transcript showCr:'accept'.

		sock := connectSock accept.

		sock isNil ifTrue:[

		    Transcript showCr:'accept failed.'.

		] ifFalse:[

		    sock buffered:false.

		    Transcript showCr:'server: got it'.

		    'can now do transfer via sock'.

		    Transcript showCr:'read'.

		    Transcript showCr:('got: ' , sock nextLine).

		    Transcript showCr:'close'.

		    sock close

		].

		connectSock close.

	    ]

	]

    example (connect to above server and send some data):

	|sock|

	sock := Socket newTCPclientToHost:(OperatingSystem getHostName) port:9997.

	sock buffered:false.

	Transcript showCr:'client: got it'.

	'can now do transfer via sock'.

	Transcript showCr:'sending <hello>'.

	sock nextPutLine:'hello'.

	sock close

    example: pingWalk (try to ping hosts on the local network)

	|myName myAddress list top hosts walkProcess port|

	myName := OperatingSystem getHostName.

	myAddress := Socket ipAddressOfHost:myName.

	port := Socket portOfService:'echo'.

	port isNil ifTrue:[

	    self error:'dont know echo port'.

	    ^ self

	].

	top := StandardSystemView new.

	top label:'PING net walk'.

	list := ScrollableView for:ListView in:top.

	list origin:0.0@0.0 corner:1.0@1.0.

	top openAndWait.

	walkProcess := [

	    |l low hi direction tryHostID dottedName hostName conn addr|

	    l := SortedCollection new.

	    ' only works with type C-net

	      the code below could simply do 1 to:254 do:[:hostID }

	      but, to probe likely hosts earlier, the probing is done

	      ping-pong like around my ip-address (assuming, that other machines

	      have numbers around my own)'.

	    low := hi := (myAddress at:4).

	    direction := 1.

	    [low > 0 or:[hi < 255]] whileTrue:[

		direction > 0 ifTrue:[

		    hi := hi + 1.

		    tryHostID := hi.

		    direction := -1.

		] ifFalse:[

		    low := low - 1.

		    tryHostID := low.

		    direction := 1.

		].

		(tryHostID between:1 and:254) ifTrue:[

		    dottedName := (myAddress at:1) printString

				  , '.' , (myAddress at:2) printString

				  , '.' , (myAddress at:3) printString

				  , '.' , tryHostID printString.

		    top label:'PING net walk - trying ' , dottedName.

		    top windowGroup withCursor:Cursor wait do:[

			conn := Socket newTCPclientToHost:dottedName port:port withTimeout:1000.

			conn notNil ifTrue:[

			    addr := Socket ipAddressOfHost:dottedName.

			    hostName := Socket hostWithIpAddress:addr.

			    hostName isNil ifTrue:[

				hostName :='?'

			    ].

			    l add:(dottedName paddedTo:15 with:Character space) 

				   , ' ' 

				   , (hostName paddedTo:15 with:Character space)

				   , ' up & reachable'.

			    list list:l.

			    conn close.

			]

		    ].

		].

	    ].

	    top label:'PING reachable hosts'.

	] forkAt:(Processor userBackgroundPriority).

	walkProcess name:'ping net walker'.

"

! !

!Socket primitiveDefinitions!

%{

/* #define NO_BUFFER */

#include <stdio.h>

#include <errno.h>

#ifdef LINUX

/* kludge to avoid some redefines ... */

# define _ARPA_NAMESER_H

# define _NETINET_TCP_H

#endif

#ifndef transputer

# include <fcntl.h>

# include <sys/types.h>

# if defined(IRIS) && !defined(IRIX5)

   /* no socket.h on 4.0.5h ?!?!? */

#  define AF_UNIX 1

#  define AF_INET 2

#  define SOCK_STREAM 1

#  define SOCK_DGRAM  2

#  define SOCK_RAW    3

# else

#  include <sys/socket.h>

# endif

# ifdef NEXT3

#  include <netinet/in_systm.h>

# endif

# include <netdb.h>

# include <netinet/in.h>

# if ! (defined(SYSV3) && defined(mc88k))

#  include <netinet/tcp.h>

# endif

#endif

/*

 * just in case those PF_xxx's are undefined

 */

#ifdef AF_UNIX

# ifndef PF_UNIX

#  define PF_UNIX AF_UNIX

# endif

#endif

#ifdef AF_INET

# ifndef PF_INET

#  define PF_INET AF_INET

# endif

#endif

#ifdef AF_DECnet

# ifndef PF_DECnet

#  define PF_DECnet AF_DECnet

# endif

#endif

#ifdef AF_APPLETALK

# ifndef PF_APPLETALK

#  define PF_APPLETALK AF_APPLETALK

# endif

#endif

#ifdef AF_X25

# ifndef PF_X25

#  define PF_X25 AF_X25

# endif

#endif

#ifdef AF_NS

# ifndef PF_NS

#  define PF_NS AF_NS

# endif

#endif

#ifdef AF_SNA

# ifndef PF_SNA

#  define PF_SNA AF_SNA

# endif

#endif

#ifdef AF_RAW

# ifndef PF_RAW

#  define PF_RAW AF_RAW

# endif

#endif

#ifdef AF_UNIX

# include <sys/un.h>

#endif

/*

 * on some systems errno is a macro ... check for it here

 */

#ifndef errno

 extern errno;

#endif

static int __debugging__ = 0;

#ifdef DEBUG

# define DBGPRINTF(x)    { if (__debugging__) printf x; }

#else

# define DBGPRINTF(x)    /* as nothing */

#endif

%}

! !

!Socket class methodsFor:'Signal constants'!

brokenConnectionSignal

    "return the signal used to tell broken connections.

     Since in unix, this is the same as the broken pipe signal,

     return that one.

     (for other Operatingsystems, this may change ..)"

    ^ PipeStream brokenPipeSignal

! !

!Socket class methodsFor:'debugging'!

debug:aBoolean

    "turn on/off internal debugprints.

     This method is for ST/X debugging only and

     may  be removed in later versions"

%{  /* NOCONTEXT */

    __debugging__ = (aBoolean == true);

%}

    "

     Socket debug:true

     Socket debug:false

    "

! !

!Socket class methodsFor:'queries'!

ipAddressOfHost:aHostName

    "return the IP (internet-) number for a hostname as a byteArray,

     where the network bytes come first (no matter what the cpus byteOrder is).

     If the host is unknown, return nil.

     This is the reverse operation to #hostWithIpAddress:."

    |b1 b2 b3 b4|

%{

    struct sockaddr_in sa ;

    struct hostent *hp ;

    long addr;

    if (__isString(aHostName)) {

	bzero(&sa, sizeof(sa)) ;

	if ((addr = inet_addr((char *) _stringVal(aHostName))) != -1) {

	    /* is Internet addr in octet notation */

	    bcopy(&addr, (char *) &sa.sin_addr, sizeof(addr)); 

	    sa.sin_family = AF_INET;

	} else {

	    /* do we know the host's address? */

	    if ((hp = gethostbyname((char *) _stringVal(aHostName))) == NULL) {

		DBGPRINTF(("SOCKET: unknown host\n"));

		RETURN ( nil );

	    }

	    bcopy(hp->h_addr, (char *) &sa.sin_addr, hp->h_length) ;

	    sa.sin_family = hp->h_addrtype;

	}

    }

    /* if the addressing family is not AF_INET, return nil */

    if (sa.sin_family != AF_INET) {

	RETURN ( nil );

    }

    sa.sin_addr.s_addr = ntohl(sa.sin_addr.s_addr);    

    b1 = _MKSMALLINT((sa.sin_addr.s_addr >> 24) & 0xFF);

    b2 = _MKSMALLINT((sa.sin_addr.s_addr >> 16) & 0xFF);

    b3 = _MKSMALLINT((sa.sin_addr.s_addr >> 8) & 0xFF);

    b4 = _MKSMALLINT((sa.sin_addr.s_addr >> 0) & 0xFF);

%}

.

    ^ ByteArray with:b1 with:b2 with:b3 with:b4

    "

     Socket ipAddressOfHost:'clam' 

     Socket ipAddressOfHost:'porty'    

     Socket ipAddressOfHost:'axept'    

     Socket ipAddressOfHost:'axept'    

     Socket ipAddressOfHost:'1.2.3.4'    

     Socket ipAddressOfHost:'193.15.16.17'    

     Socket ipAddressOfHost:'josef'     

     Socket ipAddressOfHost:'styx.com'  

     Socket hostWithIpAddress:(Socket ipAddressOfHost:'localhost') 

     Socket ipAddressOfHost:(Socket hostWithIpAddress:'127.0.0.1') 

    "

!

hostWithIpAddress:anAddress

    "return the hostname for an IP (internet-) address.

     The address is supposed to be a byteArray consisting of 4 bytes,

     the network bytes come first (no matter what the local byteorder is).

     This is the reverse operation to #ipAddressOfHost:."

    |b1 b2 b3 b4|

    b1 := anAddress at:1.

    b2 := anAddress at:2.

    b3 := anAddress at:3.

    b4 := anAddress at:4.

%{

    struct sockaddr_in sa ;

    struct hostent *hp ;

    if (__bothSmallInteger(b1, b2) && __bothSmallInteger(b3, b4)) {

	bzero(&sa, sizeof(sa)) ;

	sa.sin_addr.s_addr = _intVal(b1) & 0xFF;

	sa.sin_addr.s_addr = (sa.sin_addr.s_addr << 8) | (_intVal(b2) & 0xFF);

	sa.sin_addr.s_addr = (sa.sin_addr.s_addr << 8) | (_intVal(b3) & 0xFF);

	sa.sin_addr.s_addr = (sa.sin_addr.s_addr << 8) | (_intVal(b4) & 0xFF);

	sa.sin_addr.s_addr = htonl(sa.sin_addr.s_addr);    

	sa.sin_family = AF_INET;

	/* do we know the host's address? */

	hp = gethostbyaddr((char *) &sa.sin_addr.s_addr, sizeof(sa.sin_addr.s_addr), AF_INET);

	if (hp == NULL) {

	    DBGPRINTF(("SOCKET: unknown address: %d.%d.%d.%d\n", 

		       _intVal(b1), _intVal(b2), _intVal(b3), _intVal(b4)));

	} else {

	    sa.sin_family = hp->h_addrtype;

	}

    }

    /* if the addressing family is not AF_INET, return nil */

    if (sa.sin_family != AF_INET) {

	RETURN ( nil );

    }

    if (hp != NULL)

	RETURN (_MKSTRING(hp->h_name COMMA_CON));

    RETURN (_MKSTRING(inet_ntoa(sa.sin_addr) COMMA_CON));

%}

    "

     Socket ipAddressOfHost:'clam'

     Socket hostWithIpAddress:(Socket ipAddressOfHost:'clam') 

     Socket ipAddressOfHost:'porty'

     Socket hostWithIpAddress:(Socket ipAddressOfHost:'porty')