"{ Package: 'stx:libjava/tools' }"

Object subclass:#JavaSourceDocument

	classVariableNames:'Cache CacheSize Job'

	poolDictionaries:''

	category:'Languages-Java-Tools-Source'

!

!JavaSourceDocument class methodsFor:'documentation'!

documentation

"

    JavaSourceDocument object keeps various useful information about one source 

    file. In particular, it keeps parse tree and pre-highlighted source.

    [author:]

        Jan Vrany <jan.vrany@fit.cvut.cz>

    [instance variables:]

    [class variables:]

    [see also:]

"

! !

!JavaSourceDocument class methodsFor:'initialization'!

initialize

    "Invoked at system start or when the class is dynamically loaded."

    "/ please change as required (and remove this comment)

    CacheSize := 25.

    Cache := OrderedCollection new: CacheSize * 2 "To avoid excessive shifting...".

    Job := BackgroundQueueProcessingJob named: 'java parsing job' on:[:block | block value ].

    "Modified: / 06-09-2013 / 17:45:31 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaSourceDocument class methodsFor:'instance creation'!

for: aJavaClass

    ^self new javaClass: aJavaClass.

    "Created: / 30-08-2013 / 01:46:23 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaSourceDocument class methodsFor:'accessing'!

cachedDocumentFor: aJavaClass

    "Returns a cached document for given class or nil if no cached 

     document is found."

    Cache withIndexDo:[:document :index|

        document javaClass == aJavaClass ifTrue:[

            "/ Move that document towards the end so it'll be less likely

            "/ to be removed

            index < Cache size ifTrue:[

                Cache swap: index with: index + 1.                

            ].

            ^ document.

        ]

    ].

    ^ nil

    "Created: / 30-08-2013 / 01:27:07 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

cachedDocumentFor: aJavaClass put: aJavaSourceDocument

    "Stores given source document in the cache"

    self assert: aJavaSourceDocument javaClass == aJavaClass.

    Cache size = CacheSize ifTrue:[

        Cache removeFirst.

    ].

    Cache addLast: aJavaSourceDocument

    "Created: / 30-08-2013 / 01:42:44 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaSourceDocument methodsFor:'accessing'!

javaClass

    ^ javaClass

!

javaClass:aJavaClass

    aJavaClass == javaClass ifTrue:[

        ^ self

    ].

    javaClass notNil ifTrue:[

        self error: 'Class already set!!'

    ].

    javaClass := aJavaClass.

    self initializeSourceTree.

    "Modified: / 06-09-2013 / 17:51:59 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

sourceLineToOffset: lineNr

    lineNr == 1 ifTrue:[ ^ 1 ].

    ^  (sourceLineEnds at: lineNr - 1) + 1.

    "Created: / 08-09-2013 / 10:52:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

sourceOffsetToLine: offset

    |low    "{ Class: SmallInteger}"

     high   "{ Class: SmallInteger}"

     middle "{ Class: SmallInteger}"

     element|

    "

     we can of course use a binary search - since the elements are sorted

    "

    low := 1.

    high := sourceLineEnds size.

    [low > high] whileFalse:[

        middle := (low + high) // 2.

        element := sourceLineEnds at:middle.

        element < offset ifTrue:[

            "middleelement is smaller than object"

            low := middle + 1

        ] ifFalse:[

            high := middle - 1

        ]

    ].

    ^ low

    "Created: / 10-09-2013 / 03:40:19 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

sourceText

    ^ sourceText

!

sourceText:aText

    sourceText := aText.

!

sourceTree

    "Return source tree for my class's compilation unit (i.e., CompilationUnitDeclaration)"

    sourceTree isNil ifTrue:[

        sourceTreeLock notNil ifTrue:[

            sourceTreeLock wait.

        ].

    ].

    ^ sourceTree

    "Modified: / 06-09-2013 / 22:58:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 13-09-2013 / 04:22:49 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

sourceTreeForClass

    "Returns a root node (i.e., instance of TypeDeclaration) for my javaClass"

    ^ self sourceTreeForClass: javaClass.

    "Created: / 13-09-2013 / 04:20:59 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 13-09-2013 / 11:08:24 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

sourceTreeForClass: aJavaClass

    "Returns a root node (i.e., instance of TypeDeclaration) for my javaClass"

    | enclosingClass enclosingClassNode nm |

    enclosingClass := aJavaClass enclosingClass.

    ^ enclosingClass notNil ifTrue:[

        nm := aJavaClass name copyFrom: enclosingClass name size + 2.

        (nm conform: [:c|c isDigit]) ifTrue:[

            "/ Could only by anonymous class created in static initializer

            self error: 'Should not happen'

        ] ifFalse:[

            enclosingClassNode := self sourceTreeForClass: enclosingClass.

            enclosingClassNode memberTypes detect: [:type | type name = nm ] ifNone:[self error:'No member type'].

        ]

    ] ifFalse:[

        nm := aJavaClass lastName.

        sourceTree types detect: [:type | type name = nm] ifNone:[self error:'No type'].

    ].

    "Created: / 13-09-2013 / 11:06:53 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

sourceTreeOrNilIfParsing

    sourceTree isNil ifTrue:[

        sourceTreeLock notNil ifTrue:[

            ^ nil

        ].

    ].

    ^ sourceTree

    "Created: / 12-09-2013 / 21:40:39 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaSourceDocument methodsFor:'debugging'!

inspector2TabParseTree

    SmallSense::ParseNodeInspector notNil ifTrue:[

        ^self newInspector2Tab

            label: 'Parse Tree';

            priority: 35;

            application: (SmallSense::ParseNodeInspector new node: sourceTree source: sourceText)

    ].

    ^nil

    "Created: / 30-08-2013 / 01:59:15 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

inspector2Tabs

    | tabs |

    tabs := super inspector2Tabs.

    (SmallSense::ParseNodeInspector notNil and:[sourceTree notNil and:[sourceText notNil]]) ifTrue:[

        tabs := tabs , #(inspector2TabParseTree)

    ].

    ^tabs

    "Created: / 30-08-2013 / 02:00:44 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaSourceDocument methodsFor:'initialization-private'!

initializeSourceRefsInMethods

    | enclosingMethod typeName typeNode |

    enclosingMethod := javaClass enclosingMethod.

    (enclosingMethod isNil and:[javaClass isAnonymous]) ifTrue:[

        enclosingMethod := javaClass topEnclosingClass compiledMethodAt: #'<clinit>()V'. 

    ].

    enclosingMethod notNil ifTrue:[

        javaClass methodDictionary  keysAndValuesDo: [:selector :method | 

            method setSource: (enclosingMethod source; getSource).

        ].

        ^ self

    ].

    typeNode := self sourceTreeForClass.

    javaClass methodDictionary 

        keysAndValuesDo: [:selector :method | 

            | descriptor  methodName  methodNodes  methodNode  source |

            method isJavaMethod ifTrue:[

                descriptor := method descriptor.

                methodName := descriptor name.

                methodName = '<init>' ifTrue: [

                    methodName := typeName.

                ].

                methodNodes := typeNode methods 

                        select: [:each | 

                            each selector = methodName 

                                and: [ each arguments size == descriptor parameters size ]

                        ].

                methodNodes notEmptyOrNil ifTrue: [

                    methodNodes size == 1 ifTrue: [

                        methodNode := methodNodes anElement.

                    ] ifFalse: [

                        method hasLineNumberInformation ifTrue: [

                            | line0  offset0 |

                            line0 := method lineNumberForPC0: 1.

                            offset0 := self sourceLineToOffset: line0.

                            methodNodes := typeNode methods 

                                    select: [:each | 

                                        offset0 between: each declarationSourceStart

                                            and: each declarationSourceEnd + 1

                                    ].

                            methodNodes size == 1 ifTrue: [

                                methodNode := methodNodes anElement.

                            ]

                        ].

                        methodNode isNil ifTrue: [

                            | 

                            "/ OK, search by parameter types...

                             i |

                            i := 1.

                            [

                                (methodNodes size > 1) and: [ i <= descriptor parameters size ]

                            ] whileTrue: [

                                | descr  descrArgTypeName  descrArgDimensions |

                                descr := descriptor parameters at: i.

                                descrArgTypeName := descr javaClassName.

                                descrArgDimensions := descr dimensions.

                                descrArgTypeName first == $[ ifTrue: [

                                    descrArgTypeName := (JavaDescriptor baseTypes at: descrArgTypeName second) 

                                            javaName.

                                    descrArgDimensions := descrArgDimensions + 1.

                                ].

                                methodNodes := methodNodes 

                                        select: [:each | 

                                            | nodeArgType  nodeArgDimensions |

                                            nodeArgType := (each arguments at: i) type getTypeName asStringWith: $/.

                                            nodeArgDimensions := (each arguments at: i) type dimensions.

                                            descrArgDimensions == nodeArgDimensions 

                                                and: [ descrArgTypeName includesSubString: nodeArgType ]

                                        ].

                                i := i + 1.

                            ].

                            methodNodes isEmpty ifTrue: [

                                self error: 'No matching method node!!'.

                            ].

                            methodNodes size > 1 ifTrue: [

                                self error: 'Cannot determine method!!'.

                            ].

                            methodNode := methodNodes anElement.

                        ].

                    ].

                    methodNode notNil ifTrue: [

                        source := JavaSourceRef new.

                        source offset: methodNode declarationSourceStart.

                        source length: methodNode declarationSourceEnd - methodNode declarationSourceStart + 1.

                        source line0: (self sourceOffsetToLine: methodNode declarationSourceStart).

                        source lineH: (self sourceOffsetToLine: methodNode sourceStart).

                        method setSource: source.

                    ] ifFalse: [

                        self error: 'Cannot determine method!!'.

                    ]

                ].

            ].

        ]

    "Created: / 07-09-2013 / 01:43:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 13-09-2013 / 11:24:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

initializeSourceTree

    | task |

    sourceTreeLock := Semaphore new.

    "Job add:"

    task := [

        [

            | source  unit  parser |

            source := javaClass theNonMetaclass source.

            source notNil ifTrue: [

                unit := (Java classForName: 'stx.libjava.tools.Source') new.

                unit setContents: source.

                parser := (Java classForName: 'stx.libjava.tools.parser.Parser') 

                        new.

                sourceTree := parser parse: unit diet: true resolve: false.

                sourceLineEnds := parser scanner getLineEnds.

                self initializeSourceRefsInMethods.

            ].

        ] ensure: [

            sourceTreeLock signal.

            sourceTreeLock := nil.

        ]

    ] newProcess.

    task name: 'Parse task for ', javaClass name.

    task resume.

    "Created: / 06-09-2013 / 17:50:54 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 13-09-2013 / 17:35:37 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaSourceDocument methodsFor:'printing & storing'!

printOn:aStream

    "append a printed representation if the receiver to the argument, aStream"

    super printOn:aStream.

    aStream nextPutAll:'('.

    javaClass printOn:aStream.

    aStream nextPutAll:')'.

    "Modified: / 12-09-2013 / 01:04:02 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaSourceDocument methodsFor:'resolving'!

resolve

    | resolver |

    self sourceTree. "/Ensure source is parsed.

    sourceTree scope isNil ifTrue:[

        resolver := (Java classForName: 'stx.libjava.tools.environment.Resolver') new.

        resolver resolve: sourceTree.

    ].

    "Created: / 12-09-2013 / 22:43:02 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 13-09-2013 / 02:19:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaSourceDocument class methodsFor:'documentation'!

version_CVS

    ^ '$Header: /cvs/stx/stx/libjava/tools/JavaSourceDocument.st,v 1.1 2013-09-06 00:45:28 vrany Exp $'

!

version_HG

    ^ '$Changeset: <not expanded> $'

! !

JavaSourceDocument initialize!