"{ Encoding: utf8 }"

"

stx:libscm - a new source code management library for Smalltalk/X

Copyright (C) 2012-2015 Jan Vrany

This library is free software; you can redistribute it and/or

modify it under the terms of the GNU Lesser General Public

License as published by the Free Software Foundation; either

version 2.1 of the License. 

This library is distributed in the hope that it will be useful,

but WITHOUT ANY WARRANTY; without even the implied warranty of

MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU

Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public

License along with this library; if not, write to the Free Software

Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA

"

"{ Package: 'stx:libscm/mercurial' }"

"{ NameSpace: Smalltalk }"

Object subclass:#HGCommandParser

	instanceVariableNames:'stream command'

	classVariableNames:''

	poolDictionaries:''

	category:'SCM-Mercurial-Internal'

!

!HGCommandParser class methodsFor:'documentation'!

copyright

"

stx:libscm - a new source code management library for Smalltalk/X

Copyright (C) 2012-2015 Jan Vrany

This library is free software; you can redistribute it and/or

modify it under the terms of the GNU Lesser General Public

License as published by the Free Software Foundation; either

version 2.1 of the License. 

This library is distributed in the hope that it will be useful,

but WITHOUT ANY WARRANTY; without even the implied warranty of

MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU

Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public

License along with this library; if not, write to the Free Software

Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA

"

! !

!HGCommandParser class methodsFor:'instance creation'!

for: anHGCommand on: aStringOrStream

    | stream |

    stream := aStringOrStream isStream 

                ifTrue:[aStringOrStream]

                ifFalse:[aStringOrStream readStream].

    ^self new

        command: anHGCommand;

        stream: stream;

        yourself

    "Created: / 04-02-2013 / 13:54:37 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

on: aStringOrStream

    ^self for: nil on: aStringOrStream

    "Created: / 23-10-2012 / 11:07:52 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 04-02-2013 / 13:55:18 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!HGCommandParser class methodsFor:'templates'!

templateHeads

    ^'{rev}:{node}\n'

    "Created: / 27-11-2012 / 21:25:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

templateLog

    ^ '{rev}:{node}\n{branch}\n{p1rev}:{p1node} {p2rev}:{p2node} \n\n{file_adds}\n{file_copies}\n{file_dels}\n{file_mods}\n{author}\n{date|isodate}\n{desc}\n**EOE**\n'

    "Created: / 12-11-2012 / 23:06:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 22-11-2014 / 00:22:42 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

templateLogChildren

    ^ '{rev}:{node}\n{children}\n'

    "Created: / 05-12-2012 / 23:40:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

templateLogForVersionLessThan2_4

    ^ '{rev}:{node}\n{branch}\n{parents}\n\n{file_adds}\n{file_copies}\n{file_dels}\n{file_mods}\n{author}\n{date|isodate}\n{desc}\n**EOE**\n'

    "Created: / 27-11-2014 / 23:20:32 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

templateLogIdsOnly

    ^ '{rev}:{node}\n'

    "Created: / 05-12-2012 / 19:10:28 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!HGCommandParser methodsFor:'accessing'!

command

    ^ command

!

command:anHGCommand

    command := anHGCommand.

!

stream

    ^ stream

!

stream:something

    stream := something.

! !

!HGCommandParser methodsFor:'error reporting'!

error: aString

    <context: #return>

    <resource: #skipInDebuggersWalkBack>

    self propagate: HGCommandParseError message: aString

    "Created: / 14-11-2012 / 19:59:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 04-02-2013 / 21:50:30 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

notify: aString

    <context: #return>

    <resource: #skipInDebuggersWalkBack>

    self propagate: HGNotification message: aString

    "Created: / 04-02-2013 / 13:56:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 04-02-2013 / 21:50:42 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

propagate: anException

    "Propagates given exception to the caller og HGCommand>>execute

     (but only if command is set)"

    command notNil ifTrue:[

        command propagate: anException.

        anException isError ifTrue:[

            Processor activeProcess terminate

        ].

    ] ifFalse:[

        anException raiseSignal

    ].

    "Created: / 04-02-2013 / 21:38:53 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 19-03-2014 / 23:30:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

propagate: class message: message

    "Propagates an exception of given class with given message to

     the caller of HGCommand>>execute"

    ^self propagate: (class newException messageText: message)

    "Created: / 04-02-2013 / 21:50:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

warn: aString

    <context: #return>

    <resource: #skipInDebuggersWalkBack>

    self propagate: HGWarning message: aString

    "Created: / 04-02-2013 / 13:56:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 04-02-2013 / 21:50:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!HGCommandParser methodsFor:'parsing'!

parseBookmarks

    "Parse output of 'hg bookmarks' command. Return collection

     of orphaned HGBookmark"

    | bookmarks |

    bookmarks := OrderedCollection new.

    [ stream atEnd ] whileFalse:[

        bookmarks add: self parseBookmarksEntry

    ].

    ^bookmarks

    "Created: / 20-03-2014 / 01:51:22 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseBookmarksEntry

    | bookmark |

    "Example:

       issue37-update-to-revision 399:858944cebec4

     * master                    403:5cc256ed28a1 

    "

    bookmark := HGBookmark new.

    stream skipSeparators.

    stream peek == $* ifTrue:[

        stream next.

        stream skipSeparators.

    ].

    bookmark setName: self parseName.

    stream skipSeparators.

    bookmark setChangesetId: self parseNodeId.

    self expectLineEnd.

    ^bookmark

    "Created: / 20-03-2014 / 01:52:56 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 20-03-2014 / 17:12:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseBranches

    "Parse output of 'hg branches' command. Return collection

     of orphaned HGBranch"

    | branches branch |

    branches := OrderedCollection new.

    stream atEnd ifFalse:[ 

        branch := self parseBranchesEntryAllowForInvalidBranchheadsMessage: true.

        branch notNil ifTrue:[ 

            branches add: branch.

        ].

    ].

    [ stream atEnd ] whileFalse:[

        branch := self parseBranchesEntryAllowForInvalidBranchheadsMessage: false.  

        branches add:  branch.

    ].

    ^branches

    "Created: / 27-11-2012 / 20:20:56 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 08-10-2014 / 20:56:29 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseBranchesEntryAllowForInvalidBranchheadsMessage: allowForInvalidBrancheadsMessage

    | name branch |

    name := self parseName.

    stream skipSeparators.

    allowForInvalidBrancheadsMessage ifTrue:[ 

        stream peek isDigit ifFalse:[ 

            | message |

            message := name , ' ', stream nextLine.

            self notify: message.  

            name := self parseName.

            stream skipSeparators.   

        ].

    ].                

    branch := HGBranch new.

    branch setName: name.

    self parseNodeId.

    stream peek == Character space ifTrue:[

        stream next.

        stream peek == $( ifFalse:[self error:'''('' expected but ''' , stream peek , ''' found'].

        stream next.

        stream peek == $i ifTrue:[

            self expect:'inactive)'.

            branch setActive: false.

        ] ifFalse:[

            stream peek == $c ifTrue:[

                self expect:'closed)'.

                branch setClosed: true.

            ] ifFalse:[

                self error:'Unexpected branch attribute (only ''closed'' and ''inactive'' supported)'''

            ]

        ].

    ].

    self expectLineEnd.

    ^branch

    "Created: / 08-10-2014 / 20:54:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseConfig

    "Parse output of 'hg showconfig' command, assuming the template given

     was HGCommandParser templateLog. Return a list of HGChangeset."

    | root |

    root := HGConfig::Section new setName: '<root>'.

    [ stream atEnd ] whileFalse:[

        self parseConfigEntryInto: root.

    ].

    ^root

    "Created: / 06-12-2012 / 16:00:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 06-12-2012 / 19:59:04 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseConfigEntryInto: root

    | entry out |

    entry := root.

    out := '' writeStream.

    [ stream atEnd or:[stream peek == $=] ] whileFalse:[

        stream peek == $. ifTrue:[

            entry := entry at: out contents ifAbsentPut: [

                HGConfig::Section new setName: out contents.

            ].

            out reset.

            stream next.

        ] ifFalse:[

            out nextPut: stream next.

        ].

    ].

    stream next.

    entry at: out contents put:

        (HGConfig::Entry new setName: out contents value:stream nextLine)

    "Created: / 06-12-2012 / 19:41:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseDate

    | ts c |

    ts := Timestamp readIso8601FormatFrom:stream.

    c := stream peek.

    c == Character space ifTrue:[ 

        stream next.

        c := stream peek.

    ].

    (c == $+ or:[c == $-]) ifFalse:[

        self error:'Cannot read timezone: ''+'' or ''-'' expected, ''' , c , ''' found'

    ].

    stream next.

    4 timesRepeat:[

        c := stream peek.

        ('0123456789' includes: c) ifFalse:[

            self error:'Cannot read timezone: digit expected, ''' , c , ''' found'

        ].

        stream next.

    ].

    ^ts

    "Created: / 13-11-2012 / 10:22:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 06-11-2014 / 10:44:49 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseInteger

    "Parses integer from stream and returns it"

    ^Integer readFrom: stream onError:[self error: 'integer value expected']

    "

    (HGCommandParser on: '12 34' readStream) parseInteger; skipSeparators; parseInteger

    "

    "Created: / 19-11-2012 / 20:05:28 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseLog

    "Parse output of 'hg log' command, assuming the template given

     was HGCommandParser templateLog. Return a list of HGRevision."

    | revs |

    revs := OrderedCollection new.

    [ stream atEnd ] whileFalse:[

        | rev |

        rev := self parseLogEntry.

        revs add: rev.

    ].

    ^revs.

    "Created: / 13-11-2012 / 09:46:28 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseLogEntry

    "Parse single revision entry, assuming the template given

     was HGCommandParser templateLog. Return a HGRevision."

    | rev branches line message adds copies deletions modifications |

    rev := HGChangeset new.

    rev setId: self parseNodeId. self expectLineEnd.

    branches := self parseNameList. self expectLineEnd.

    rev setBranches: branches.

    rev setParent1Id: self parseNodeId. self expectSpace.

    rev setParent2Id: self parseNodeId. self expectSpace. self expectLineEnd.

    "rev setChildren: self parseNodeIdList." self expectLineEnd.

    adds := self parsePathList. self expectLineEnd.

    copies := self parsePathCopyList. self expectLineEnd.

    deletions := self parsePathList. self expectLineEnd.

    modifications := self parsePathList. self expectLineEnd.

    copies pairsDo:[:dst :src|

        adds remove: dst ifAbsent:[].

        deletions remove: src ifAbsent:[].

    ].

    adds := adds collect:[:e|HGChange newAdded setChangeset: rev path: e].

    copies := copies collect:[:e|HGChange newCopied setChangeset: rev path: e first; setSource: e second].

    deletions := deletions collect:[:e|HGChange newRemoved setChangeset: rev path: e].

    modifications := modifications collect:[:e|HGChange newModified setChangeset: rev path: e].

    rev setChanges: modifications , adds , deletions , copies.

    rev setAuthor: self nextLine.

    rev setTimestamp: self parseDate. self expectLineEnd.

    message := String streamContents:[:s|

        line := self nextLine.

        s nextPutAll: line.

        [ line := self nextLine . line = '**EOE**' ] whileFalse:[

            s cr.

            s nextPutAll: line

        ].

    ].

    rev setMessage: message.

    rev setNonLazy.

    ^rev

    "Created: / 13-11-2012 / 09:45:40 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 19-03-2014 / 23:23:16 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseMergeLocalChanged: info

    "Parses

    local changed lcmake.bat which remote deleted

    use (c)hanged version or (d)elete? c

    " 

    self expect: 'local changed'.

    stream nextLine.

    self expect: 'use'.

    stream nextLine.

    "Created: / 22-03-2013 / 08:59:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseMergePath: info

    "Parses 'merging Make.proto' line" 

    self expect: 'merging '.

    self parsePath.

    self expectLineEnd.

    "Created: / 14-01-2013 / 15:56:22 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseMergeRemoteChanged: info

    "Parses

    remote changed CharacterEncoderImplementations__SJIS.st which local deleted

    use (c)hanged version or leave (d)eleted? c

    " 

    self expect: 'remote changed'.

    stream nextLine.

    self expect: 'use'.

    stream nextLine.

    "Created: / 15-01-2013 / 09:59:39 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseMergeSummary

    ^self parseMergeSummary: HGMergeInfo new

    "Created: / 14-01-2013 / 15:48:14 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parseMergeSummary: info