"

 COPYRIGHT (c) 1996-2011 by Claus Gittinger

 New code and modifications done at SWING Research Group [1]:

 COPYRIGHT (c) 2010-2011 by Jan Vrany, Jan Kurs and Marcel Hlopko

                            SWING Research Group, Czech Technical University in Prague

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

 [1] Code written at SWING Research Group contains a signature

     of one of the above copright owners. For exact set of such code,

     see the differences between this version and version stx:libjava

     as of 1.9.2010

"

"{ Package: 'stx:libjava' }"

Object subclass:#JavaNativeMethodImpl_OpenJDK6

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:'JavaVMData'

	category:'Languages-Java-Support-OpenJDK6'

!

!JavaNativeMethodImpl_OpenJDK6 class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1996-2011 by Claus Gittinger

 New code and modifications done at SWING Research Group [1]:

 COPYRIGHT (c) 2010-2011 by Jan Vrany, Jan Kurs and Marcel Hlopko

                            SWING Research Group, Czech Technical University in Prague

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

 [1] Code written at SWING Research Group contains a signature

     of one of the above copright owners. For exact set of such code,

     see the differences between this version and version stx:libjava

     as of 1.9.2010

"

!

documentation

"

    This class implements all native methods of Open JDK 6.

    [author:]

        Jan Vrany <jan.vrany@fit.cvut.cz>

    [instance variables:]

    [class variables:]

    [see also:]

        JavaVM

        JavaVMData

"

! !

!JavaNativeMethodImpl_OpenJDK6 class methodsFor:'helpers - awt'!

commonReshapeComponent:nativeContext

    |view x y width height ext menu|

    view := self viewForWPeer:nativeContext.

    x := nativeContext argAt:1.

    y := nativeContext argAt:2.

    width := nativeContext argAt:3.

    height := nativeContext argAt:4.

    ext := width@height.

"/    'pReshape ' print. view print.

"/    ' ' print. x print. '/' print. y print.

"/    ' extent: ' print. ext printNL.

    view isPopUpView ifTrue:[

	view origin:x@y extent:ext.

    ] ifFalse:[

	(view isTopView

	or:[view isMemberOf:JavaEmbeddedFrameView]) ifTrue:[

	    "/

	    "/ dont allow setting the origin

	    "/

	    menu := self topViewsMenu:view.

	    menu notNil ifTrue:[

		"/ must add the menus height

		height := height + menu height.

		ext := width@height.

	    ].

	    "/ to prevent a view from not being visible/closable

	    "/ in case Java goes mad ..

	    (width < 30

	    or:[height < 10]) ifTrue:[

		"/ self halt.

		width := 30.

		height := 20.

		ext := width@height.

	    ].

	    view extent:ext.

	    (view isKindOf:ModalBox) ifTrue:[

		view preferredExtent:ext

	    ].

	    "/ adjust non-resizable views min/max

	    view isTopView ifTrue:[

		view minExtent notNil ifTrue:[

		    view minExtent:ext.

		    view maxExtent:ext

		].

	    ]

	] ifFalse:[

	    (view superView notNil

	    and:[view superView isTopView]) ifTrue:[

		menu := self topViewsMenu:view superView.

		menu notNil ifTrue:[

		    "/ must add menus height to yPos

		    y := y + menu height.

		]

	    ] ifFalse:[

		"/ post a configuration event

		EventTrace == true ifTrue:[

		    'JAVA: configure: need event' printCR.

		]

	    ].

	    (x isNil or:[y isNil]) ifTrue:[

		Transcript showCR:'bad args to reshape'.

	    ] ifFalse:[

		view origin:x@y extent:ext.

	    ]

	].

    ].

    view isJavaView ifTrue:[

	view invalidate.

    ].

    ^ nil

    "Created: / 4.1.1998 / 18:00:52 / cg"

    "Modified: / 5.12.1998 / 13:34:20 / cg"

!

createdWindowsView:aView for:aJavaPeer

    "this is only sent with the sun.awt.windows toolkit"

    aJavaPeer instVarNamed:'pData' put:aView.

    JavaWindowGroup isNil ifTrue:[

	JavaWindowGroup := WindowGroup new.

	JavaWindowGroup isForModalSubview:true.

    ].

    aView windowGroup:JavaWindowGroup.

    JavaWindowGroup addView:aView.

    KnownWindows isNil ifTrue:[

	KnownWindows := IdentityDictionary new.

    ].

    KnownWindows at:aJavaPeer put:aView.

    FirstWindowCreationSemaphore signalIf.

"/'*** ' print. aJavaPeer print. ' -> ' print. aView printCR.

"/(aView isKindOf:ModalBox) ifTrue:[

"/    self halt.

"/].

    "Created: / 4.1.1998 / 17:57:16 / cg"

    "Modified: / 28.1.1998 / 22:40:19 / cg"

!

gcForWGraphics:nativeContext

    |jGraphics gc orgX orgY trans tX tY|

    jGraphics := nativeContext receiver.

    O_WGgraphics_pData isNil ifTrue:[

	O_WGgraphics_pData := (jGraphics class instVarOffsetOf:'pData').

    ].

    O_WGgraphics_originX isNil ifTrue:[

	O_WGgraphics_originX := (jGraphics class instVarOffsetOf:'originX').

    ].

    O_WGgraphics_originY isNil ifTrue:[

	O_WGgraphics_originY := (jGraphics class instVarOffsetOf:'originY').

    ].

    gc := jGraphics instVarAt:O_WGgraphics_pData.

    trans := gc translation.

    tX := trans x.

    tY := trans y.

"/    tX := gc translationX.

"/    tY := gc translationY.

    orgX := jGraphics instVarAt:O_WGgraphics_originX.

    orgY := jGraphics instVarAt:O_WGgraphics_originY.

    ((orgX ~~ tX) or:[orgY ~~ tY]) ifTrue:[

	gc translation:orgX@orgY

    ].

    ^ gc

    "Created: / 8.1.1998 / 00:16:38 / cg"

    "Modified: / 23.12.1998 / 20:27:35 / cg"

!

jPeerForView:aView

    ^ KnownWindows keyAtValue:aView ifAbsent:nil

    "Created: / 15.1.1998 / 13:48:01 / cg"

    "Modified: / 15.1.1998 / 13:48:43 / cg"

!

pReshape:nativeContext

    |jFramePeer view x y width height menu|

    jFramePeer := nativeContext receiver.

    view := jFramePeer instVarNamed:'pData'.

    x := nativeContext argAt:1.

    y := nativeContext argAt:2.

    width := nativeContext argAt:3.

    height := nativeContext argAt:4.

"/    'pReshape ' print. view print.

"/    ' ' print. x print. '/' print. y print.

"/    ' extent: ' print. width print. '/' print. height printNL.

    view isPopUpView ifTrue:[

	self halt.

    ].

    (view isTopView

    or:[view isMemberOf:JavaEmbeddedFrameView]) ifTrue:[

	"/

	"/ dont allow setting the origin

	"/

	menu := self topViewsMenu:view.

	menu notNil ifTrue:[

	    "/ must add the menus height

	    height := height + menu height

	].

	view extent:width@height.

    ] ifFalse:[

	(view superView notNil

	and:[view superView isTopView]) ifTrue:[

	    menu := self topViewsMenu:view superView.

	    menu notNil ifTrue:[

		"/ must add menus height to yPos

		y := y + menu height.

	    ]

	].

	view origin:x@y extent:width@height.

    ].

    ^ nil

    "Created: / 7.1.1998 / 21:47:11 / cg"

    "Modified: / 5.12.1998 / 13:47:52 / cg"

!

replacementFontFor:name style:styleNr size:size

    |font family style|

    style := 'roman'.

    styleNr = 0 ifTrue:[

        style := 'roman'

    ].

    font := Font family:name style:style size:size.

    font notNil ifTrue:[^ font].

    name = 'Dialog' ifTrue:[

        family := 'helvetica'

    ] ifFalse:[

        family := 'courier'

    ].

    ^ Font family:name style:style size:size.

!

topViewsMenu:view

    |idx|

    view isTopView ifTrue:[

	view subViews size > 0 ifTrue:[

	    (idx := view subViews findFirst:[:v | v isMemberOf:MenuPanel]) ~~ 0 ifTrue:[

		"/ must add the menus height

		^ view subViews at:idx

	    ]

	].

    ].

    ^ nil

    "Modified: / 4.8.1997 / 01:23:06 / cg"

    "Created: / 4.1.1998 / 18:01:42 / cg"

!

viewForWPeer:nativeContext

    |jPeer|

    jPeer := nativeContext receiver.

    "/ sigh; pData was renamed to pNativeWidget in jdk1.2 ...

    O_FramePeer_pNativeWidget isNil ifTrue:[

	O_FramePeer_pNativeWidget := (jPeer class instVarOffsetOf:'pNativeWidget').

	O_FramePeer_pNativeWidget isNil ifTrue:[

	    O_FramePeer_pNativeWidget := 0.

	    O_FramePeer_pData isNil ifTrue:[

		O_FramePeer_pData := (jPeer class instVarOffsetOf:'pData').

	    ].

	]

    ].

    O_FramePeer_pNativeWidget > 0 ifTrue:[

	"/ ok, we are < 1.2

	^ jPeer instVarAt:O_FramePeer_pNativeWidget.

    ].

    ^ jPeer instVarAt:O_FramePeer_pData.

    "Modified: / 19.11.1998 / 01:43:20 / cg"

! !

!JavaNativeMethodImpl_OpenJDK6 class methodsFor:'helpers - io'!

addOpenFile:aStream

    "Given a stream, adds it into the open file table. Returns a

     (fake) file descriptor number"

    | fd |

    OpenFileTableLock critical:[

        fd := OpenFileTable indexOf: nil.

        fd ~~ 0 ifTrue:[

            OpenFileTable at: fd put: aStream.

            fd := fd - 1.

        ] ifFalse:[

            OpenFileTable add:aStream.

            fd := OpenFileTable size - 1.

        ].

    ].

    ^fd

    "Created: / 02-01-1998 / 18:32:59 / cg"

    "Modified (comment): / 18-07-2012 / 23:00:44 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

anyStream_close:nativeContext

    |jStream fileNo file|

    jStream := nativeContext receiver.

    file := self validateFile:jStream.

    file == Stdin ifTrue:[

        file := StdinReplacementFileQuerySignal raiseRequest.

        file isNil ifTrue:[

            file := Stdin

        ]

    ].

    "/ should always be bytes

    (file ~~ Stdin

    and:[file ~~ Stdout

    and:[file ~~ Stderr

    and:[file ~~ Transcript]]]) ifTrue:[

        file close.

    ] ifFalse:[

        self breakPoint: #jv.

    ].

    self setOpenFile:nil at:fileNo.

    fileNo := jStream instVarNamed:'fd'.

    fileNo isInteger ifFalse:[

        "/ JDK 1.1.3

        fileNo instVarNamed:'fd' put:0.

    ] ifTrue:[

        "/ JDK 1.0

        jStream instVarNamed:'fd' put:0

    ].

    "Created: / 04-02-1998 / 15:22:03 / cg"

    "Modified: / 14-10-1998 / 15:10:07 / cg"

    "Modified: / 28-07-2012 / 02:45:19 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

anyStream_readBytes:nativeContext

    |bytes offset count stream nRead|

    bytes := nativeContext argAt:1.

    offset := nativeContext argAt:2.

    count := nativeContext argAt:3.

    stream := self validateFile:(nativeContext receiver).

    "/ should always be bytes

    bytes class isBytes ifFalse:[

        self halt.

    ].

    stream == Stdin ifTrue:[

        stream := StdinReplacementFileQuerySignal raiseRequest.

        stream isNil ifTrue:[

            ^ -1 "/ 0  EOF

        ]

    ].

    FileIOTrace ifTrue:[

        ('JAVA: read ' , count printString , ' bytes from ' , stream pathName) infoPrintCR.

    ].

    stream isPositionable ifFalse:[

        "/ mhmh - some kind of socket or pipe

        stream readWait.

    ].

    count == 0 ifTrue:[^0].

    Stream readErrorSignal handle:[:ex |

        nRead := -1

    ] do:[

        nRead := stream nextAvailableBytes:count into:bytes startingAt:offset+1.

    ].

    nRead == 0 ifTrue:[

        stream atEnd ifTrue:[

            FileIOTrace ifTrue:[

                ('JAVA: at EOF ' , nRead printString) infoPrintCR.

            ].

            ^ -1

        ].

    ].

    count ~~ nRead ifTrue:[

        FileIOTrace ifTrue:[

            ('JAVA: only got ' , nRead printString) infoPrintCR.

        ]

    ].

    ^ nRead

    "Created: / 04-02-1998 / 15:20:00 / cg"

    "Modified: / 10-11-1998 / 19:56:47 / cg"

    "Modified: / 10-08-2011 / 21:35:00 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

anyStream_writeBytes:nativeContext

    |bytes offset count stream|

    bytes := nativeContext argAt:1.

    offset := nativeContext argAt:2.

    count := nativeContext argAt:3.

    stream := self validateFile:(nativeContext receiver).

    FileIOTrace ifTrue:[

        stream isFileStream ifTrue:[

            Logger log: ('write ' , count printString , ' bytes to ' , stream pathName) severity: #info facility: 'JVM'.

        ] ifFalse:[

            stream ~~ Stdout ifTrue:[

                stream ~~ Stderr ifTrue:[

                    Logger log: ('write ' , count printString , ' bytes to ' , stream displayString) severity: #info facility: 'JVM'.

                ]

            ]

        ]

    ].

    "/ should always be bytes

    Stream writeErrorSignal handle:[:ex |

        ex return

    ] do:[

        Socket brokenConnectionSignal handle:[:ex |

            ex return

        ] do:[

            stream isBinary ifTrue:[

                stream nextPutBytes:count from:bytes startingAt:offset+1

            ] ifFalse:[

                stream nextPutAll: (bytes asString copyFrom: offset + 1 to: offset + count).

            ]

        ].

        stream == Transcript ifTrue:[

            Transcript endEntry

        ]

    ].

    "Created: / 04-02-1998 / 15:23:58 / cg"

    "Modified: / 16-02-1999 / 11:32:45 / cg"

    "Modified: / 14-09-2011 / 22:05:25 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!