"

 COPYRIGHT (c) 1990 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

PipeStream subclass:#PrinterStream

	instanceVariableNames:'native'

	poolDictionaries:''

	category:'Streams-External'

!

!PrinterStream class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1990 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    a stream for printing; this (concrete or abstract) class can handle only

    very dumb printers. No attributes (italic, bold etc) and no multiple fonts

    are supported - just plain single font text printing.

    More intelligence is added by subclasses (see PostscriptPrinterStream among others.)

    These classes do not support graphics printing - they are only for

    text; although some limited font functionality (such as bold or italic printing)

    may be supported by some subclasses.

    The concrete printer class is bound to the global variable Printer,

    which is either set to PrinterStream (for dumb printers) or to one of

    the subclasses (PostscriptPrinterStream etc.).

    To print:

        |p|

        p := Printer new.

        p notNil ifTrue:[

            p nextPutAll:'hello world'; cr.

            p nextPutAll:' ...'; cr.

            p close

        ].

    See users of the Printer global variable for more examples.

"

! !

!PrinterStream class methodsFor:'initialization'!

initialize

    "this is usually redefined by the startup-file"

    PrintCommand isNil ifTrue:[

	OperatingSystem isBSDlike ifTrue:[

	    PrintCommand := 'lpr'

	] ifFalse:[

	    PrintCommand := 'lp'

	]

    ].

    LeftMargin isNil ifTrue:[

	LeftMargin := 0

    ]

! !

!PrinterStream class methodsFor:'instance creation'!

new

    "return a new stream for printing"

    ^ self basicNew startPrint

!

newNative

    "return a new stream for untranslated printing

     (i.e. text should be sent via nextPutUntranslated in the printers

      native format)"

    ^ self basicNew setNative; writingTo:(self printCommand)

! !

!PrinterStream class methodsFor:'accessing'!

leftMargin:aNumber

    "set the number of blanks for the left margin"

    LeftMargin := aNumber

!

printCommand

    "return command used for printing (usually lp or lpr)"

    ^ PrintCommand

!

printCommand:aString

    "set the command for printing (usually lp or lpr)"

    PrintCommand := aString

    "

     PrinterStream printCommand:'lpr'

     PrinterStream printCommand:'lpr -h'

     PrinterStream printCommand:'rsh ibm lpr -h'

     PrinterStream printCommand:'gs -sDEVICE=djet500 -sOutputFile=/tmp/stx.ps -sPAPERSIZE=a4 -q -; cat /tmp/stx.ps | rsh ibm lpr -h'

    "

! !

!PrinterStream class methodsFor:'queries'!

printerTypeName

    "return a descriptive name"

    ^ 'dumb printer'

    "Modified: 18.4.1996 / 20:04:12 / cg"

!

supportsPostscript

    "return true if this is a postscript printer"

    ^ false

    "Created: 10.2.1996 / 16:23:07 / cg"

! !

!PrinterStream methodsFor:'access font change'!

bold

    "set font to bold

     - ignore here, since this class does not know anything about the printer"

    ^ self

!

courier

    "set font to courier 

     - ignore here, since this class does not know anything about the printer"

    ^ self

!

helvetica

    "set font to helvetic

     - ignore here, since this class does not know anything about the printer"

    ^ self

!

italic

    "set font to italic

     - ignore here, since this class does not know anything about the printer"

    ^ self

!

normal

    "set font to normal (non-bold, non-italic)

     - ignore here, since this class does not know anything about the printer"

    ^ self

!

times

    "set font to times 

     - ignore here, since this class does not know anything about the printer"

    ^ self

! !

!PrinterStream methodsFor:'access writing'!

cr

    "send a carriage-return to the printer"

    super nextPut:(Character cr).

    self spaces:LeftMargin

!

next:count put:aCharacter

    "send some character multiple times to the printer - translate as needed.

     Redefined to allow individual character translation in subclasses"

    count timesRepeat:[

        self nextPut:aCharacter

    ]

    "Created: 10.4.1996 / 13:08:13 / cg"

    "Modified: 10.4.1996 / 13:09:06 / cg"

!

nextPut:aCharacter

    "send some characters to the printer - translate as needed"

    (aCharacter == Character cr) ifTrue:[

	super nextPut:(Character cr).

	self spaces:LeftMargin

    ] ifFalse:[

	super nextPut:aCharacter

    ]

!

nextPutAll:aCollection

    "send some characters to the printer - translate as needed"

    aCollection do:[:aChar |

	self nextPut:aChar

    ]

!

nextPutAllUntranslated:aCollection

    "send some raw characters to the printer - even if not in native mode"

    super nextPutAll:aCollection

    "Modified: 10.4.1996 / 13:08:35 / cg"

!

nextPutUntranslated:aCharacter

    "send a raw character to the printer - even if not in native mode"

    super nextPut:aCharacter

    "Modified: 10.4.1996 / 13:08:28 / cg"

! !

!PrinterStream methodsFor:'helpers writing'!

escape:aCharacter

    "since its so common, this method sends escape followed by aCharacter"

    super nextPut:(Character escape); nextPut:aCharacter

!

escapeAll:aString

    "since its so common, this method sends escape followed by aString"

    super nextPut:(Character escape); nextPutAll:aString

! !

!PrinterStream methodsFor:'open/close'!

basicClose

    super close

!

close

    self endPrint.

    super close

!

endPrint

    ^ self

!

setNative

    native := true

    "Created: 10.4.1996 / 13:05:01 / cg"

!

startPrint

    super writingTo:PrintCommand.

    self spaces:LeftMargin

! !

!PrinterStream methodsFor:'queries'!

lineLength

    "the printer pages width (in characters)"

    ^ 80

! !

!PrinterStream class methodsFor:'documentation'!

version

! !

PrinterStream initialize!