"

 COPYRIGHT (c) 1996 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libhtml' }"

Object subclass:#HTMLDocGenerator

	instanceVariableNames:'outStream'

	classVariableNames:''

	poolDictionaries:''

	category:'System-Documentation'

!

!HTMLDocGenerator class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1996 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    Generates HTML documentation for a class.

    Although this is normally used with the SystemBrowser

    (classes-generate documentation menu),

    it may be useful on its own, to programatically generate

    up-to-date documents from a classes source.

    This generator extracts the documentation methods source

    (or comment), individual method comments (the first comment in

    a method) and version information to generate a neatly formatted

    HTML page.

    If executable examples (EXBEGIN .. EXEND) are present in the classes 

    documentation category these are also added as executable code

    to the document.

    [author:]

        Claus Gittinger

    [see also:]

        BrowserView

        HTMLDocumentView

"

! !

!HTMLDocGenerator class methodsFor:'document generation'!

htmlClassCategoryList

    "generate a formatted list of all available class categories as

     an HTML string. Each category will be a hyperlink to another

     autogenerated page, containing the classes per category.

     The generated page is supposed to be given to an HTML reader

     with home being set to ../doc/online/xxx/classDoc 

     (i.e. the images are to be found one-up in the doc hierarchy)"

    ^ self new htmlClassCategoryList

    "

     HTMLDocGenerator htmlClassCategoryList

    "

!

htmlClassListPrefix:prefix

    "generate an HTML document string which contains HREFS for a list

     of classes which start with some prefix (typically, the first

     character is given)"

    ^ self new htmlClassListPrefix:prefix

    "

     HTMLDocGenerator htmlClassListPrefix:'A'

    "

!

htmlClassesListOfCategory:aCategory backTo:backMessage

    "generate an HTML document string which contains HREFS for a list

     of classes which are contained in a particular category."

    ^ self new htmlClassesListOfCategory:aCategory backTo:backMessage

!

htmlDocOf:aClass

    "generate an HTML document string which contains a classes documentation"

    ^ self new htmlDocOf:aClass

    "

     HTMLDocGenerator htmlDocOf:Array

    "

!

htmlDocOfImplementorsOf:selector

    "generate an HTML document string which contains HREFS

     to all implementors of a particular selector"

    ^ self new htmlDocOfImplementorsOf:selector

    "

     HTMLDocGenerator htmlDocOfImplementorsOf:#at:

    "

!

htmlSelectorList

    "generate an HTML string for all selectors (for which methods exist)

     in the system"

    ^ self new htmlSelectorList

    "

     HTMLDocGenerator htmlSelectorList

    "

!

htmlSelectorListMatching:prefix

    "generate an HTML string for all selectors which match a pattern

     (and for which methods exist) in the system"

    ^ self new htmlSelectorListMatching:prefix

!

htmlSelectorListPrefix:prefix

    "generate an HTML string for all selectors whose names starts with

     a prefix (and for which methods exist) in the system"

    ^ self new htmlSelectorListPrefix:prefix

    "

     HTMLDocGenerator htmlSelectorListPrefix:'a'

    "

!

manPageFor:aCommandName

    "generate a (unix-) man page for a given command & convert the output to html"

    ^ self new manPageFor:aCommandName

    "

     HTMLDocGenerator manPageFor:'ls'

     HTMLDocumentView openFullOnText:(HTMLDocGenerator manPageFor:'ls')

    "

!

manPageFor:aManPageTemplateFile manCommand:nroffCommand

    "convert man-command output to html.

     Only the body of the text (without head../head and body../body) is generated"

    ^ self new manPageFor:aManPageTemplateFile manCommand:nroffCommand

    "

     HTMLDocGenerator 

        manPageForFile:'/usr/man/man2/open.2'

        manCommand:'nroff -man /usr/man/man2/open.2'

    "

!

manPageForFile:aManPageTemplateFile

    "convert a .man file to html"

    ^ self new manPageForFile:aManPageTemplateFile

    "

     HTMLDocGenerator manPageForFile:'/usr/man/man2/open.2'

     HTMLDocumentView openFullOnText:(HTMLDocGenerator manPageForFile:'../../stc/stc.1')

    "

! !

!HTMLDocGenerator methodsFor:'document generation'!

htmlClassCategoryList

    "generate a formatted list of all available class categories as

     an HTML string. Each category will be a hyperlink to another

     autogenerated page, containing the classes per category.

     The generated page is supposed to be given to an HTML reader

     with home being set to ../doc/online/xxx/classDoc 

     (i.e. the images are to be found one-up in the doc hierarchy)"

    |categories s prefixList prefix prefixStack prev|

    categories := Smalltalk allClassCategories asOrderedCollection sort.

    outStream := s := '' writeStream.

    self generateHTMLHeadWithTitle:'Class Categories:'.

    s nextPutLine:'<body>'.

    self generateUpArrowButtonForTop.

    self generateHorizontalLine.

    self generateH1:'Class Categories:'.

    s nextPutLine:'<ul>'.

    prefixList := Set new.

    categories keysAndValuesDo:[:index :element |

        |prev common|

        index ~~ 1 ifTrue:[

            prev := categories at:(index - 1).

            common := (Array with:prev with:element) longestCommonPrefix.

            (common endsWith:'-') ifTrue:[

                prefixList add:(common copyWithoutLast:1)

            ] ifFalse:[

                (common includes:$-) ifTrue:[

                    prefixList add:(common copyTo:(common lastIndexOf:$-)-1).

                ] ifFalse:[

"/                    common = prev ifTrue:[

"/                        prefixList add:common

"/                    ]

                ]

            ]

        ]

    ].

    prefix := ''. prefixStack := OrderedCollection new. 

    prev := ''.

    categories := categories select:[:nm | nm ~= 'obsolete'].

    categories do:[:nm |

        |longest|

        "/ longest prefix ....

        longest := prefixList inject:'' into:[:maxPrefix :prefix |

                        |prefixWithDash|

                        prefixWithDash := prefix , '-'.

                        nm = prefix ifTrue:[

                            maxPrefix

                        ] ifFalse:[

                            (nm startsWith:prefixWithDash)

                            ifTrue:[

                                prefixWithDash size > maxPrefix size

                                ifTrue:[

                                    prefixWithDash

                                ] ifFalse:[

                                    maxPrefix

                                ]

                            ] ifFalse:[

                                maxPrefix

                            ]

                        ]

                   ].

        longest size > 0 ifTrue:[

            longest = prefix ifTrue:[

                "/ no change

            ] ifFalse:[

                (longest startsWith:prefix) ifTrue:[

                    prefixStack addLast:longest.

                    longest ~= prev ifTrue:[    

                        prefixStack size == 1 ifTrue:[

                            s nextPutLine:'<p>'.

                        ].

                        s nextPutLine:'<li>' , (longest copyFrom:prefix size + 1).

                    ].

                    s nextPutLine:'<ul>'.

                    prefix := longest.

                ] ifFalse:[

                    s nextPutLine:'</ul>'.

                    prefixStack notEmpty ifTrue:[

                        prefixStack removeLast.

                    ].

                    [prefixStack notEmpty

                     and:[(longest startsWith:prefixStack last) not]] whileTrue:[

                        s nextPutLine:'</ul>'.

                        prefixStack removeLast.

                    ].

                    prefixStack notEmpty ifTrue:[

                        prefix := prefixStack last.

                    ] ifFalse:[

                        prefixStack addLast:longest.

                        prefix := longest.

                        longest ~= prev ifTrue:[    

                            prefixStack size == 1 ifTrue:[

                                s nextPutLine:'<p>'.

                            ].

                            s nextPutLine:'<li>' , longest.

                        ].

                        s nextPutLine:'<ul>'.

                    ] 

                ].

            ]

        ] ifFalse:[

            [prefixStack size > 0] whileTrue:[

                s nextPutLine:'</ul>'.

                prefixStack removeLast.

            ].

            prefixStack size == 0 ifTrue:[

                s nextPutLine:'<p>'.

            ].

            prefix := ''.

        ].

        s nextPutAll:'<li>'.

        s nextPutLine:(self 

                        anchorForHTMLDocAction:

                            ('htmlClassesListOfCategory:''', nm

                            , ''' backTo:''htmlClassCategoryList''')

                        info:

                            ('Classes in ' , nm)

                        text:

                            (nm copyFrom:prefix size + 1)).

        prev := nm.

    ].

    s nextPutAll:'

</ul>

</body>

</html>

'.

    ^ s contents

    "

     HTMLDocGenerator new htmlClassCategoryList

    "

    "Created: / 22.4.1996 / 20:03:30 / cg"

    "Modified: / 30.10.1997 / 13:16:08 / cg"

!

htmlClassListPrefix:prefix

    "generate an HTML document string which contains HREFS for a list

     of classes which start with some prefix (typically, the first

     character is given)"

    |classes|

    classes := Smalltalk allClasses

                select:[:cls | 

                                cls isPrivate not

                                and:[(cls isNameSpace not or:[cls == Smalltalk])

                                and:[cls name startsWith:prefix]]

                       ].

    ^ self 

        htmlClasses:classes 

        title:('Classes starting with ''' , prefix asString , ''':').

    "Created: / 22.4.1996 / 20:03:31 / cg"

    "Modified: / 30.10.1997 / 13:21:49 / cg"

!

htmlClasses:classes title:title

    "generate an HTML document string which contains HREFS for a given list

     of classes"

    ^ self

        htmlClasses:classes 

        title:title 

        backTo:nil

    "Modified: / 30.10.1997 / 13:21:40 / cg"

!

htmlClasses:classes title:title backTo:backRef

    "generate an HTML document string which contains HREFS for a given list

     of classes. If backref is nonNil, a back-button to that

     HREF is added at the top.

     The generated page is supposed to be given to an HTML reader

     with home being set to ../doc/online/xxx/classDoc 

     (i.e. the images are to be found one-up in the doc hierarchy)"

    |classNames s|

    classNames := (classes collect:[:cls | cls name]) asOrderedCollection sort.

    outStream := s := '' writeStream.

    self generateHTMLHeadWithTitle:title.

    s nextPutLine:'<body>'.

    backRef notNil ifTrue:[

        backRef ~~ #none ifTrue:[

            self

                generateUpArrowButtonWithReference:'TOP.html' 

                command:backRef 

                imagePath:nil 

                altLabel:'back'.

        ]

    ] ifFalse:[

        self

            generateUpArrowButtonWithReference:'TOP.html' 

            command:nil 

            imagePath:nil 

            altLabel:'top'.

    ].

    backRef ~~ #none ifTrue:[

        self generateHorizontalLine.

    ].

    self generateH1:title.

    s nextPutLine:'<ul>'.

    classNames do:[:className |

        s nextPutAll:'<li>'.

        self generateClassDocReferenceFor:className.

    ].

    s nextPutAll:'

</ul>

</body>

</html>

'.

    ^ s contents

    "Created: / 23.4.1996 / 15:31:55 / cg"

    "Modified: / 30.10.1997 / 13:21:32 / cg"

!

htmlClassesListOfCategory:category

    "generate an HTML document string which contains HREFS for a list

     of classes which are contained in a particular category."

    ^ self

        htmlClassesListOfCategory:category

        backTo:nil

    "Modified: / 30.10.1997 / 13:21:23 / cg"

!

htmlClassesListOfCategory:category backTo:backRef

    "generate an HTML document string which contains HREFS for a list

     of classes which are contained in a particular category."

    |classes|

    classes := Smalltalk allClasses

                select:[:cls | cls isPrivate not

                               and:[(cls isNameSpace not or:[cls == Smalltalk])

                               and:[cls category = category]]

                       ].

    ^ self 

        htmlClasses:classes 

        title:('Classes in: ' , category)

        backTo:backRef

    "Created: / 23.4.1996 / 15:39:39 / cg"

    "Modified: / 30.10.1997 / 13:21:16 / cg"

!

htmlClassesMatching:aMatchPattern backTo:backRef

    "generate an HTML document string which contains HREFS

     for a list of classes whose name matches a given matchPattern."

    |classes cls|

    classes := Smalltalk allClasses

                select:[:cls | cls isPrivate not

                               and:[(cls isNameSpace not or:[cls == Smalltalk])

                               and:[aMatchPattern match:cls name]]

                       ].

    ^ self 

        htmlClasses:classes 

        title:('Classes matching: ' , aMatchPattern)

        backTo:backRef

    "

     self htmlClassesMatching:'Tgen::*' backTo:nil

    "

    "Modified: / 30.10.1997 / 13:21:06 / cg"

!

htmlDocOf:aClass

    "generate an HTML document string which contains a classes documentation"

    ^ self htmlDocOf:aClass back:nil backRef:nil

    "

     self htmlDocOf:PostscriptPrinterStream

    "