"{ Package: 'stx:libjava' }"

TestCase subclass:#JavaTestCaseProxy

	instanceVariableNames:''

	classVariableNames:'TestCases'

	poolDictionaries:''

	category:'Languages-Java-Tests-Proxies'

!

JavaTestCaseProxy class instanceVariableNames:'javaClassName shouldFork'

"

 The following class instance variables are inherited by this class:

	TestCase - lastTestRunResultOrNil lastTestRunsPassedTests lastTestRunsFailedTests lastTestRunsErrorTests

	TestAsserter - 

	Object - 

"

!

!JavaTestCaseProxy class methodsFor:'initialization'!

setJavaClassName: aSymbol

    javaClassName ifNotNil:

        [self error: 'Attempting to set java class name twice'].

    javaClassName := aSymbol.

    "Created: / 01-03-2011 / 10:43:05 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaTestCaseProxy class methodsFor:'accessing'!

javaClass

    ^Java classForName: javaClassName

    "Created: / 01-03-2011 / 11:30:29 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 21-06-2011 / 17:09:23 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

javaClassName

    ^javaClassName

    "Created: / 01-03-2011 / 11:30:56 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

shouldFork

    ^ shouldFork ? false

    "Modified: / 13-06-2011 / 16:34:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

shouldFork:aBoolean

    shouldFork := aBoolean.

! !

!JavaTestCaseProxy class methodsFor:'private'!

testSelectors

    "raise an error: must be redefined in concrete subclass(es)"

    ^ self subclassResponsibility

! !

!JavaTestCaseProxy class methodsFor:'queries'!

isAbstract

    ^self == JavaTestCaseProxy or:[self superclass == JavaTestCaseProxy]

    "Created: / 21-06-2011 / 16:56:52 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

isTestlet

    ^false

    "Created: / 21-06-2011 / 16:57:44 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaTestCaseProxy class methodsFor:'subclass creation'!

for: javaClass 

    self subclassResponsibility

    "Modified: / 21-06-2011 / 17:08:08 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

forClassNamed: name 

    "Answers a new (anonymous) testcase proxy for

     given javaClass"

    | meta  cls   |

    TestCases at: name ifPresent: [:c | ^ c ].

    meta := Metaclass new.

    meta setSuperclass: self class.

    meta instSize: self class instSize.

    cls := meta new.

    cls setSuperclass: self.

    cls flags: self flags.

    cls instSize: self instSize.

    cls setJavaClassName: name.

    cls 

        setName: (self name , ' for: (Java classForName: ' , name storeString 

                , ')') asSymbol.

    cls setCategory: #'(java test case proxies)'.

    TestCases at: name put: cls.

    ^ cls

    "Modified: / 03-03-2011 / 00:20:49 / Marcel Hlopko <hlopik@gmail.com>"

    "Modified: / 29-04-2011 / 10:21:39 / Marcel Hlopko <hlopkmar@fel.cvut.cz>"

    "Created: / 21-06-2011 / 17:07:28 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaTestCaseProxy methodsFor:'accessing'!

javaClass

    | javaClass |

    self 

        assert: (javaClass := self class javaClass) isJavaClass

        description: 'java class does not exists'.

    ^javaClass

    "Created: / 01-03-2011 / 14:48:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaTestCaseProxy class methodsFor:'documentation'!

version_SVN

    ^ '$Id$'

! !