"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

StandardSystemView subclass:#DebugView

	instanceVariableNames:'busy haveControl exitAction canContinue contextView codeView

		receiverInspector contextInspector contextArray selectedContext

		catchBlock grabber traceView tracing bigStep skipLineNr

		steppedContextAddress canAbort abortButton terminateButton

		continueButton stepButton nextButton sendButton returnButton

		restartButton exclusive inspecting nChainShown inspectedProcess

		updateProcess stopButton updateButton monitorToggle stepping

		steppedContextLineno stepForReturn actualContext inWrap

	classVariableNames:'CachedDebugger CachedExclusive OpenDebuggers MoreDebuggingDetail

		DebuggingDebugger VerboseBacktraceDefault'

	poolDictionaries:''

	category:'Interface-Debugger'

!

!DebugView class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    this class implements a graphical debugger interface.

    The debugger usually sits on top of the faulting process,

    taking over its event processing. Thus only the 'stopped' process is affected;

    other processes continue to respond to events.

    The one exception is when an error occurs within the dispatcher process

    or in one of the eventhandler processes - in this case, the debugger

    will sit on an exclusive display connection.

    The whole debugging will be changed, once the required process primitives

    are available, which allow control of another processes execution

    (i.e. single-step, restart & return). The setup will be changed then,

    to have the debugger control the debuggee (i.e. two processes)

    See additional information in 'doc/misc/debugger.doc'.

    Notice: the DebugView class caches the last used debugger in a class

    variable. It may happen, that a malfunctioning debugger (for example,

    a halfway destoyed one) is kept there. You will notice this, if a

    debugger comes up without showing any contents. In this case, close

    (or destroy) the broken debugView, and execute

        Debugger newDebugger

    which removes the cached debugger and forces creation of a new one the

    next time. This is a temporary workaround - the debugger will be fixed to

    avoid this problem.

    [author:]

        Claus Gittinger

    [see also:]

        Exception Signal

        Process

"

! !

!DebugView class methodsFor:'initialization'!

reinitialize

    self newDebugger

! !

!DebugView class methodsFor:'instance creation'!

enter

    "another way of entering the debugger"

    ^ self enter:(thisContext sender) withMessage:'Debugger'

    "Debugger enter"

!

enter:aContext

    "enter the debugger on aContext"

    ^ self enter:aContext withMessage:'Debugger'

!

enter:aContext withMessage:aString

    "enter a debugger; if this is a recursive invocation, enter

     a MiniDebugger instead.

     This is the standard way of entering the debugger;

     sent from error- and halt messages."

    |active found c|

    StepInterruptPending := nil.

    thisContext isRecursive ifTrue:[

        "/ care for the special case, were the Debugger was autoloaded.

        "/ in this case, thisContext IS recursive, but thats no error

        "/ condition.

        found := false.

        c := thisContext sender.

        [found not

         and:[c notNil 

         and:[c selector ~~ #enter:withMessage:]]] whileTrue:[

            c selector == #noByteCode ifTrue:[

                found := true

            ].

            c := c sender

        ].

        found ifFalse:[

            ('DebugView [warning]: reentered with: ', aString) errorPrintCR.

            ^ MiniDebugger enterWithMessage:'DEBUGGER: recursive error'.

        ]

    ].

    "

     well, it could be a stepping or sending debugger up there;

     in this case, return to it. This happens, when a stepping process

     runs into an error (for example, a halt). In this case, we want the

     stepping debugger to come up again instead of a new one.

    "

    OpenDebuggers notNil ifTrue:[

        active := Processor activeProcess.

        OpenDebuggers do:[:aDebugger |

            (aDebugger notNil and:[aDebugger ~~ 0]) ifTrue:[

                (aDebugger inspectedProcess == active) ifTrue:[

"/ 'entering stepping debugger again' printNL.

                    aDebugger unstep.

                    aDebugger setLabelFor:aString in:active.

                    ^ aDebugger enter:aContext.

                ]

            ]

        ]

    ].

    ^ self enterUnconditional:aContext withMessage:aString

    "Modified: 10.1.1997 / 17:35:34 / cg"

!

enterUnconditional:aContext withMessage:aString

    "enter a debugger - do not check for recursive invocation"

    |aDebugger|

    StepInterruptPending := nil.

    aDebugger := self new.

    aDebugger setLabelFor:aString in:Processor activeProcess.

    aDebugger enter:aContext.

    ^ nil

    "nil halt"

!

enterWithMessage:aString

    "the standard way of entering the debugger - sent from Objects

     error- and halt messages"

    ^ self enter:(thisContext sender) withMessage:aString

    "Debugger enterWithMessage:'hi there'"

!

new

    "return a new DebugView - return a cached debugger if it already

     exists"

    |debugger|

    "

     need a blocking debugger if no processes or 

     or if its a timing/interrupt process 

     (because otherwise we would not get any events here ...

    "

    Processor activeProcessIsSystemProcess ifTrue:[

        CachedExclusive isNil ifTrue:[

            debugger := self newExclusive

        ] ifFalse:[

            debugger := CachedExclusive.

            CachedExclusive := nil.

        ].

    ] ifFalse:[

        CachedDebugger isNil ifTrue:[

            debugger := super new.

            debugger label:'Debugger'.

            debugger icon:self defaultIcon.

        ] ifFalse:[

            debugger := CachedDebugger.

            CachedDebugger := nil.

        ]

    ].

    ^ debugger

    "Modified: 1.1.1970 / 01:00:00 / cg"

!

newExclusive

    "return a debugger for exclusive display access"

    |debugger|

    debugger := super new.

    debugger label:'Debugger'.

    debugger icon:self defaultIcon.

    debugger exclusive:true.

    ^ debugger

    "Modified: 1.1.1970 / 23:27:06 / cg"

!

openOn:aProcess

    "start a  debugger on aProcess

     (actually not more than a good-looking inspector)"

    |aDebugger label nm|

    aDebugger := super new.

    aDebugger icon:self defaultIcon.

    aProcess notNil ifTrue:[

        nm := aProcess name.

        nm notNil ifTrue:[

            nm := (nm contractTo:17) , '-' , aProcess id printString

        ] ifFalse:[

            nm := aProcess id printString

        ].

        label := 'Debugger [' , nm , ']'.

    ] ifFalse:[

        label := 'no process'

    ].

    aDebugger label:label.

    aDebugger iconLabel:'Debugger'.

    aDebugger openOn:aProcess.

    ^ nil

    "Modified: 19.12.1996 / 14:07:50 / cg"

! !

!DebugView class methodsFor:'cleanup'!

lowSpaceCleanup 

    "in low memory situations, give up cached debuggers"

    CachedDebugger := nil.

    CachedExclusive := nil.

    OpenDebuggers := nil.

    "

     DebugView lowSpaceCleanup

    "

    "Modified: 18.4.1996 / 16:48:03 / cg"

!

newDebugger

    "force creation of a new debugger"

    CachedDebugger := nil.

    CachedExclusive := nil.

    OpenDebuggers := nil.

    "

     DebugView newDebugger

    "

! !

!DebugView class methodsFor:'defaults'!

defaultIcon

    ^ Image fromFile:'bitmaps/Debugger.xbm' resolution:100

    "Created: 1.1.1970 / 01:00:00 / cg"

!

defaultVerboseBacktrace

    ^ VerboseBacktraceDefault

    "Created: 11.1.1997 / 12:14:35 / cg"

!

defaultVerboseBacktrace:aBoolean

    VerboseBacktraceDefault := aBoolean

    "Created: 11.1.1997 / 12:14:44 / cg"

! !

!DebugView class methodsFor:'misc'!

interestingContextFrom:aContext

    "return an interesting contexts offset, or nil.

     This is the context initially shown in the walkback.

     We move up the calling chain, skipping all intermediate Signal

     and Exception contexts, to present the context in which the error

     actually occured.

     Just for your convenience :-)"

    |delta con|

    delta := self interestingContextIndexFrom:aContext.

    con := aContext.

    [delta > 1] whileTrue:[

        con := con sender.

        delta := delta - 1.

    ].

    ^ con

    "Modified: 7.1.1997 / 21:31:05 / cg"

!

interestingContextIndexFrom:aContext

    "return an interesting contexts offset, or nil.

     This is the context initially shown in the walkback.

     We move up the calling chain, skipping all intermediate Signal

     and Exception contexts, to present the context in which the error

     actually occured.

     Just for your convenience :-)"

    |c found offset sel prev ex|

    aContext isBlockContext ifTrue:[^ 1].

    "somewhere, at the bottom, there must be a raise ..."

    c := aContext.

    1 to:5 do:[:i |

        c isNil ifTrue:[^ 1 "^ nil"].

        sel := c selector.

        ((sel == #raise) 

        or:[sel == #raiseRequest]) ifTrue:[

            (c receiver isKindOf:Exception) ifTrue:[

                ex := c receiver.

                offset := i.

                found := c

            ] ifFalse:[

                (c receiver isSignal) ifTrue:[

                    offset := i.

                    found := c

                ]

            ]

        ].

        c := c sender.

    ].

    "

     if this is a noHandler exception, skip forward

     to the erronous context

    "

    ex notNil ifTrue:[

        ex signal == Signal noHandlerSignal ifTrue:[

            c := ex suspendedContext

        ]

    ].

    (c := found) isNil ifTrue:[

        "/ this is a kludge, but convenient.

        "/ show the place where the divisionByZero happend,

        "/ not where the signal was raised.

        sel := aContext selector.

        (sel == #//      

        or:[sel == #/

        or:[sel == #\\]]) ifTrue:[

            ^ 2

        ].

        ^ 1

    ].

    "

     got it; move up, skipping all intermediate Signal and

     Exception contexts

    "

    prev := nil.

    [   

        ((c receiver isSignal)

        or:[(c receiver isKindOf:Exception)])

    ] whileTrue:[

        prev := c.

        (c := c sender) isNil ifTrue:[^ offset].

        offset := offset + 1.

    ].

    "

     now, we are one above the raising context

    "

    "

     if the sender-method of the raise is one of objects error methods ...

    "

    ( #( halt halt: 

         error error: 

         doesNotUnderstand: 

         subclassResponsibility 

         primitiveFailed) includes:c selector) 

    ifTrue:[

        c selector == #doesNotUnderstand: ifTrue:[

            "

             one more up, to get to the originating context

            "

            (c := c sender) isNil ifTrue:[^ offset].

            offset := offset + 1.

        ].

        (c := c sender) isNil ifTrue:[^ offset].

        offset := offset + 1.

    ] ifFalse:[

        "

         ok, got the raise - if its a BreakPoint, look for the sender

        "

        (MessageTracer notNil and:[prev receiver == MessageTracer breakpointSignal]) ifTrue:[

            offset := offset + 1

        ].

    ].

    ^ offset

    "Created: 7.1.1997 / 21:26:05 / cg"

    "Modified: 8.1.1997 / 17:39:15 / cg"

! !

!DebugView methodsFor:'basic'!

enter

    "enter the debugger - on the sending context"

    |where|

    busy := true.

    where := thisContext.      "enter"

    where := where sender.     "the calling context"

    where notNil ifTrue:[

	(where receiver == DebugView) ifTrue:[

	    where := where sender

	]

	"where is now interrupted methods context"

    ].

    ^ self enter:where

!

enter:aContext

    "enter the debugger - get and display the context, then start an

     exclusive event loop on top of eveything else"

    |con selection m idx retval enteredByInterrupt sel|

    busy := true.

    inspecting := false.

    inspectedProcess := Processor activeProcess.

    stepping := false.

    bigStep := false.

    nChainShown := 50.

    "if debugger is entered while a box has grabbed the

     pointer, we must ungrab - otherwise X wont talk to

     us here

    "

    (grabber := device activePointerGrab) notNil ifTrue:[

        device ungrabPointer.

        device ungrabKeyboard.

    ].

    (inspectedProcess suspendedContext isNil 

    or:[Processor isSystemProcess:inspectedProcess]) ifTrue:[

        terminateButton disable.

    ] ifFalse:[

        terminateButton enable.

        abortButton enable.

    ].