"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic3' }"

OrderedCollection subclass:#ChangeSet

	instanceVariableNames:'changedClasses changeSelectors'

	classVariableNames:''

	poolDictionaries:''

	category:'System-Changes'

!

Object subclass:#ChangeFileReader

	instanceVariableNames:'inputStream parseTree changeAction changeSet selector receiver

		arguments receiverSelector receiverReceiver lineNumber position

		className methodSelector'

	classVariableNames:''

	poolDictionaries:''

	privateIn:ChangeSet

!

Object subclass:#DiffSet

	instanceVariableNames:'changed onlyInReceiver onlyInArg'

	classVariableNames:''

	poolDictionaries:''

	privateIn:ChangeSet

!

ChangeSet::ChangeFileReader subclass:#DolphinPACFileReader

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:ChangeSet

!

ChangeSet::ChangeFileReader subclass:#SIFChangeFileReader

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:ChangeSet

!

!ChangeSet class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    used in the changes management to keep track of changes

    [author:]

	Claus Gittinger

"

! !

!ChangeSet class methodsFor:'instance creation'!

decodedStreamFor:aStream

    |encoding decoder decodedStream|

    encoding := CharacterEncoder guessEncodingOfStream:aStream.

    (encoding isNil

    or:[ encoding == #'iso8859-1' 

    or:[ encoding == #'ascii' ]]) ifTrue:[

        ^ aStream

    ].

    decoder := CharacterEncoder encoderFor:encoding.

    decodedStream := EncodedStream stream:aStream encoder:decoder.

    decodedStream skipEncodingChunk.

    ^ decodedStream

!

forExistingClass:aClass

    "build a changeSet for some given class, all of its private classes

     and all extensions if any. 

     I.e. a changeSet which represents the existing class in the image.

     That does of course not give deltas, but instead reflects the current

     state of the given class.

     It is useful in conjunction with the other utility methods,

     for example, when building patchLists, diffSets, comparing etc."

    |changeSet s changeObject|

    s := ReadWriteStream on:''.

    aClass fileOutOn:s.

    s reset.

    changeSet := self fromStream:s.

    "/ fetch the real package info...

    changeSet do:[:eachChange |

        eachChange isMethodChange ifTrue:[

            changeObject := eachChange changeMethod.

            changeObject notNil ifTrue:[

                eachChange package:changeObject package

            ].

        ] ifFalse:[

            eachChange isClassChange ifTrue:[

                changeObject := eachChange changeClass.

                changeObject notNil ifTrue:[

                    eachChange package:changeObject package

                ].

            ].

        ].

    ].

    ^ changeSet

"/    |source changeSet chunk sawExcla lastTimeStamp s change nameSpace|

"/    changeSet := self new.

"/

"/    "/ first, a classDefinition change ...

"/    changeSet addClassDefinitionChangeFor:aClass.

"/    "/ are there any class-instVars ?

"/    aClass class instVarNames size > 0 ifTrue:[

"/        changeSet addInstVarDefinitionChangeFor:aClass class.

"/    ].

"/    "/ a comment ?

"/    aClass comment size > 0 ifTrue:[

"/        changeSet addClassCommentChangeFor:aClass.

"/    ].

"/

"/    "/ class methods first ...

"/    aClass class methodDictionary keysAndValuesDo:[:sel :mthd |

"/        changeSet addMethodChange:mthd in:aClass class. 

"/    ].

"/

"/    "/ instance methods ...

"/    aClass methodDictionary keysAndValuesDo:[:sel :mthd |

"/        changeSet addMethodChange:mthd in:aClass.

"/    ].

"/

"/    ^ changeSet

    "

     ChangeSet forExistingClass:ChangeSet

     ChangeSet forExistingClass:A

     Rectangle hasExtensions

     ChangeSet forExistingClass:Rectangle

    "

    "Created: / 16-02-1998 / 12:19:34 / cg"

    "Modified: / 12-10-2006 / 23:45:14 / cg"

!

forExistingClass:aClass withExtensions:withExtensions extensionsOnly:extensionsOnly

    "build a changeSet for some given full class, the base-class or the extensions only,

     as specified by the with-arguments.

     That does of course not give deltas, but instead reflects the current

     state of the given class.

     It is useful in conjunction with the other utility methods,

     for example, when building patchLists, diffSets etc."

    |changeSet classPackage|

    changeSet := self forExistingClass:aClass.

    classPackage := aClass package.

    extensionsOnly ifTrue:[

        ^ changeSet 

            select:[:change |

                change isMethodChange and:[ change package ~= classPackage ]

            ].

    ].

    withExtensions ifFalse:[

        ^ changeSet 

            reject:[:change |

                change isMethodChange and:[ change package ~= classPackage ]

            ].

    ].

    ^ changeSet

    "

     ChangeSet forExistingClass:ChangeSet

     Rectangle hasExtensions

     Rectangle extensions

     ChangeSet forExistingClass:Rectangle withExtensions:true extensionsOnly:false

     ChangeSet forExistingClass:Rectangle withExtensions:false extensionsOnly:false

     ChangeSet forExistingClass:Rectangle withExtensions:false extensionsOnly:true

    "

    "Created: / 12-10-2006 / 18:13:02 / cg"

    "Modified: / 12-10-2006 / 23:46:05 / cg"

!

forExistingMethods:aCollectionOfMethods

    "build a changeSet for a collection of methods.

     That does of course not give deltas, but instead reflects the current

     state of the given set of methods.

     It is useful in conjunction with the other utility methods,

     for example, when building patchLists, diffSets etc."

    |changeSet stream previousPackage|

    stream := ReadWriteStream on:''.

    aCollectionOfMethods do:[:eachMethod | 

        previousPackage ~= eachMethod package ifTrue:[

            stream nextPutAll:'"{ Package: '''.

            stream nextPutAll:eachMethod package asString.

            stream nextPutAll:''' }"'; cr; cr.

        ].

        eachMethod mclass fileOutMethod:eachMethod on:stream

    ].

    stream reset.

    changeSet := self fromStream:stream.

    changeSet do:[:eachChange |

        eachChange package:(eachChange changeMethod package).

    ].

    ^ changeSet

    "

     ChangeSet forExistingMethods:(Array with:(Array compiledMethodAt:#at:)

                                         with:(Object compiledMethodAt:#at:)

                                         with:(Behavior compiledMethodAt:#compiledMethodAt:) )

    "

    "Modified: / 13-10-2006 / 00:33:15 / cg"

!

fromDolphinPACStream:aStream

    "build a changeSet from a stream, containing dolphin pac file chunks."

    ^ self fromDolphinPACStream:aStream while:[:thisChange | true]

!

fromDolphinPACStream:aStream while:aConditionBlock

    "build a changeSet from a stream, containing dolphin pac file chunks."

    |changeSet|

    changeSet := self new.

    self 

        changesFromStream:aStream 

        for:changeSet 

        reader:(DolphinPACFileReader new) 

        do:[:aChange :lineNumberOrNil :posOrNil |

            changeSet add:aChange.

            (aConditionBlock value:aChange) ifFalse:[^ changeSet].

        ].

    ^ changeSet

!

fromFile:aFilename

    |mime stream|

    mime := MIMETypes mimeTypeForFilename:aFilename.

    mime isNil ifTrue:[

        mime := aFilename asFilename mimeTypeOfContents.

        mime isNil ifTrue:[

            self error:'unknown MIME type for file'.

        ].

    ].

    [

        stream := aFilename asFilename readStream.

        mime = 'text/xml' ifTrue:[

            ^ self fromXMLStream:stream.

        ].

        mime = 'application/x-smalltalk-source-sif' ifTrue:[

            ^ self fromSIFStream:stream.

        ].

        mime = 'application/x-smalltalk-dolphin-package' ifTrue:[

            ^ self fromDolphinPACStream:stream.

        ].            

        stream := self decodedStreamFor:stream.

        ^ self fromStream:stream.

    ] ensure:[

        stream notNil ifTrue:[stream close].

    ].

    "

     ChangeSet fromFile:('changes')

     ChangeSet fromFile:('patches')

    "

    "Created: / 16.2.1998 / 12:19:34 / cg"

    "Modified: / 14.12.1999 / 15:23:16 / cg"

!

fromSIFStream:aStream

    "build a changeSet from a SIF stream, containing chunks

     in smalltalk interchange format.

     Return the changeSet."

    ^ self fromSIFStream:aStream while:[:thisChange | true]

!

fromSIFStream:aStream while:aConditionBlock

    "build a changeSet from a SIF stream, containing chunks

     in smalltalk interchange format.

     Return the changeSet."

    |changeSet|

    changeSet := self new.

    self 

        changesFromStream:aStream 

        for:changeSet 

        reader:(SIFChangeFileReader new) 

        do:[:aChange :lineNumberOrNil :posOrNil |

            changeSet add:aChange.

            (aConditionBlock value:aChange) ifFalse:[^ changeSet].

        ].

    ^ changeSet

!

fromStream:aStream

    "build a changeSet from a stream, containing chunks.

     (i.e. either a classes sourceFile or a change-file).

     Return the changeSet."

    ^ self fromStream:aStream while:[:thisChange | true]

    "

     ChangeSet fromStream:('changes' asFilename readStream)

     ChangeSet fromStream:('patches' asFilename readStream)

     ChangeSet fromStream:(Object source asString readStream)

    "

    "Created: / 16.2.1998 / 12:19:34 / cg"

    "Modified: / 14.12.1999 / 15:23:16 / cg"

!

fromStream:aStream while:aConditionBlock

    "build a changeSet from a stream, containing chunks.

     (i.e. either a classes sourceFile or a change-file).

     Return the changeSet."

    |changeSet|

    changeSet := self new.

    self 

        changesFromStream:aStream 

        for:changeSet 

        reader:(ChangeFileReader new)

        do:[:aChange :lineNumberOrNil :posOrNil |

            changeSet add:aChange.

            (aConditionBlock value:aChange) ifFalse:[^ changeSet].

        ].

    ^ changeSet

    "

     ChangeSet fromStream:('changes' asFilename readStream)

     ChangeSet fromStream:('patches' asFilename readStream)

     ChangeSet fromStream:(Object source asString readStream)

    "

    "Created: / 16.2.1998 / 12:19:34 / cg"

    "Modified: / 14.12.1999 / 15:23:16 / cg"

!

fromXMLStream:aStream

    "build a changeSet from an XML stream, containing XML definitions.

     Return the changeSet."

    |changeSet builder nameSpace|

    aStream isNil ifTrue:[^ nil].

    changeSet := self new.

    nameSpace := Smalltalk.

    builder := XML::SourceScannerNodeBuilder new.

    builder scanFile:aStream do:[:change | changeSet add: change. ].

    ^ changeSet

    "

     ChangeSet fromXMLStream:('../../goodies/xml/vw/xmlFileInTests/XMLParser.xml' asFilename readStream)

     ChangeSetBrowser 

        openOn:(ChangeSet fromXMLStream:('../../goodies/xml/vw/xmlFileInTests/XMLParser.xml' asFilename readStream))

    "

! !

!ChangeSet class methodsFor:'Compatibility-ST80'!

patches

    ^ #()

    "Created: / 27.10.1997 / 13:52:54 / cg"

! !

!ChangeSet class methodsFor:'Compatibility-VW'!

component: component definition: anObject change: changeSymbol

    "Include indication that a class/namespace was added or removed

     from a CodeComponent." 

    self 

        changed:#'component:definition:change:'

        with:

            ( Array 

                    with: component

                    with: anObject

                    with: changeSymbol

            )

! !

!ChangeSet class methodsFor:'instance creation-private'!

changesFromStream:aStream do:aBlock

    "enumerate changes from a stream and invoke aBlock on each.

     The block is invoked with the change, a lineNumberOrNil and streamPosition arguments. 

     The lineNumber is only valid, if the underlying stream 

     provides line-numbers; otherwise, nil is passed."

    ^ self

        changesFromStream:aStream 

        for:(self new) 

        reader:nil

        do:aBlock

    "

     ChangeSet 

        changesFromStream:('changes' asFilename readStream) 

        do:[:chg | Transcript showCR:chg]

    "

    "Created: / 16.2.1998 / 12:19:34 / cg"

    "Modified: / 14.12.1999 / 15:23:16 / cg"

!

changesFromStream:aStream for:aChangeSet reader:aReader do:aBlock

    "enumerate changes from a stream and invoke aBlock on each.

     The block is invoked with the change, a lineNumberOrNil and streamPosition arguments. 

     The lineNumber is only valid, if the underlying stream 

     provides line-numbers; otherwise, nil is passed."

    |chunk lastTimeStamp s change nameSpace package

     lineNumber pos reader|

    nameSpace := Smalltalk.

    package := Class packageQuerySignal query.

    (reader := aReader) isNil ifTrue:[

        reader := ChangeFileReader new.

    ].

    reader changeSet:aChangeSet.

    reader changeAction:aBlock.

    reader inputStream:aStream.

    [aStream atEnd] whileFalse:[

        aStream skipSeparators.

        lineNumber := aStream lineNumber.

        pos := aStream position1Based.

        chunk := aStream nextChunk.

        (chunk notEmptyOrNil) ifTrue:[

            Class nameSpaceQuerySignal answer:nameSpace do:[

                |parser tree ns pkg|

                parser := Parser for:chunk.

                tree := parser 

                            parseExpressionWithSelf:nil 

                            notifying:nil 

                            ignoreErrors:true 

                            ignoreWarnings:true 

                            inNameSpace:nameSpace.