"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

Object subclass:#ObjectFileLoader

	instanceVariableNames:''

	classVariableNames:'MySymbolTable Verbose LastError LinkErrorMessage NextHandleID

		LoadedObjects PreviouslyLoadedObjects ActuallyLoadedObjects

		SearchedLibraries LibPath LoadLibraryPath ErrorPrinting

		LinkCommand LinkArgs'

	poolDictionaries:''

	category:'System-Compiler'

!

!ObjectFileLoader primitiveDefinitions!

%{

/*

 * by default, use whatever the system provides

 */

#ifdef sunos    /* sunos (pre 5.4) dlopen interface */

# define SUN_DL

# define HAS_DL

#endif

#ifdef NeXT     /* next rld interface */

# define NEXT_DL

# define HAS_DL

#endif

#if defined(SYSV4) || defined(HAS_DLOPEN)   /* sys5.4 dlopen interface */

# define SYSV4_DL

# define HAS_DL

#endif

#if defined(hpux10)

# undef SYSV4_DL

# define HPUX10_DL

# define HAS_DL

#endif

#if defined(alpha) && defined(__osf__)

# define SYSV4_DL

# define HAS_DL

#endif

#ifdef __VMS__

# undef __new

# define VMS_DL

#endif

#ifdef DL1_6    /* dl1.6 COFF loader */

# define HAS_DL

#endif

#ifdef _AIX

# define AIX_DL

# define HAS_DL

#endif

/*

 * but GNU_DL overwrites this - its better

 */

#ifdef GNU_DL   /* dld2.3.x interface */

# define HAS_DL

# undef SYSV4_DL

# undef NEXT_DL

# undef SUN_DL

# undef DL1_6

#endif

#include <stdio.h>

#if defined(WIN32)

# undef COFF

# undef ELF

# undef A_DOT_OUT

# define HAS_DL

# define WIN_DL

#endif

/*

 * if no dynamic link facilities, try it the hard way ...

 */

#if !defined(HAS_DL)

# ifdef A_DOT_OUT

#  include <a.out.h>

#  ifndef N_MAGIC

#   if defined(sinix) && defined(BSD)

#    define N_MAGIC(hdr) (hdr.a_magic & 0xFFFF)

#   else

#    define N_MAGIC(hdr) (hdr.a_magic)

#   endif

#  endif

# endif /* a.out */

# ifdef COFF

#  ifdef mips

#    include <sys/exec.h>

#  else

#    include <a.out.h>

#  endif

# endif /* coff */

# ifdef ELF

#  include <elf.h>

# endif /* elf */

#endif /* not HAS_DL */

#ifdef NEXT_DL

# ifndef _RLD_H_

#  define _RLD_H_

#  ifdef NEXT3

#   include <mach-o/rld.h>

#  else

#   include <rld.h>

#  endif

# endif

#endif /* NEXT_DL */

#ifdef SYSV4_DL

# include <dlfcn.h>

# define dlcfn_h

#endif

#ifdef GNU_DL

#  ifndef dld_h

#   include "dld.h"

#   define dld_h

#  endif

#endif

#ifdef DL1_6

#  ifndef dl_h

#   include "dl.h"

#   define dl_h

#  endif

#endif

#ifdef AIX_DL

# include <nlist.h>

# include <sys/ldr.h>

# include <errno.h>

#endif

#ifdef HPUX10_DL

# include <dl.h>

# include <errno.h>

#endif

#ifdef WIN_DL

# ifdef WIN32

#  undef INT

#  undef Array

#  undef Number

#  undef Method

#  undef Block

#  ifdef i386

#   ifndef _X86_

#    define _X86_

#   endif

#  endif

#  ifdef __BORLANDC__

#   define NOATOM

#   define NOUSER

#   define NOGDI

#   define NOGDICAPMASKS

#   define NOMETAFILE

#   define NOMINMAX

#   define NOMSG

#   define NOOPENFILE

#   define NORASTEROPS

#   define NOSCROLL

#   define NOSOUND

#   define NOSYSMETRICS

#   define NOTEXTMETRIC

#   define NOWH

#   define NOCOMM

#   define NOKANJI

#   define NOCRYPT

#   define NOMCX

#   define WIN32_LEAN_AND_MEAN

#   include <windows.h> /* */

#  else

/* #  include <windows.h> /* */

#  endif

#  include <windef.h> /* */

#  include <winbase.h> /* */

#  ifdef __DEF_Array

#   define Array __DEF_Array

#  endif

#  ifdef __DEF_Number

#   define Number __DEF_Number

#  endif

#  ifdef __DEF_Method

#   define Method __DEF_Method

#  endif

#  ifdef __DEF_Block

#   define Block __DEF_Block

#  endif

# endif

#endif /* WIN_DL */

%}

! !

!ObjectFileLoader class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    This class knowns how to dynamically load in external object-modules.

    WARNING:

      As to date, this is completely experimental and WITHOUT ANY WARRANTY.

      It is still being developed and the code below needs cleanup and more

      robustness.

    There are basically two totally different mechanisms to do this:

	a) if there exists some dynamic-link facility such as:

	   GNU-DL, dlopen (sparc, SYS5.4), rld_open (NeXT),

	   this is used

	b) if no such facility exists, the normal linker is used to

	   link the module to text/data address as previously malloced,

	   and the object file loaded into that space.

    Currently, not all mechanisms work fully satisfying.

    For example, the sun dl*-functions do an exit on link-errors (which

    is certainly not what we want here :-(; the NeXT mechanism does not

    allow for selective unloading (only all or last).

    The only really useful packages are the GNU-dl package and the SGI/Unixware

    sys5.4 libdl packages. 

    The GNU-dl package is only available for a.out file formats; 

    i.e. only (a subset of) linux people can use it at this time.

    For the above reasons, dynamic object loading is currently only

    officially released for SYS5.4 and LINUX systems.

    Once stable, the functionality contained herein will be moved into

    the VM. 

    (It is needed there, to allow reloading of objectfiles upon

     image restart; i.e. before any class is reinitialilized).

    [author:]

	Claus Gittinger

"

! !

!ObjectFileLoader class methodsFor:'initialization'!

initialize

    |systemType|

    OperatingSystem isMSDOSlike ifTrue:[

        "/ default setup for msc

        OperatingSystem getCCDefine ='__BORLANDC__' ifTrue:[

            LinkCommand isNil ifTrue:[

            ].

            LinkArgs isNil ifTrue:[

                LinkArgs := '-L..\libbc -L\Programme\Borland\CBuilder3\lib -c -ap -Tpd -s -Gi -v -w-dup ..\libbc\librun.lib'.

            ].

        ] ifFalse:[

            LinkCommand isNil ifTrue:[

                LinkCommand := 'link'

            ].

            LinkArgs isNil ifTrue:[

                LinkArgs := '/NOPACK /NOLOGO /DEBUG /MACHINE:I386 /DLL /OUT:%1.dll /DEF:%1.def'

            ].

        ].

    ].

    MySymbolTable isNil ifTrue:[

        Verbose := false.

        NextHandleID := 1.

        ObjectMemory addDependent:self.

"/      OperatingSystem isMSDOSlike ifTrue:[

"/          "/ ... we'll see

"/      ].

        OperatingSystem isUNIXlike ifTrue:[

            systemType := OperatingSystem getOSType.

            "/ name of object file, where initial symbol table is found

            "/ not req'd for all architectures.

            MySymbolTable := 'stx'.

            "/ default set of libraries to be considered when

            "/ unresolved symbols are encountered during the load.

            "/ Only req'd for linux and sunos non-ELF systems.

            "/ Can (should) be set in the smalltalk.rc file.

            SearchedLibraries := #().

            (systemType = 'linux' 

            or:[systemType = 'sunos']) ifTrue:[

                '/usr/lib/libc.a' asFilename isReadable ifTrue:[

                    SearchedLibraries := #('/usr/lib/libc.a')

                ] ifFalse:[

                    '/lib/libc.a' asFilename isReadable ifTrue:[

                        SearchedLibraries := #('/lib/libc.a')

                    ]

                ]

            ].

            "/ default libraryPath where shared objects are searched for

            "/ when a dynamic library is loaded without an explicit path.

            LoadLibraryPath := OperatingSystem getEnvironment:'LD_LIBRARY_PATH'.

            LoadLibraryPath isNil ifTrue:[

                LoadLibraryPath := #('.'

                                     'lib'

                                     '/usr/local/smalltalk/lib'

                                     '/usr/local/lib'

                                     '/usr/lib'

                                     '/lib'

                                    ) asOrderedCollection.

            ].

            "/ default libraryPath where shared objects are expected

            "/ when a sharedObject load requires other objects to be loaded.

            "/ Only req'd for aix.

            "/ For more compatibility with ELF systems, look for a shell variable

            "/ named LD_LIBRARY_PATH, and - if present - take that instead if a default.

            "/ Can (should) be set in the smalltalk.rc file.

            systemType = 'aix' ifTrue:[

                LibPath := OperatingSystem getEnvironment:'LD_LIBRARY_PATH'.

                LibPath isNil ifTrue:[

                    LibPath := '.:/usr/local/smalltalk/lib:/usr/local/lib:/usr/lib:/lib'.

                ]

            ].

        ]

    ]

    "

     ObjectFileLoader initialize

    "

!

lastError

    ^ LastError

!

libPath

    "see comment in #libPath:"

    ^ LibPath

!

libPath:aSharedLibraryPath

    "set the pathnames of directories, where other shared objects

     are searched, in case a loaded module requires another module shared

     library object to be loaded.

     Currently, this is only required to be set for AIX systems;

     ELF based linux and solaris systems specify the libPath in the 

     LD_LIBRARY_PATH environment variable."

    LibPath := aSharedLibraryPath

    "

     ObjectFileLoader libPath:'.:/usr/lib:/usr/local/lib'

    "

!

linkErrorMessage

    ^ LinkErrorMessage

!

searchedLibraries

    "see comment in #searchedLibraries:"

    ^ SearchedLibraries

!

searchedLibraries:aCollectionOfArchivePathNames

    "set the pathnames of archives which are to be searched

     when unresolved references occur while loading in an object

     file. On systems which support shared libraries (all SYS5.4 based

     systems), this is usually not required. Instead, modules which are to

     be filed in (.so files) are to be prelinked with the appropriate

     shared libraries. The dynamic loader then cares about loading those

     modules (keeping track of which modules are already loaded).

     Only systems in which the dynamic load is done 'manually' by st/x

     (i.e. currently only linux and a.out-sunos) need to set this."

    SearchedLibraries := aCollectionOfArchivePathNames

!

verbose

    "return true, if debug traces are turned on"

    ^ Verbose

!

verbose:aBoolean

    "turn on/off debug traces"

    Verbose := aBoolean

    "ObjectFileLoader verbose:true"

! !

!ObjectFileLoader class methodsFor:'change & update'!

update:something with:aParameter from:changedObject

    "sent, when image is saved or restarted"

    (something == #aboutToSnapshot) ifTrue:[

	self invalidateAndRememberAllObjectFiles

    ].

    (something == #finishedSnapshot) ifTrue:[

	self revalidateAllObjectFiles

    ].

"/    (something == #restarted) ifTrue:[

"/        self reloadAllRememberedObjectFiles

"/    ].

    "Modified: 5.10.1995 / 15:49:14 / claus"

    "Modified: 8.3.1996 / 23:34:29 / cg"

    "Created: 21.6.1996 / 19:50:01 / cg"

! !

!ObjectFileLoader class methodsFor:'defaults'!

hasValidBinaryExtension:aFilename

    "return true, if aFilename looks ok for binary loading.

     This checks only the extension - not its contents. 

     (So an attempt to load the file may fail due to format errors or unresolved symbols)

     This is very machine specific."

    self validBinaryExtensions do:[:ext |

	(aFilename endsWith:ext) ifTrue:[^ true].

    ].

    ^ false

    "

     ObjectFileLoader hasValidBinaryExtension:'foo.st'

     ObjectFileLoader hasValidBinaryExtension:'foo.o' 

     ObjectFileLoader hasValidBinaryExtension:'foo.so'

     ObjectFileLoader hasValidBinaryExtension:'foo.dll'

     ObjectFileLoader hasValidBinaryExtension:'foo.obj'

     ObjectFileLoader hasValidBinaryExtension:'foo.sl'

    "

    "Modified: 29.4.1997 / 21:55:07 / cg"

!

linkArgs

    ^ LinkArgs ? ''   "/ that default is ok for Unix

    "Created: / 12.8.1998 / 21:41:16 / cg"

    "Modified: / 12.8.1998 / 21:42:50 / cg"

!