"

 COPYRIGHT (c) 1996-2011 by Claus Gittinger

 New code and modifications done at SWING Research Group [1]:

 COPYRIGHT (c) 2010-2011 by Jan Vrany, Jan Kurs and Marcel Hlopko

                            SWING Research Group, Czech Technical University in Prague

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

 [1] Code written at SWING Research Group contains a signature

     of one of the above copright owners. For exact set of such code,

     see the differences between this version and version stx:libjava

     as of 1.9.2010

"

"{ Package: 'stx:libjava' }"

Object subclass:#JavaFinalizationRegistry

	instanceVariableNames:'activeReferees finalizationSemaphore finalizationProcess'

	classVariableNames:''

	poolDictionaries:''

	category:'Languages-Java-Support'

!

!JavaFinalizationRegistry class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1996-2011 by Claus Gittinger

 New code and modifications done at SWING Research Group [1]:

 COPYRIGHT (c) 2010-2011 by Jan Vrany, Jan Kurs and Marcel Hlopko

                            SWING Research Group, Czech Technical University in Prague

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

 [1] Code written at SWING Research Group contains a signature

     of one of the above copright owners. For exact set of such code,

     see the differences between this version and version stx:libjava

     as of 1.9.2010

"

!

documentation

"

    A tricky class that implements Java-style finalization.

    Future versions may involve some C / VM optimization,

    if this algorithm prooves usefull

    [author:]

        Jan Vrany <jan.vrany@fit.cvut.cz>

    [instance variables:]

    [class variables:]

    [see also:]

"

! !

!JavaFinalizationRegistry class methodsFor:'instance creation'!

new

    "return an initialized instance"

    ^ self basicNew initialize.

! !

!JavaFinalizationRegistry methodsFor:'finalization'!

finalizationCycle

    | referees references living wasBlocked firstPendingReference lastPendingReference ref |

    referees := (activeReferees select:[:e|e notNil]) asArray.

    references := Array new: referees size.

    living := Array new: referees size.

    firstPendingReference := nil.

    ObjectMemory allObjectsIncludingContextsDo:[:o|

        | index |

        (o ~~ referees and:[o ~~ activeReferees]) ifTrue:[

            (index := self references: o anyOf: referees) ~~ 0 ifTrue:[

                o class name == #'java/lang/ref/Finalizer' ifTrue:[

                    self assert: (self getNextOf: o) isNil.

                    references at: index put: o                

                ] ifFalse:[

                    living at: index put: o.

                ]

            ].

        ].

    ].

    wasBlocked := OperatingSystem blockInterrupts.

    living withIndexDo:[:each :index|

        each isNil ifTrue:[

            ref := references at: index.    

            activeReferees at: (activeReferees identityIndexOf: (referees at: index)) put: nil.

            firstPendingReference isNil ifTrue:[

                firstPendingReference := lastPendingReference := ref

            ] ifFalse:[

                self setNextOf: lastPendingReference to: ref.

                lastPendingReference := ref.

            ].

            self setNextOf: lastPendingReference to: lastPendingReference

        ].

    ].

    wasBlocked ifFalse:[ OperatingSystem unblockInterrupts].

    self informReferenceHandler: firstPendingReference

    "Created: / 24-07-2012 / 15:14:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

finalizationLoop

    [ 

        finalizationSemaphore waitWithTimeoutMs: 10000"10sec".

        self finalizationCycle    

    ] loop

    "Created: / 24-07-2012 / 15:16:51 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaFinalizationRegistry methodsFor:'initialization'!

initialize

    "Invoked when a new instance is created."

    "/ please change as required (and remove this comment)

    activeReferees := Array new: 200.

    "/ super initialize.   -- commented since inherited method does nothing

    "Modified: / 24-07-2012 / 15:23:18 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaFinalizationRegistry methodsFor:'private'!

firstFreeIndex

    activeReferees withIndexDo:[:value :index|

        value isNil ifTrue:[

            ^index

        ].

    ].

    self grow.

    "Created: / 24-07-2012 / 01:19:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

getNextOf: reference

    ^reference instVarAt: 3

    "Created: / 24-07-2012 / 11:22:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

grow

    "Created: / 24-07-2012 / 01:20:09 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

informReferenceHandler: reference

    | referenceClass lock |

    reference isNil ifTrue:[ ^ self ].

    referenceClass := Java classForName: 'java.lang.ref.Reference'.

    lock := JavaVM monitorFor: (referenceClass instVarNamed: #lock).

    lock enter.

    [

        referenceClass instVarNamed: #pending put: reference.

        lock notify.

    ] ensure:[

        lock exit.

    ].

    "Created: / 24-07-2012 / 03:42:37 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

references: object anyOf: aCollection

    "If object references any object in a collection, return

     index of value which it references, zero otherwise"

%{

    OBJ cls, flags;

    int nInsts, inst;

    if (! __isNonNilObject(object)) {

        RETURN (__MKINT(0));

    }

    if (__isArrayLike(aCollection)) {

        int nObjs = __arraySize(aCollection);

        char *minAddr = 0, *maxAddr = 0;

        if (nObjs == 0) {

            RETURN (__MKINT(0));

        }

        /*

         * a little optimization: use the fact that all old objects

         * refering to a new object are on the remSet; if I am not,

         * a trivial reject is possible, if all objects are newbees.

         * as a side effect, gather min/max addresses

         */

        if ((__qSpace(object) <= OLDSPACE) && !__isRemembered(object)) {

            int allNewBees = 1;

            int i;

            minAddr = (char *)(__ArrayInstPtr(aCollection)->a_element[0]);

            maxAddr = minAddr;

            for (i=0; i<nObjs; i++) {

                OBJ anObject;

                anObject = __ArrayInstPtr(aCollection)->a_element[i];

                if (__isNonNilObject(anObject)) {

                    int spc;

                    if (((spc = __qSpace(anObject)) != NEWSPACE) && (spc != SURVSPACE)) {

                        allNewBees = 0;

                    }

                }

                if ((char *)anObject < minAddr) {

                    minAddr = (char *)anObject;

                } else if ((char *)anObject > maxAddr) {

                    maxAddr = (char *)anObject;

                }

            }

            if (allNewBees) {

                RETURN (__MKINT(0));

            }

        }

        /*

         * fetch min/max in searchList (if not already done)

         */

        if (minAddr == 0) {

            int i;

            for (i=0; i<nObjs; i++) {

                OBJ anObject;

                anObject = __ArrayInstPtr(aCollection)->a_element[i];

                if ((char *)anObject < minAddr) {

                    minAddr = (char *)anObject;

                } else if ((char *)anObject > maxAddr) {

                    maxAddr = (char *)anObject;

                }

            }

        }

        cls = __qClass(object);

        flags = __ClassInstPtr(cls)->c_flags;

        if (((INT)flags & __MASKSMALLINT(ARRAYMASK)) == __MASKSMALLINT(POINTERARRAY)) {

            nInsts = __BYTES2OBJS__(__qSize(object) - OHDR_SIZE);

        } else {

            nInsts = __intVal(__ClassInstPtr(cls)->c_ninstvars);

        }

        if (! nInsts) {

            RETURN (__MKINT(0));

        }

        if (nObjs == 1) {

            /* better reverse the loop */

            OBJ anObject;

            anObject = __ArrayInstPtr(aCollection)->a_element[0];

#if defined(memsrch4)

            if (memsrch4(__InstPtr(object)->i_instvars, (INT)anObject, nInsts)) {

                RETURN (__MKINT(1));

            }

#else

            for (inst=0; inst<nInsts; inst++) {

                if ((__InstPtr(object)->i_instvars[inst]) == anObject) {

                    RETURN (__MKINT(1));

                }

            }

#endif

            RETURN (false);

        }

        for (inst=0; inst<nInsts; inst++) {

            OBJ instVar = __InstPtr(object)->i_instvars[inst];

            int i;

            if (((char *)instVar >= minAddr) && ((char *)instVar <= maxAddr)) {

                for (i=0; i<nObjs; i++) {

                    OBJ anObject;

                    anObject = __ArrayInstPtr(aCollection)->a_element[i];

                    if (instVar == anObject) {

                        RETURN (__MKINT(i+1));

                    }

                }

            }

        }

        RETURN (__MKINT(0));

    }

%}.

    aCollection withIndexDo:[:each :eachi|

        (object references: each) ifTrue:[^eachi].

    ].

    ^0

    "Created: / 24-07-2012 / 01:49:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

setNextOf: reference to: value

    ^reference instVarAt: 3 put: value

    "Created: / 24-07-2012 / 11:22:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaFinalizationRegistry methodsFor:'registering objects'!

register: object

    "Register an object for being finalized"

    | index finalizedClass |

    index := self firstFreeIndex.

    activeReferees at: index put: object.

    finalizedClass := Java classForName:'java.lang.ref.Finalizer'.

    finalizedClass classInit.

    (finalizedClass methodDictionary at: #'register(Ljava/lang/Object;)V')

        valueWithReceiver: finalizedClass arguments: (Array with: object)

    "Created: / 24-07-2012 / 01:14:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

registerChange: anObject

    "/Nothing to do, to be polymprph with Registry"

    "Created: / 24-07-2012 / 03:31:18 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaFinalizationRegistry methodsFor:'start & stop'!

startFinalizationProcessAt:aPriority

    |p|

    finalizationProcess notNil ifTrue:[

        finalizationProcess priority:aPriority.

        ^ self

    ].

    finalizationSemaphore := Semaphore new name:'FinalizationSemaphore (Java)'.

    p :=

        [

            [

                self finalizationLoop

            ] ifCurtailed:[

                finalizationProcess := nil.

                finalizationSemaphore := nil

            ]

        ] newProcess.

    p name:'background finalizer (Java)'.

    p priority:aPriority.

    p restartable:true.

    p beSystemProcess.

    p resume.

    finalizationProcess := p

    "Created: / 24-07-2012 / 15:25:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

stopFinalizationProcess

    "stop the background finalizer"

    finalizationProcess notNil ifTrue:[

        finalizationProcess terminate.

        finalizationProcess := nil

    ].

    "Created: / 24-07-2012 / 15:26:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaFinalizationRegistry methodsFor:'utilities'!

finalizeNow

    "Force finalization to run now"

    finalizationSemaphore signal

    "Created: / 24-07-2012 / 15:28:45 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaFinalizationRegistry class methodsFor:'documentation'!

version_SVN

    ^ '$Id::                                                                                                                        $'

! !