"

 COPYRIGHT (c) 1995 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

'From Smalltalk/X, Version:2.10.4 on 20-feb-1995 at 6:26:23 am'!

Array subclass:#ImmutableArray

	 instanceVariableNames:''

	 classVariableNames:''

	 poolDictionaries:''

	 category:'System-Compiler-Support'

!

!ImmutableArray class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1995 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

version

"

"

!

documentation

"

    By default, array literals in smalltalk are mutable objects. That

    a literal array constant as argument to someone else, who changes the

    array using at:put: like messages. Since the array object is kept in 

    the first methods literals, the array constant has now been changed without

    behave differently from what its source may make you think.

    configured to create instances of this ImmutableArray instead of Arrays

    for array literals. Instances of ImmutableArray catch storing accesses and

    enter the debugger. Although useful, this feature is disabled by default

    for compatibility to other smalltalk implementations. 

    (Also, if turned on, this makes inspecting array literals entered in

     a workspace somewhat strange: you cannot modify it any longer).

    Turn the ImmutableArray feature on by setting the Parsers class variable

"

! !

!ImmutableArray methodsFor:'error handling'!

creator 

    "find the method that contains me"

    Method allSubInstances do:[:aMethod |

	|lits|

	lits := aMethod literals.

	(lits notNil and:[(lits identityIndexOf:self) ~~ 0]) ifTrue:[

	    ^ aMethod

	]

    ].

    ^ nil

!

notifyStoreError

    "a store is attempted - for our convenience, find the method that

     contains me, for a nicer error message"

    |creator msg|

    creator := self creator.

    msg := 'store into/change of literal'.

    creator notNil ifTrue:[

	msg := msg , ' (' , creator whoString , ')'

    ].

    "

     this error is reported on an attempt to store into a literal

     array. The literal was created in creator.

     If you press continue in the debugger, the store will be performed.

     If you dont want this, press abort and check your code.

     Storing into literals is VERY VERY bad coding style.

    "

    self error:msg

! !

!ImmutableArray methodsFor:'accessing'!

at: index put: value

    "Trigger an error if an immutable array is stored into.

     The store will be performed (for compatibility reasons) if you continue

     in the debugger."

    self notifyStoreError.

    ^ super at: index put: value

!

basicAt: index put: value

    "Trigger an error if an immutable array is stored into.

     The store will be performed (for compatibility reasons) if you continue

     in the debugger."

    self notifyStoreError.

    ^ super basicAt: index put: value

! !

!ImmutableArray methodsFor:'specials'!

become:anotherObject

    self notifyStoreError.

    ^ super become:anotherObject

!

becomeNil

    self notifyStoreError.

    ^ super becomeNil

! !

!ImmutableArray methodsFor:'private'!

species

    "Copies should be mutable"

    ^Array

! !

!ImmutableArray methodsFor:'queries'!

isLiteral

    "return true, if the receiver can be used as a literal

     (i.e. can be used in constant arrays)"

    "yes, I must be"

    ^ true

! !

!ImmutableArray methodsFor:'copying'!

copyEmptyAndGrow:size

    ^ Array new:size

!

copyEmpty

    ^ Array new:self size

!

shallowCopy

    ^ Array new:self size withAll:self

!

postCopy

    self changeClassTo:Array.

! !