"{ Package: 'stx:libscm/git' }"

GitLibraryObject subclass:#GitWorkingCopy

	instanceVariableNames:'repository reference commit index root detached'

	classVariableNames:''

	poolDictionaries:'GitStatusCodes'

	category:'SCM-Git-Model'

!

!GitWorkingCopy methodsFor:'accessing'!

index

    "Get the Index file for this repository."

    index isNil ifTrue:[

        | ref err |

        ref := ByteArray new: ExternalBytes sizeofPointer.

        err := GitPrimitives prim_git_repository_index: ref repo: handle.

        GitError raiseIfError: err.

        index := GitIndex new

            setHandleFromRef: ref;

            setRepository: repository;

            yourself

    ].

    ^ index

    "Created: / 24-09-2012 / 15:42:05 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

root

    ^ root

! !

!GitWorkingCopy methodsFor:'actions'!

checkout: aStringOrOidOrTreeish

    | obj |

    aStringOrOidOrTreeish isGitTreeish ifTrue:[

        obj := aStringOrOidOrTreeish 

    ] ifFalse:[

        | oid |

        oid := aStringOrOidOrTreeish isGitOid 

                    ifTrue:[aStringOrOidOrTreeish]

                    ifFalse:[GitOid fromString: aStringOrOidOrTreeish].

        obj := repository lookup: oid.

    ].

    repository checkout: obj.

    commit := obj.

    "Created: / 19-09-2012 / 14:00:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

commit: message

    self commit: message tree: index tree

    "Created: / 25-09-2012 / 10:19:58 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

commit: message tree: tree

    self commit: message tree: tree parents: (Array with: commit)

    "Created: / 25-09-2012 / 11:09:43 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

commit: message tree: tree parents: parents 

    self commit: message tree: tree parents: parents update: (detached ifTrue:[nil] ifFalse:[reference]).

    "Created: / 25-09-2012 / 11:11:23 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

commit: message tree: tree parents: parents update: refOrNil

    ^self commit: message tree: tree parents: parents update: refOrNil commiter: nil.

    "Created: / 25-09-2012 / 12:24:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

commit: message tree: tree parents: parents update: refOrNil commiter: commiterOrNil

    ^self commit: message tree: tree parents: parents update: refOrNil commiter: commiterOrNil author: nil

    "Created: / 25-09-2012 / 14:50:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

commit: message tree: tree parents: parents update: refOrNil commiter: commiterOrNil author: authorOrNil

    ^repository commit: message tree: tree parents: parents update: refOrNil commiter: commiterOrNil author: authorOrNil

    "Created: / 25-09-2012 / 14:50:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

stage

    "Stage all unstaged files"

    self entriesAndStatusesDo: [:entry :status|

        (status bitAnd: (GIT_STATUS_WT_MODIFIED | GIT_STATUS_WT_DELETED)) ~~ 0 ifTrue:[

            self index add: entry.            

        ] ifFalse:[

            (status bitAnd: (GIT_STATUS_WT_DELETED)) ~~ 0 ifTrue:[

                self index remove: entry.

            ].

        ].

    ].

    self index write

    "Created: / 25-09-2012 / 00:13:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GitWorkingCopy methodsFor:'enumerating'!

entriesAndStatusesDo: aBlock

    | cb err |

    cb := ExternalFunctionCallback new.

    cb returnType:#int argumentTypes: #(charPointer int pointer).

    cb action:[:path :status :payload|

        aBlock value: (root / path copyCStringFromHeap) value: status

    ].

    cb generateClosure.

    err := GitPrimitives prim_git_status_foreach: repository getHandle callback: cb payload: nil.

    GitError raiseIfError: err.

    "Created: / 25-09-2012 / 00:11:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GitWorkingCopy methodsFor:'initialization'!

setRepository: aGitRepository

    handle := aGitRepository getHandle.

    repository := aGitRepository.

    root := GitWorkingCopyEntry wc: self path: repository workdir.

    "Created: / 19-09-2012 / 09:43:47 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GitWorkingCopy methodsFor:'initialization & release'!

free

    "Nothing to do, I have no backing structure"

    "Modified: / 25-09-2012 / 00:39:16 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GitWorkingCopy methodsFor:'instance creation'!

/ aString

    ^root construct: aString

    "Created: / 24-09-2012 / 13:49:45 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

construct: aString

    ^root construct: aString

    "Created: / 24-09-2012 / 13:50:28 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GitWorkingCopy methodsFor:'private'!

statusOf: aStringOrFilenameOrWorkingCopyEntry

    ^repository statusOf: aStringOrFilenameOrWorkingCopyEntry

    "Created: / 24-09-2012 / 22:36:25 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GitWorkingCopy methodsFor:'private-accessing'!

getHandleClass

    ^ self shouldNotImplement

    "Modified (comment): / 25-09-2012 / 00:39:28 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!GitWorkingCopy class methodsFor:'documentation'!

version_SVN

    ^ '$Id::                                                                                                                        $'

! !