"

 COPYRIGHT (c) 1990-93 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

ArrayedCollection subclass:#VariableString

       instanceVariableNames:'contents'

       classVariableNames:''

       poolDictionaries:''

       category:'Collections-Indexed'

!

VariableString comment:'

COPYRIGHT (c) 1990-93 by Claus Gittinger

              All Rights Reserved

VariableStrings can grow and shrink - in contrast to Strings which are

fixed in size - this may change in the future.

%W% %E%

'!

!VariableString class methodsFor:'initialization'!

initialize

! !

!VariableString class methodsFor:'instance creation'!

new

    "return a new VariableString - with size 0"

    ^ self new:0

!

new:size

    "return a new VariableString"

    ^ (self basicNew) setContents:(String new:size)

!

copyFrom:aString

    "return a new VariableString with contents copied from the argument"

    ^ self basicNew setContents:(String copyFrom:aString)

! !

!VariableString methodsFor:'accessing'!

at:index

    "return the element at index"

    ^ contents at:index

!

at:index put:anObject

    "set the element at index"

    ^ contents at:index put:anObject

! !

!VariableString methodsFor:'queries'!

size

    ^ contents size

!

isFixedSize

    "return true if the receiver cannot grow - this will vanish once

     Arrays and Strings learn how to grow ..."

    ^ false

! !

!VariableString methodsFor:'filling & replacing'!

replaceFrom:start to:stop with:aCollection startingAt:repStart

    "reimplemented for speed

     - can use Strings fast replace if aCollection

       is String or VariableString"

    |col|

    col := aCollection.

    (aCollection isKindOf:VariableString) ifTrue:[

        ((stop - start + repStart) <= aCollection size) ifTrue:[

            col := aCollection getContents

        ]

    ].

    (col isMemberOf:String) ifTrue:[

        (stop <= (contents size)) ifTrue:[

            ^ contents replaceFrom:start to:stop with:col startingAt:repStart

        ]

    ].

    ^ super replaceFrom:start to:stop with:aCollection startingAt:repStart

! !

!VariableString methodsFor:'converting'!

asText

    ^ contents asText

! !

!VariableString methodsFor:'kludges'!

shallowCopy:anArray

    "return a shallow copy of the receiver

     have to kludge the kludge ... - shallow copy the contents array"

    |newText|

    newText := self class basicNew.

    newText setContents:(contents shallowCopy).

    ^ newText

! !

!VariableString methodsFor:'private'!

getContents

    "return the contents array"

    ^ contents

!

setContents:aString

    "set the contents"

    contents := aString

! !

!VariableString methodsFor:'error handling'!

doesNotUnderstand:aMessage

    "this is funny: all message we do not understand, are passed

     on to the string - so we do not have to care for all

     possible messages ...(thanks to the Message class)"

     ^ contents perform:(aMessage selector)

          withArguments:(aMessage arguments)

! !

!VariableString methodsFor:'grow & shrink'!

grow:newSize

    |old oldSize|

    oldSize := contents size.

    (newSize < oldSize) ifTrue:[

        contents := contents copyFrom:1 to:newSize

    ] ifFalse:[

        (newSize > oldSize) ifTrue:[

            old := contents.

            (newSize > (oldSize * 2)) ifTrue:[

                contents := String new:newSize

            ] ifFalse:[

                contents := String new:(oldSize * 2)

            ].

            contents replaceFrom:1 to:oldSize

                            with:old startingAt:1

        ]

    ]

! !