"

 Copyright (c) 2010-2011 Jan Vrany, Jan Kurs & Marcel Hlopko,

                         SWING Research Group, Czech Technical University 

                         in Prague

 Permission is hereby granted, free of charge, to any person

 obtaining a copy of this software and associated documentation

 files (the 'Software'), to deal in the Software without

 restriction, including without limitation the rights to use,

 copy, modify, merge, publish, distribute, sublicense, and/or sell

 copies of the Software, and to permit persons to whom the

 Software is furnished to do so, subject to the following

 conditions:

 The above copyright notice and this permission notice shall be

 included in all copies or substantial portions of the Software.

 THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND,

 EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES

 OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND

 NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT

 HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,

 WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING

 FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR

 OTHER DEALINGS IN THE SOFTWARE.

"

"{ Package: 'stx:libjava' }"

"{ NameSpace: Smalltalk }"

TestCase subclass:#JavaClassReloaderTests

	instanceVariableNames:'testClassLoader'

	classVariableNames:''

	poolDictionaries:''

	category:'Languages-Java-Tests-ClassReloading'

!

!JavaClassReloaderTests class methodsFor:'documentation'!

copyright

"

 Copyright (c) 2010-2011 Jan Vrany, Jan Kurs & Marcel Hlopko,

                         SWING Research Group, Czech Technical University 

                         in Prague

 Permission is hereby granted, free of charge, to any person

 obtaining a copy of this software and associated documentation

 files (the 'Software'), to deal in the Software without

 restriction, including without limitation the rights to use,

 copy, modify, merge, publish, distribute, sublicense, and/or sell

 copies of the Software, and to permit persons to whom the

 Software is furnished to do so, subject to the following

 conditions:

 The above copyright notice and this permission notice shall be

 included in all copies or substantial portions of the Software.

 THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND,

 EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES

 OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND

 NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT

 HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,

 WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING

 FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR

 OTHER DEALINGS IN THE SOFTWARE.

"

!

history

    "Created: #resources / 21-12-2012 / 18:09:27 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

    "Modified: #setUp / 02-10-2013 / 22:54:13 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

    "Modified: #tearDown / 02-10-2013 / 22:54:16 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

! !

!JavaClassReloaderTests class methodsFor:'resources'!

resources

  ^ Array 

        with: JavaInitializedResource.

    "Created: / 21-12-2012 / 18:09:27 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

! !

!JavaClassReloaderTests methodsFor:'interfaces'!

testAddingInterface

    OperatingSystem getLoginName = 'm' ifTrue:[

        self assert: false message: 'implement me!!'

    ]

    "Created: / 16-12-2012 / 17:40:40 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

    "Modified: / 03-04-2013 / 22:07:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaClassReloaderTests methodsFor:'private'!

compile: sourceCode

    | classes |

    classes := JavaCompiler compile: sourceCode.

"/    classes do:[:cls|cls classLoader: testClassLoader] .

    ^classes

    "Created: / 16-12-2012 / 17:02:41 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

    "Modified: / 09-04-2013 / 22:39:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

compileAndRegister: sourceCode

    |compiledClasses|

    compiledClasses := self compile: sourceCode.

    ^ self register: compiledClasses.

    "Created: / 16-12-2012 / 16:59:19 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

!

performTest

    JavaClassReader classLoaderQuerySignal answer: testClassLoader do:[

        super performTest

    ].

    "Created: / 16-12-2012 / 16:35:01 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

!

register: aClassOrArray

    ^aClassOrArray isArray ifTrue:[

        JavaVM registry registerClasses: aClassOrArray .

        JavaVM registry classNamed: aClassOrArray anElement binaryName loader: aClassOrArray anElement classLoader

    ] ifFalse:[

        JavaVM registry registerClass: aClassOrArray.

        JavaVM registry classNamed: aClassOrArray binaryName loader: aClassOrArray classLoader

    ].

    "Created: / 16-12-2012 / 17:02:04 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

    "Modified: / 14-10-2013 / 23:12:02 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

testInfrastructure

    |compiledClass|

    self assert: (JavaClassReader classLoaderQuerySignal query = testClassLoader ) 

        message: 'tests should run in testClassLoader sandbox'.

    compiledClass := self compileAndRegister: '

public class HelloSun {

    public String hello() {

        return "helloooo";

    }

}

'.

    self assert: compiledClass notNil message: 'Java compiler should be working for these tests to run'.

    self assert: compiledClass classLoader = testClassLoader message: 'compiled classes should have testClassLoader as their defining cl'.

    self assert: (JavaVM registry getClassesDefinedBy: testClassLoader) size = 1 message: 'only classes from these tests should use testClassLoader'.

    self assert: (JavaVM registry getClassesDefinedBy: testClassLoader) anElement == compiledClass message: 'compiled classes should be registered in testClassLoader'.

    "Created: / 16-12-2012 / 16:38:17 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

! !

!JavaClassReloaderTests methodsFor:'running'!

setUp

    testClassLoader := JAVA java lang ClassLoader new.

    ObjectMemory garbageCollect.

    "Created: / 16-12-2012 / 16:32:32 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

    "Modified: / 02-10-2013 / 22:54:13 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

!

tearDown

    JavaVM registry unregisterClassLoader: testClassLoader.

    ObjectMemory garbageCollect.

    "Created: / 16-12-2012 / 16:33:31 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

    "Modified: / 02-10-2013 / 22:54:16 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

! !

!JavaClassReloaderTests methodsFor:'test helpers'!

callerClass

    | callerClass |

    callerClass := (JavaCompiler 

            compile: '

package classReloadingTests;

public class Caller {

    public String callFooToString(Object c) {

        return c.toString();

    }   

}

') anElement.

    callerClass 

        ifNil: [ self error: 'callerClass is expected to be not nil in these tests' ].

    ^ callerClass.

    "Created: / 06-12-2012 / 21:41:35 / Marcel Hlopko <hlopkmar@fel.cvut.cz>"

    "Modified: / 18-12-2012 / 14:00:12 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

    "Modified: / 04-01-2013 / 14:51:47 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

compileAndRegisterChangingClassParent

    self compileAndRegister: '

package classReloadingTests;

public class ChangingClassParent {

    public String foo() {

        return "parent";

    }

    public String toString() {

        return "" + foo();

    }   

}'.

    "Created: / 18-12-2012 / 13:47:32 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

! !

!JavaClassReloaderTests methodsFor:'tests - classes'!

test_classes_01a

    "

    1) compile simple class with static method that returns an instance

       **non-existent** class Missing

    2) 

    3) compile Missing class

    4) call that static method, should return an instance of Missing

    "

    | user missing  |

    user := self compileAndRegister:'

public class test_classes_01a_user { 

    public static Object foo() {

        return new test_classes_01a_Missing();

    }

}'.

    self should: [ user new foo ] raise: JavaUnresolvedCompilationError.

    missing := self compileAndRegister:'

public class test_classes_01a_Missing {

}

'.

    self shouldnt: [ user new foo ] raise: JavaUnresolvedCompilationError.

    self assert: user new foo class == missing.

    "Created: / 16-10-2013 / 13:26:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaClassReloaderTests methodsFor:'tests - concurrency'!

test_concurrency_01

    "

    Test whether an update of class is atomic    

    1) compile simple class with one method

    2) spawn a hammering thread that run that method in a loop.

    3) change the method to call another method

    4) change the method back

    5) repeat steps 3) and 4) 100 times.

    Check, that everything works, no error occur...

    "

    <timeout: 600> "10min"

    | source1 source2 class hammerer iterations stop error limit probes |

    source1 := '

public class test_concurrency_01 { 

    public String bar() {

        String s = foo();

        assert(s instanceof String);

        return s;

    }

    public String foo() { 

        return "XXX"; 

    }

}'.                                  

    source2 := '

public class test_concurrency_01 { 

    public String bar() {

        String s = foo();

        assert(s instanceof String);

        return s;

    }

    public String foo() { 

        return foo(this.getClass().getName()); 

    }

    public String foo(String s) {

        return s;

    }

}'.

    class := self compileAndRegister: source1.

    self assert: class new foo = 'XXX'.

    "/ Spawn a hammering thread...

    stop := false.

    error := nil.

    iterations := 0.

    hammerer := [ 

        | inst |

        inst := class new.

        [ 

            [ stop ] whileFalse:[ 

                | string |

                string := inst bar.

                Object assert: string isString.

                iterations := iterations + 1.

            ].

        ] on: Error do:[:ex |

            error := ex.

            self yourself.

        ]

    ] fork.

    probes := 0.

    [ error isNil and:[ probes < 100 ] ] whileTrue:[

        Transcript 

            show: 'JavaClassReloaderTests>>test_concurrency_01, iteration ';

            showCR: probes printString.

        limit := iterations + 10.

        "/ Wait until some more iterations are done...

        [ (iterations < limit) and:[error isNil ] ] whileTrue:[ 

            Delay waitForMilliseconds: 100. 

        ].          

        class := self compileAndRegister: (probes even ifTrue:[source2] ifFalse:[source2]).

        limit := iterations + 10.

        "/ Wait until some more iterations are done...

        [ (iterations < limit) and:[error isNil ] ] whileTrue:[ 

            Delay waitForMilliseconds: 100. 

        ].

        probes := probes + 1.

    ].

    stop := true.

    hammerer terminate.

    self assert: error isNil.

    "Created: / 01-04-2015 / 12:03:58 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 01-04-2015 / 19:25:51 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaClassReloaderTests methodsFor:'tests - fields'!

test_fields_00a

    "

     1) compile simple class with one field

     2) change type of the field from int to Object

"

    | jclass1  jinst1  jclass2  jinst2  callerClass |

    jclass1 := self 

            compileAndRegister: '

public class test_01 { 

    public int foo = 1;

    public int bar() {

        return 1;

    }

}'.

    self assert: jclass1 hasMultipleVersions not message: 'java class should not have multiple versions initially'.

    jinst1 := jclass1 new.

    jclass2 := self 

            compileAndRegister: '

public class test_01 { 

    public Object foo = new Object();

    public int bar() {

        return 2;

    }

}'.

    jinst2 := jclass2 new.

    callerClass := self 

            compileAndRegister: '

public class CallerClass {

    public static Object getFoo(test_01 inst) {

        return inst.foo;

    }

}'.

    self assert: jclass1 ~~ jclass2.

    self assert: jclass1 fields size == 1.

    self assert: jclass1 fields anElement descriptor = 'I'.

    self assert: jinst1 bar == 1.

    self assert: jclass2 fields size == 1.

    self assert: jclass2 fields anElement descriptor = 'Ljava/lang/Object;'.

    self assert: jinst2 bar == 2.

    self shouldnt: [ callerClass getFoo: jinst1 ] raise: Error.

    self shouldnt: [ callerClass getFoo: jinst2 ] raise: Error.

    "Created: / 09-04-2013 / 15:00:51 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 09-04-2013 / 16:17:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 28-10-2013 / 12:51:20 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

!

test_fields_00b

    "

     1) compile simple class with one field

     2) change type of the field from Object to int

"

    | jclass1  jinst1  jclass2  jinst2  callerClass |

    jclass1 := self 

            compileAndRegister: '

public class test_01 { 

    public Object foo = new Object();

    public int bar() {

        return 1;

    }

}'.

    jinst1 := jclass1 new.

    jclass2 := self 

            compileAndRegister: '

public class test_01 { 

    public int foo = 42;

    public int bar() {

        return 2;

    }

}'.

    jinst2 := jclass2 new.

    callerClass := self 

            compileAndRegister: '

public class CallerClass {

    public static int getFoo(test_01 inst) {

        return inst.foo;

    }

}'.

    self assert: jclass1 ~~ jclass2.

    self assert: jclass1 fields size == 1.

    self assert: jclass1 fields anElement descriptor = 'Ljava/lang/Object;'.

    self assert: jinst1 bar == 1.

    self assert: jclass2 fields size == 1.

    self assert: jclass2 fields anElement descriptor = 'I'.

    self assert: jinst2 bar == 2.

    self shouldnt: [ callerClass getFoo: jinst1 ] raise: Error.

    self shouldnt: [ callerClass getFoo: jinst2 ] raise: Error.

    "Created: / 20-09-2013 / 00:05:59 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

    "Modified: / 12-10-2013 / 18:19:51 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

!

test_fields_01a

    "

    1) compile simple class with one field

    2) change type of the field from String to Object

    3) as this is type generalization, no new class version

        should be introduced, new field type is used by old class

    "

    | jclass1 jinst1 jclass2 jinst2 callerClass |

    jclass1 := self compileAndRegister:'

public class test_01 { 

    public String foo = "xxx";

    public int bar() {

        return 1;

    }

}'.

    jinst1 := jclass1 new.

    jclass2 := self compileAndRegister:'

public class test_01 { 

    public Object foo = new Object();

    public int bar() {

        return 2;

    }

}'.

    jinst2 := jclass2 new.

    callerClass := self compileAndRegister:'

public class CallerClass {

    public static Object getFoo(test_01 inst) {

        return inst.foo;

    }

}'.

    self assert: jclass1 == jclass2.

    self assert: jclass1 fields size == 1.

    self assert: jclass1 fields anElement descriptor = 'Ljava/lang/Object;'.

    self assert: jinst1 bar == 2.

    self assert: jclass2 fields size == 1.

    self assert: jclass2 fields anElement descriptor = 'Ljava/lang/Object;'.

    self assert: jinst2 bar == 2.

    self shouldnt:   [ callerClass getFoo: jinst1 ] raise: Error.

    self shouldnt: [ callerClass getFoo: jinst2 ] raise: Error.

    "Created: / 09-04-2013 / 15:24:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 12-10-2013 / 19:28:02 / Marcel Hlopko <marcel.hlopko@fit.cvut.cz>"

!

test_fields_01b

    "

    1) compile simple class with one field

    2) change type of the field from Object to String

    3) new class version should be created

    "

    | jclass1 jinst1 jclass2 jinst2 callerClass |

    jclass1 := self compileAndRegister:'

public class test_01 {