"{ Package: 'stx:libjava' }"

Object subclass:#JavaDescriptor

	instanceVariableNames:''

	classVariableNames:'BaseTypes BaseTypesByTypeName ArrayTypes'

	poolDictionaries:''

	category:'Languages-Java-Support'

!

!JavaDescriptor class methodsFor:'instance creation'!

fromString: aString

    ^self readFromString: aString

    "Created: / 25-11-2010 / 18:20:41 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

readFrom: aStream

    ^ self

        readFrom:aStream

        onError:[ self conversionErrorSignal

                    raiseErrorString:'invalid java descriptor']

    "Created: / 25-11-2010 / 18:04:32 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

readFrom:stream onError:exceptionBlock

    stream peek == $(

        ifTrue: [^self readMethodDescriptorFrom: stream onError: exceptionBlock]

        ifFalse:[^self readFieldDescriptorFrom:  stream onError: exceptionBlock].

    "

        JavaDescriptor fromString:'Ljava/lang/Object;'

        JavaDescriptor fromString:'[I'

        JavaDescriptor fromString:'[[I'

        JavaDescriptor fromString:'(ILjava/lang/Object;)V'

        JavaDescriptor fromString:'(ILjava/lang/Object;)Ljava/lang/Class;'    

    "

    "Created: / 25-11-2010 / 17:50:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 06-02-2011 / 15:08:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaDescriptor class methodsFor:'accessing'!

baseTypes

    ^BaseTypes

    "Created: / 22-05-2011 / 17:45:18 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

baseTypesByTypeName

    ^BaseTypesByTypeName

    "Created: / 03-02-2011 / 21:08:03 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaDescriptor class methodsFor:'class initialization'!

initialize

    "

    Tools::NewSystemBrowser browseClasses: BaseTypes values label:'Java primitive types'        

    "

    BaseTypes := IdentityDictionary new

        at: $B  put: Byte;

        at: $C  put: Character;

        at: $D  put: Float;

        at: $F  put: ShortFloat;

        at: $I  put: Integer;       "Kludge: instances of java int are in fact SmallIntegers"

        at: $J  put: LargeInteger;

        at: $S  put: Short;

        at: $Z  put: Boolean;

        at: $V  put: UndefinedObject;

        yourself.

    BaseTypesByTypeName := Dictionary new

        at: 'byte'      put: Byte;

        at: 'char'      put: Character;

        at: 'double'    put: Float;

        at: 'float'     put: ShortFloat;

        at: 'int'       put: Integer;       "Kludge: instances of java int are in fact SmallIntegers"

        at: 'long'      put: LargeInteger;

        at: 'short'     put: Short;

        at: 'boolean'   put: Boolean;

        at: 'void'      put: UndefinedObject;

        yourself.

    "

    Tools::NewSystemBrowser browseClasses: ArrayTypes values label:'Java primitive array types'        

    "

    ArrayTypes := IdentityDictionary new

        at: $B  put: ByteArray;

        at: $C  put: Unicode32String;

        at: $D  put: DoubleArray;

        at: $F  put: FloatArray;

        at: $I  put: SignedIntegerArray;    

        at: $J  put: SignedLongIntegerArray;

        at: $S  put: WordArray;

        at: $Z  put: BooleanArray;

        yourself

    "Created: / 25-11-2010 / 17:51:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 25-06-2011 / 08:35:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaDescriptor class methodsFor:'reading-private'!

readArrayTypeFrom:  stream onError: exceptionBlock

    | p c |

    stream next. "eat $["

    p := stream peek.

    (#(

         $B "byte"

         $C "char"

         $D "double"

         $F "float"

         $I "int"

         $J "long"

         $S "short"

         $Z "boolean"

    ) includes: p) ifTrue:[^JavaFieldDescriptor javaClass: (ArrayTypes at: stream next)].

    "OK, not a primitive array..."

    c := self readFrom: stream onError: exceptionBlock.

    ^JavaFieldDescriptor javaClass: (JavaVM javaArrayClassFor: c javaClass)

    "Created: / 25-11-2010 / 18:12:29 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 06-02-2011 / 23:15:09 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

readBaseTypeFrom:  stream onError: exceptionBlock

    ^JavaFieldDescriptor javaClass: (BaseTypes at: (stream next) ifAbsent: exceptionBlock)

    "Created: / 25-11-2010 / 18:11:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

readFieldDescriptorFrom:  stream onError: exceptionBlock

    | p |

    p := stream peek.

    p == $L ifTrue:[^self readObjectTypeFrom: stream onError: exceptionBlock].

    p == $[ ifTrue:[^self readArrayTypeFrom: stream onError: exceptionBlock].

    (#(

         $B "byte"

         $C "char"

         $D "double"

         $F "float"

         $I "int"

         $J "long"

         $S "short"

         $Z "boolean"

         $V "void"

    ) includes: p) ifTrue:[^self readBaseTypeFrom: stream onError: exceptionBlock].

    exceptionBlock value

    "Created: / 25-11-2010 / 17:55:22 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 21-12-2010 / 22:47:31 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

readMethodDescriptorFrom: stream onError: exceptionBlock

    | parameterDescriptors returnDescriptor |

    stream next. "eat $("

    parameterDescriptors := OrderedCollection new.

    [ stream peek ~= $) ] whileTrue:[

        parameterDescriptors add:( self readFieldDescriptorFrom: stream onError: exceptionBlock).

    ].

    stream next. "eat $)"

    stream peek == $V ifFalse:[

        returnDescriptor := self readFieldDescriptorFrom: stream onError: exceptionBlock.

    ] ifTrue:[

        stream next. "eat $V"

    ].

    ^JavaMethodDescriptor parameters: parameterDescriptors return: returnDescriptor

    "

        JavaDescriptor fromString:'(ILjava/lang/Object;)V'

        JavaDescriptor fromString:'(ILjava/lang/Object;)Ljava/lang/Class;'  

    "

    "Created: / 25-11-2010 / 18:36:07 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 21-12-2010 / 22:50:15 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

readObjectTypeFrom:  stream onError: exceptionBlock

    | clsName |

    stream next. "/eat $L.

    clsName := stream upTo: $;.

    "Just a check"

    stream skip: -1.

    stream next ~= $; ifTrue:[exceptionBlock value].

    ^JavaFieldDescriptor javaClassName: clsName.

    "Created: / 25-11-2010 / 18:08:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaDescriptor class methodsFor:'documentation'!

version_SVN

    ^ '$Id$'

! !

JavaDescriptor initialize!