"{ Package: 'stx:libscm/mercurial' }"

Object subclass:#HGCommandParser

	instanceVariableNames:'stream'

	classVariableNames:''

	poolDictionaries:''

	category:'SCM-Mercurial-Internal'

!

!HGCommandParser class methodsFor:'instance creation'!

on: aStringOrStream

    | stream |

    stream := aStringOrStream isStream 

                ifTrue:[aStringOrStream]

                ifFalse:[aStringOrStream readStream].

    ^self new stream: stream

    "Created: / 23-10-2012 / 11:07:52 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 13-11-2012 / 16:36:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!HGCommandParser class methodsFor:'templates'!

templateLog

    ^

'{rev}:{node}

{branch}

{parents}

{author}

{date|isodate}

{desc}

**EOE**

'

    "Created: / 12-11-2012 / 23:06:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 13-11-2012 / 17:18:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!HGCommandParser methodsFor:'accessing'!

stream

    ^ stream

!

stream:something

    stream := something.

! !

!HGCommandParser methodsFor:'error reporting'!

error: aString

    <context: #return>

    <resource: #skipInDebuggersWalkBack>

    HGCommandParseError raiseWith:#error: errorString:aString

    "Created: / 14-11-2012 / 19:59:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!HGCommandParser methodsFor:'parsing'!

parseDate

    | ts |

    ts := Timestamp readIso8601FormatFrom:stream.

    (stream peek == $+ or:[stream peek == $-]) ifFalse:[

        self error:'Timezone expected, ' , stream peek , ' found'

    ].

    stream next.

    4 timesRepeat:[

        ('0123456789' includes: stream peek) ifFalse:[

            self error:'Timezone expected, ' , stream peek , ' found'

        ].

        stream next.

    ].

    ^ts

    "Created: / 13-11-2012 / 10:22:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 13-11-2012 / 17:28:44 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseLog

    "Parse output of 'hg log' command, assuming the template given

     was HGCommandParser templateLog. Return a list of HGRevision."

    | revs |

    revs := OrderedCollection new.

    [ stream atEnd ] whileFalse:[

        | rev |

        rev := self parseLogEntry.

        revs add: rev.

    ].

    ^revs.

    "Created: / 13-11-2012 / 09:46:28 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseLogEntry

    "Parse single revision entry, assuming the template given

     was HGCommandParser templateLog. Return a HGRevision."

    | rev line message |

    rev := HGChangeset new.

    rev setId: self parseNodeId. self nextLineEnd.

    rev setBranch: self nextLine.

    rev setParent1Id: self parseNodeId. self nextSpace.

    rev setParent2Id: self parseNodeId. self nextSpace. self nextLineEnd.

    rev setAuthor: self nextLine.

    rev setTimestamp: self parseDate. self nextLineEnd.

    message := String streamContents:[:s|

        [ line := self nextLine . line = '**EOE**' ] whileFalse:[

            s nextPutLine: line

        ].

    ].

    rev setMessage: message.

    ^rev

    "Created: / 13-11-2012 / 09:45:40 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 13-11-2012 / 17:29:23 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseNodeId

    "Parses node id from stream and returns it. Support both,

     short and full node ids"

    ^HGNodeId readFrom: stream onError:[:msg|self error: msg]

    "

        (HGCommandParser on: '4:6f88e1f44d9eb86e0b56ca15e30e5d786acd83c7' readStream) parseNodeId

        Bad ones:

        (HGCommandParser on: '4:6f88e1f44d9eb86e0b56ca15e30e5d786acd' readStream) parseNodeId

        (HGCommandParser on: '4:6f88Z1f44d9eb86e0b56ca15e30e5d786acd83c7' readStream) parseNodeId

    "

    "Created: / 13-11-2012 / 10:22:49 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 13-11-2012 / 16:52:23 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!HGCommandParser methodsFor:'parsing - commands'!

parseCommandLog

    "Parse output of 'hg log' command, assuming the template given

     was HGCommandParser templateLog. Return a list of HGRevision."

    ^self parseLog

    "Created: / 13-11-2012 / 09:09:24 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseCommandStatus

    | statusesAndPaths |

    statusesAndPaths := OrderedCollection new.

    [ stream atEnd ] whileFalse:[

        | status path |

        status := HGStatus forCode: self next.

        self nextSpace.

        path := self nextLine.

        statusesAndPaths add: { status . path }

    ].

    ^ statusesAndPaths

    "Created: / 23-10-2012 / 10:57:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!HGCommandParser methodsFor:'parsing-utils'!

next

    ^stream next.

    "Created: / 23-10-2012 / 10:57:24 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

nextLine

    ^stream nextLine

    "Created: / 23-10-2012 / 11:05:47 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 09-11-2012 / 12:02:08 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

nextLineEnd

    | c |

    ((c := stream peek) ~= Character cr) ifTrue:[

        self error:'New line expected. ''', c , ''' found!!'

    ].

    stream next.

    "Created: / 13-11-2012 / 10:17:28 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 13-11-2012 / 17:18:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

nextSpace

    | c |

    ((c := stream next) ~= Character space) ifTrue:[

        self error:'Space expected. ''', c , ''' found!!'

    ]

    "Created: / 23-10-2012 / 10:58:20 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 09-11-2012 / 11:59:45 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!HGCommandParser class methodsFor:'documentation'!

version_HG

    "Never, ever change this method. Ask JV or CG why"

    ^thisContext method mclass theNonMetaclass instVarNamed: #revision

!

version_SVN

! !