"{ Package: 'stx:libjava' }"

TestCase subclass:#JUnitTestCaseProxy

	instanceVariableNames:''

	classVariableNames:'TestCases'

	poolDictionaries:''

	category:'Languages-Java-JUnit'

!

JUnitTestCaseProxy class instanceVariableNames:'javaClassName'

"

 The following class instance variables are inherited by this class:

	TestCase - lastTestRunResultOrNil lastTestRunsPassedTests lastTestRunsFailedTests lastTestRunsErrorTests

	TestAsserter - 

	Object - 

"

!

!JUnitTestCaseProxy class methodsFor:'initialization'!

initialize

    TestCases := Dictionary new.

    "Created: / 01-03-2011 / 10:43:45 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

setJavaClassName: aSymbol

    javaClassName ifNotNil:

        [self error: 'Attempting to set java class name twice'].

    javaClassName := aSymbol.

    "Created: / 01-03-2011 / 10:43:05 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JUnitTestCaseProxy class methodsFor:'accessing'!

javaClass

    ^Java at: javaClassName

    "Created: / 01-03-2011 / 11:30:29 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 01-03-2011 / 14:48:30 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

javaClassName

    ^javaClassName

    "Created: / 01-03-2011 / 11:30:56 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

lookupHierarchyRoot

    ^JUnitTestCaseProxy

    "Created: / 01-03-2011 / 11:41:59 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 01-03-2011 / 14:54:55 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

selector: aSymbol

    ^super selector: aSymbol

    "Created: / 01-03-2011 / 11:55:18 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JUnitTestCaseProxy class methodsFor:'private'!

testSelectors

    | javaClass |

    self == JUnitTestCaseProxy ifTrue:[ ^ #() ].

    javaClass := self javaClass.

    (javaClass includesBehavior:(JavaVM classForName:'junit.framework.TestCase')) 

        ifTrue:[ ^ javaClass selectors select:[:sel | sel startsWith:'test' ]. ].

    ^ (javaClass 

        selectMethodsAnnotatedWith:(JavaVM classForName:'org.junit.Test') typeName) 

            collect:[:method | method selector ]

    "

        (JUnitTestCase for: JAVA::stx::libjava::tests::junit::JUnit3Tests)

            testSelectors"

    "Created: / 01-03-2011 / 10:49:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 03-03-2011 / 00:34:39 / Marcel Hlopko <hlopik@gmail.com>"

    "Modified: / 04-03-2011 / 00:05:51 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JUnitTestCaseProxy class methodsFor:'queries'!

isAbstract

    ^self == JUnitTestCaseProxy

    "Created: / 28-02-2011 / 22:32:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 01-03-2011 / 14:54:58 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

shouldFork

	^true

! !

!JUnitTestCaseProxy class methodsFor:'subclass creation'!

for:javaClass 

    "Answers a new (anonymous) testcase proxy for

     given javaClass"

    | meta  cls  name |

    self assert:javaClass isJavaClass description:'Not a java class'.

    self assert:javaClass isTestCaseLike

        description:'Not a testcase-like class'.    

    name := javaClass name.

    TestCases at: name ifPresent:[:c|^c].

    meta := Metaclass new.

    meta setSuperclass: JUnitTestCaseProxy class.

    meta instSize: JUnitTestCaseProxy class instSize.

    cls := meta new.

    cls setSuperclass: JUnitTestCaseProxy.

    cls flags: JUnitTestCaseProxy flags.

    cls instSize: JUnitTestCaseProxy instSize.

    cls setJavaClassName: name.

    cls setName: ('JUnitTestCase for: (Java classForName: ', name storeString, ')') asSymbol.

    cls setCategory: javaClass category.

    TestCases at: name put: cls.

        ^cls

    "Created: / 01-03-2011 / 10:30:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 03-03-2011 / 00:20:49 / Marcel Hlopko <hlopik@gmail.com>"

    "Modified: / 01-04-2011 / 16:02:45 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JUnitTestCaseProxy methodsFor:'accessing'!

javaClass

    | javaClass |

    self 

        assert: (javaClass := self class javaClass) isJavaClass

        description: 'java class does not exists'.

    ^javaClass

    "Created: / 01-03-2011 / 14:48:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

nameForHDTestReport

    ^self class javaClassName copyReplaceAll:$/ with: $.

    "Created: / 01-04-2011 / 16:10:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

selectorForHDTestReport

! !

!JUnitTestCaseProxy methodsFor:'private'!

performTest

    <resource: #skipInDebuggersWalkBack>

    [

    self javaClass new perform: testSelector sunitAsSymbol

    ] on: JavaError do: [:ex|

        "This is the tricky part. We have to auto-magically convert

         jUnit's AssertionFailedError to sUnits TestFailure's"

        "Bad, bad, I know..."

        (ex parameter class name == #'junit/framework/AssertionFailedError')

            ifTrue:

                [ TestResult failure sunitSignalWith: ex description ]

            ifFalse:

                [ ex pass ]

    ]

    "Created: / 01-03-2011 / 14:50:32 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 04-03-2011 / 00:07:15 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JUnitTestCaseProxy class methodsFor:'documentation'!

version_SVN

    ^ '$Id$'

! !

JUnitTestCaseProxy initialize!