Object subclass:#Java

	instanceVariableNames:''

	classVariableNames:'Classes UnresolvedClassRefs ClassPath SourceDirectories

		JavaString'

	poolDictionaries:''

	category:'Java-Support'

!

!Java class methodsFor:'accessing'!

classNamed:aString

    ^ self at:aString

!

classPath

    ^ ClassPath

    "Created: 7.2.1997 / 19:23:45 / cg"

    "Modified: 7.2.1997 / 19:23:55 / cg"

!

classPath:aCollectionOfPaths

    ClassPath := aCollectionOfPaths asOrderedCollection

    "Created: 7.2.1997 / 19:23:45 / cg"

!

javaString

    ^ JavaString

!

sourceDirectories

    ^ SourceDirectories

!

sourceDirectories:aCollectionOfPaths

    SourceDirectories := aCollectionOfPaths asOrderedCollection

    "

     Java

        sourceDirectories:#(

                            '/phys/ibm3/java/src'

                           )

    "

! !

!Java class methodsFor:'class initialization'!

initAllClasses

     self initAllStaticFields.

     self allClassesDo:[:cls |

        cls isInitialized ifFalse:[

            cls classInit

        ]

     ]

!

initAllStaticFields

     self allClassesDo:[:cls |

        cls initializeStaticFields

     ]

!

initialize

    self classPath:#(

                   ).

    self

        sourceDirectories:#(

                           )

     "

      Java initialize

     "

!

reinitAllClasses

     self markAllClassesUninitialized.

     self initAllClasses

! !

!Java class methodsFor:'enumerating'!

allClasses

    ^ Classes

!

allClassesDo:aBlock

    Classes notNil ifTrue:[

        Classes do:aBlock

    ]

! !

!Java class methodsFor:'registering java classes'!

at:aJavaName

    "search & return for a class by name;

     if there is no such class, return nil.

     The argument, aJavaName may be either an internal name

     (sep'd by slashes) or an external name (sep'd by periods).

     The 'java/lang' standard packages prefix may be ommitted."

    |sym nm cls|

    Classes isNil ifTrue:[^ nil].

    sym := aJavaName asSymbolIfInterned.

    sym notNil ifTrue:[

        cls := Classes at:sym ifAbsent:nil.

        cls notNil ifTrue:[^ cls].

    ].

    nm := aJavaName.

    (nm includes:$.) ifTrue:[

        nm := (nm asString copy replaceAll:$. by:$/).

        sym := nm asSymbolIfInterned.

        sym notNil ifTrue:[

            cls := Classes at:sym ifAbsent:nil.

            cls notNil ifTrue:[^ cls].

        ].

    ].

    (nm includes:$/) ifFalse:[

        "/

        "/ try java.lang.Foo

        "/

        nm := 'java/lang/' , nm.

        sym := nm asSymbolIfInterned.

        sym notNil ifTrue:[

            cls := Classes at:sym ifAbsent:nil.

            cls notNil ifTrue:[^ cls].

        ].

    ].

    ^ nil

    "

     Java at:'java/lang/String' 

     Java at:'java.lang.String'

     Java at:'String'          

     Java at:'System'            

     Java at:'Foo'               

    "

!

at:aJavaName put:aJavaClass

    |nameSymbol|

    Classes isNil ifTrue:[

        Classes := IdentityDictionary new.

    ].

    nameSymbol := aJavaName asSymbol.

    (Classes includesKey:nameSymbol) ifTrue:[

        ('JAVA: class ' , aJavaName , ' is already loaded') infoPrintCR.

    ].

    Classes at:nameSymbol put:aJavaClass.

    nameSymbol == #'java/lang/String' ifTrue:[

        JavaString := aJavaClass

    ].

"/    UnresolvedClassRefs notNil ifTrue:[

"/        UnresolvedClassRefs do:[:toResolve |

"/        ]

"/    ].

    self changed:#classes

    "Created: 17.4.1996 / 23:29:31 / cg"

    "Modified: 18.4.1996 / 00:45:39 / cg"

!

flushClasses

    Classes := UnresolvedClassRefs := JavaString := nil.

    JavaInterpreter releaseAllJavaResources.

    JavaUnresolvedConstant flushPatchLists.

    "

     Java flushClasses

    "

    "Modified: 18.4.1996 / 00:20:23 / cg"

!

markAllClassesUninitialized

    self allClassesDo:[:aJavaClass |

        aJavaClass markUninitialized

    ].

    "

     Java markAllClassesUninitialized

    "

!

rememberUnresolved:anUnresolvedClassRef

    ('JAVA: remember unresolved class: ' , anUnresolvedClassRef fullName) infoPrintCR.

    UnresolvedClassRefs isNil ifTrue:[

        UnresolvedClassRefs := Set new.

    ].

    UnresolvedClassRefs add:anUnresolvedClassRef

    "Created: 18.4.1996 / 00:05:31 / cg"

    "Modified: 18.4.1996 / 00:05:41 / cg"

!

unresolvedClassRefFor:aClassName

    UnresolvedClassRefs isNil ifTrue:[^ nil].

    ^ UnresolvedClassRefs at:aClassName ifAbsent:nil.

! !

!Java class methodsFor:'source management'!

classSourceOf:aClass

    |package dirName binary sourceFileName sourceFile dirHolder fileName path|

    aClass isNil ifTrue:[

        ^ nil

    ].

    package := aClass package.

    "/ first, look in the directory, where the binary

    "/ was loaded from.

    binary := aClass binaryFile asFilename.

    sourceFileName := binary withSuffix:'java'.

    sourceFile := sourceFileName asFilename.

    sourceFile exists ifFalse:[

        sourceFileName := binary withSuffix:'jav'.

        sourceFile := sourceFileName asFilename.

        sourceFile exists ifFalse:[

            sourceFileName := binary withSuffix:'JAV'.

            sourceFile := sourceFileName asFilename.

            sourceFile exists ifFalse:[

                sourceFileName := binary withSuffix:'JAVA'.

                sourceFile := sourceFileName asFilename.

            ].

        ].

    ].

    "/ special case: there where multiple classes in a single

    "/ source file.

    binary withoutSuffix baseName ~= aClass sourceFile asFilename withoutSuffix baseName ifTrue:[

        'JAVA: trouble extracting fileName: ' print.

        binary withoutSuffix baseName print. ' vs. ' print.

        aClass sourceFile asFilename withoutSuffix baseName printCR.

    ].

    "/ if that fails, look in standard places

    sourceFile exists ifFalse:[

        sourceFileName := aClass sourceFile.

        sourceFile := sourceFileName asFilename.

        sourceFile exists ifFalse:[

            "/

            "/ mhmh - look for its directory

            "/

            dirName := sourceFile directoryName.

            fileName := sourceFile baseName.

            (dirName asFilename exists 

            and:[(dirName asFilename construct:(package , '/' , fileName)) exists])

            ifFalse:[

                (dirName asFilename exists 

                and:[(dirName asFilename construct:(fileName)) exists])

                ifFalse:[

                    dirName := self findSourceDirOf:fileName inPackage:package.

    "/                [dirName isNil] whileTrue:[

    "/                    dirName := Dialog requestDirectoryName:'top directory for ' , package , '/' , fileName.

    "/                    (dirName isNil or:[dirName isEmpty]) ifTrue:[^ self].

    "/                ].

                ].

            ].

            (dirName notNil and:[dirName asFilename exists]) ifTrue:[

                path := (dirName asFilename construct:(package , '/' , fileName)) asFilename.

                path exists ifFalse:[

                    path := (dirName asFilename construct:(fileName)) asFilename.

                ].

            ].

            (path notNil and:[path exists]) ifFalse:[

                ^ nil

            ].

            sourceFile := path asFilename.

        ].

    ].

    ^ (sourceFile contentsOfEntireFile).

!

findSourceDirOf:fileName inPackage:aPackage

    SourceDirectories notNil ifTrue:[

        SourceDirectories do:[:aDir |

            (aDir asFilename construct:('/' , aPackage , '/' , fileName))

            asFilename exists ifTrue:[

                ^ aDir 

            ].

            (aDir asFilename construct:('/' , fileName))

            asFilename exists ifTrue:[

                ^ aDir 

            ].

        ]

    ].

    ^ nil

! !

!Java class methodsFor:'documentation'!

version

! !

Java initialize!