"

 COPYRIGHT (c) 2003 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libjava/tools' }"

Object subclass:#JavaScannerBase

	instanceVariableNames:'typeArray actionArray source lineNr tokenType tokenStartPosition

		tokenEndPosition tokenLineNr numberRadix numberScale hereChar

		peekChar peekChar2 requestor saveComments tokenValue

		scaledMantissaValue parserFlags comments'

	classVariableNames:'Warnings'

	poolDictionaries:''

	category:'Languages-Java-Parser'

!

JavaScannerBase class instanceVariableNames:'TypeArray ActionArray KeywordTable'

"

 No other class instance variables are inherited by this class.

"

!

!JavaScannerBase class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2003 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

! !

!JavaScannerBase class methodsFor:'initialization'!

initialize

    "initialize the classes defaults. Typically, these are changed

     later in the 'private.rc' file."

"/    ScannerError isLoaded ifFalse:[

"/        ScannerError autoload

"/    ].

"/    EmptySourceNotification notifierString:'empty source given to evaluate'.

    Warnings := false.

    "ActionArray := nil.

     TypeArray := nil.

     self initialize

    "

    "Modified: / 15-03-2012 / 00:05:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

setupActions

    "initialize the scanners tables - these are used to dispatch

     into scanner methods as characters are read"

    self subclassResponsibility

"/    |block|

"/

"/    ActionArray := Array new:256.

"/    TypeArray := Array new:256.

"/

"/    block := [:s :char | s nextNumber].

"/    ($0 asciiValue) to:($9 asciiValue) do:[:index |

"/        ActionArray at:index put:block

"/    ].

"/

"/    block := [:s :char | s nextIdentifier].

"/    ($a asciiValue) to:($z asciiValue) do:[:index |

"/        ActionArray at:index put:block

"/    ].

"/    ($A asciiValue) to:($Z asciiValue) do:[:index |

"/        ActionArray at:index put:block

"/    ].

"/    ActionArray at:$_ asciiValue put:block

"/

! !

!JavaScannerBase class methodsFor:'instance creation'!

for:aStringOrStream

    "create & return a new scanner reading from aStringOrStream"

    ^ (super new) initializeFor:aStringOrStream

    "Modified: 23.5.1997 / 12:08:42 / cg"

!

new

    "create & return a new scanner"

    ^ self basicNew initialize.

    "Modified: / 23.5.1997 / 12:08:42 / cg"

    "Created: / 26.5.1999 / 12:02:16 / stefan"

! !

!JavaScannerBase class methodsFor:'Signal constants'!

emptySourceNotificationSignal

    ^ EmptySourceNotification

    "Created: / 16.5.1998 / 15:55:14 / cg"

!

errorSignal

    ^ ScannerError

    "Created: / 16.5.1998 / 15:55:14 / cg"

!

scannerErrorSignal

    ^ ScannerError

    "Created: / 16.5.1998 / 15:55:14 / cg"

!

warningSignal

    ^ ScannerWarning

    "Created: / 16.5.1998 / 15:55:14 / cg"

! !

!JavaScannerBase class methodsFor:'defaults'!

warnings

    "return true, if any warnings are to be shown"

    ^ Warnings

!

warnings:aBoolean

    "this allows turning on/off all warnings; the default is on.

     You can turn off warnings in your 'private.rc' file with

	 Compiler warnings:false

    "

    Warnings := aBoolean

    "Modified: 23.5.1997 / 12:03:05 / cg"

! !

!JavaScannerBase class methodsFor:'private accessing'!

actionArray

    ^ ActionArray

!

keywordTable

    ^ KeywordTable

!

typeArray

    ^ TypeArray

! !

!JavaScannerBase class methodsFor:'utility scanning'!

scanNumberFrom:aStream

    "utility - helper for Number>>readSmalltalkSyntaxFrom:"

    ^ self basicNew scanNumberFrom:aStream

    "

     |s|

     s := '12345abcd' readStream.

     Transcript showCR:(self scanNumberFrom:s).

     Transcript showCR:(s upToEnd).

    "

    "

     |s|

     s := '16rffffxabcd' readStream.

     Transcript showCR:(self scanNumberFrom:s).

     Transcript showCR:(s upToEnd).

    "

    "

     |s|

     s := '1.2345abcd' readStream.

     Transcript showCR:(self scanNumberFrom:s).

     Transcript showCR:(s upToEnd).

    "

    "

     |s|

     s := '1.abcd' readStream.

     Transcript showCR:(self scanNumberFrom:s).

     Transcript showCR:(s upToEnd).

    "

    "Modified: / 18.6.1998 / 23:10:39 / cg"

! !

!JavaScannerBase methodsFor:'Compatibility - ST80'!

endOfLastToken

    "return the position of the token which was just read.

     This method was required by some PD program.

     It is not maintained and may be removed without notice."

    ^ source position

    "Modified: 23.5.1997 / 12:14:27 / cg"

!

scan:aStringOrStream

    "initialize the scanner: set the source-stream and

     preread the first token"

    self initializeFor:aStringOrStream.

    self nextToken

    "Created: / 30.10.1997 / 16:59:39 / cg"

!

scanToken

    "read the next token from my input stream"

    ^ self nextToken

    "Created: / 30.10.1997 / 17:00:16 / cg"

!

scanTokens:aStringOrStream

    "return a collection of symbolic tokens from the passed input"

    |tokens|

    self initializeFor:aStringOrStream.

    tokens := OrderedCollection new.

    self nextToken.

    [tokenValue notNil] whileTrue:[

	tokens add:tokenValue.

	self nextToken

    ].

    ^ tokens

    "

     Scanner new

	scanTokens:'Boolean subclass:#True

				instanceVariableNames:''''

				classVariableNames:''''

				poolDictionaries:''''

				category:''Kernel-Objects''

	'

    "

    "Modified: 20.6.1997 / 18:22:58 / cg"

! !

!JavaScannerBase methodsFor:'accessing'!

actionArray

    ^ actionArray

!

actionArray:something

    actionArray := something.

!

comments

    "if saveComments is on:

      returns the collection of collected comments (so far)

      clears the internal collection for the next access"

    |ret|

    ret := comments ? #().

    comments := nil.

    ^ ret

    "Created: 20.4.1996 / 20:07:01 / cg"

    "Modified: 23.5.1997 / 12:14:45 / cg"

!

lineNumber

    "the current line number (in the stream)"

    ^ lineNr

!

newSourceStream:aStream

    source := aStream.

    self nextToken.

    "Created: / 29.10.1998 / 21:59:33 / cg"

!

numberRadix

    "the radix of the previously scanned number"

    ^ numberRadix

!

parserFlags:something

    parserFlags := something.

!

saveComments:aBoolean

    "toggle to turn on/off comment remembering"

    saveComments := aBoolean

    "Created: 20.4.1996 / 20:03:56 / cg"

    "Modified: 23.5.1997 / 12:14:49 / cg"

!

sourceStream

    ^ source

    "Created: 20.4.1996 / 19:59:58 / cg"

!

token

    "the previously scanned token"

    "/ generated lazily ...

    self halt.

!

tokenEndPosition

    "the previously scanned tokens last character position"

    ^ tokenEndPosition

!

tokenLineNumber

    "the previously scanned tokens line number"

    ^ tokenLineNr

!

tokenStartPosition

    "the previously scanned tokens first character position"

    ^ tokenStartPosition

!

tokenType

    "the type (symbolic) of the previously scanned token"

    ^ tokenType

!

tokenValue

    "the value (string or number) of the previously scanned token"

    ^ tokenValue

!

typeArray

    ^ typeArray

!

typeArray:something

    typeArray := something.

! !

!JavaScannerBase methodsFor:'error handling'!

correctableError:message position:pos1 to:pos2

    "report an error which can be corrected by compiler -

     return non-false, if correction is wanted (there is more than

     true/false returned here)"

    |correctIt|

    requestor isNil ifTrue:[

"/        self showErrorMessage:message position:pos1.

	correctIt := false

    ] ifFalse:[

	correctIt := requestor correctableError:message position:pos1 to:pos2 from:self

    ].

    ^ correctIt

    "Created: / 13.5.1998 / 16:45:56 / cg"

!

errorMessagePrefix

    ^ 'Error:'

!

ignoreWarnings

    ^ Warnings == false

    "Modified: / 14-03-2012 / 22:36:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

lastTokenLineNumber

    "return the line number of the token which was just read."

    ^ tokenLineNr

    "Created: 8.11.1996 / 18:46:36 / cg"

    "Modified: 23.5.1997 / 12:16:12 / cg"

!

notifyError:aMessage position:position to:endPos

    "notify requestor of an error - if there is no requestor

     put it on the transcript. Requestor is typically the CodeView

     in which the accept/doIt was triggered, or the PositionableStream

     which does the fileIn. The requestor may decide how to highlight the

     error (and/or to abort the compile).

     Return the result passed back by the requestor."

    requestor isNil ifTrue:[

	self showErrorMessage:aMessage position:position.

	^ false

    ].

    ^ requestor error:aMessage position:position to:endPos from:self

!

notifyWarning:aMessage position:position to:endPos

    "notify requestor of an warning - if there is no requestor

     put it on the transcript.

     Return the result passed back by the requestor."

    |warn|

    self ignoreWarnings ifFalse:[

	requestor isNil ifTrue:[

	    warn := ScannerWarning new.

	    warn startPosition:position.

	    warn endPosition:endPos.

	    warn lineNumber:tokenLineNr.

	    warn errorString:((self warningMessagePrefix) , ' ' , aMessage).

	    warn raiseRequest.

	    ^ false

	].

	^ requestor warning:aMessage position:position to:endPos from:self

    ].

    ^ false

!

parseError:aMessage

    "report an error"

    ^ self parseError:aMessage position:tokenStartPosition to:nil

    "Created: / 13.5.1998 / 16:45:13 / cg"

!

parseError:aMessage position:position

    "report an error"

    ^ self parseError:aMessage position:position to:nil

    "Created: / 13.5.1998 / 16:45:05 / cg"

!

parseError:aMessage position:position to:endPos

    "report an error"

    |m|

    m := (self errorMessagePrefix) , ' ' , (aMessage ? '???').

    self notifyError:m position:position to:endPos.

    ^ false

    "Created: / 13.5.1998 / 16:44:55 / cg"

    "Modified: / 28.9.1998 / 19:29:27 / cg"

!

showErrorMessage:aMessage position:pos

    "show an errormessage on the Transcript"

    Transcript showCR:(pos printString , ' [line: ' , tokenLineNr printString , '] ' , aMessage)

!

syntaxError:aMessage

    "a syntax error happened - position is not known"

    ^ self syntaxError:aMessage position:tokenStartPosition

!

syntaxError:aMessage position:position

    "a syntax error happened - only start position is known"

    ^ self syntaxError:aMessage position:position to:nil

!

syntaxError:aMessage position:position to:endPos

    "a syntax error happened"

    |err|

    err := ParseError new.

    err errorMessage:((self errorMessagePrefix) , ' ' , aMessage)

        startPosition:tokenStartPosition

        endPosition:tokenEndPosition.

    err lineNumber:tokenLineNr.

    err raiseRequest

    "Modified: / 21-10-2013 / 09:51:14 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

warning:aMessage

    "a warning - position is not known"

    ^ self warning:aMessage position:tokenStartPosition