"

 COPYRIGHT (c) 2010 by Jan Vrany, SWING Research Group. CTU in Prague

              All Rights Reserved

Permission is hereby granted, free of charge, to any person

obtaining a copy of this software and associated documentation

files (the 'Software'), to deal in the Software without

restriction, including without limitation the rights to use,

copy, modify, merge, publish, distribute, sublicense, and/or sell

copies of the Software, and to permit persons to whom the

Software is furnished to do so, subject to the following

conditions:

The above copyright notice and this permission notice shall be

included in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND,

EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES

OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND

NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT

HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,

WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING

FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR

OTHER DEALINGS IN THE SOFTWARE.

"

"{ Package: 'stx:libtool' }"

SyntaxHighlighter subclass:#SyntaxHighlighter2

	instanceVariableNames:'elements lastVariableElements lastSelectorElement'

	classVariableNames:''

	poolDictionaries:''

	category:'Interface-CodeView-Syntax'

!

!SyntaxHighlighter2 class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2010 by Jan Vrany, SWING Research Group. CTU in Prague

              All Rights Reserved

Permission is hereby granted, free of charge, to any person

obtaining a copy of this software and associated documentation

files (the 'Software'), to deal in the Software without

restriction, including without limitation the rights to use,

copy, modify, merge, publish, distribute, sublicense, and/or sell

copies of the Software, and to permit persons to whom the

Software is furnished to do so, subject to the following

conditions:

The above copyright notice and this permission notice shall be

included in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND,

EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES

OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND

NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT

HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,

WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING

FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR

OTHER DEALINGS IN THE SOFTWARE.

"

! !

!SyntaxHighlighter2 class methodsFor:'highlighting'!

format:aString parsingWith:aBlock in:aClass elementsInto:elements

    "common code for formatStatementList, formatExpression, ...

     format (recolor) whatever is parsed in aBlock (within the context of a given class).

     Return the text containing font changes and color information.

     As a side effect, put syntax elements into the passed in elements container

     (for element-highlighting in codeView2)"

    |parser tree text endPos|

    aString isNil ifTrue:[^ nil].

    parser := self for:(ReadStream on:aString string) in:aClass.

    parser elements: elements.

    parser ignoreErrors:true.

    parser ignoreWarnings:true.

    parser sourceText:(text := aString string asText).

    "/ use an array here - this can be changed much faster using #at:put:

    text emphasisCollection:(Array new:aString size).

    parser nextToken.

    tree := aBlock value:parser.

    "/ now, convert the emphasis-array to a runArray

    text emphasisCollection:(text emphasis asRunArray).

    tree == #Error ifTrue:[

        "/ mhmh - which is better ...

        "/ alternative1: color rest after error in red

"/        text 

"/            emphasizeFrom:(parser sourceStream position) 

"/            to:text size 

"/            with:(#color->Color red).

        "/ alternative2: take original emphasis for rest

        endPos := parser sourceStream position1Based.

        endPos >= text size ifTrue:[

            ^ text

        ].

        ^ ((text copyTo:endPos) , (aString copyFrom:(endPos+1))).

        "/ alternative3: no emphasis for rest.

"/        ^ text "/ aString

    ].

    ^ text

    "

     self

        formatStatementList:'(1 + 2) max:5. 1 + 2' 

        in:UndefinedObject

        elementsInto:(OrderedCollection new).

    "

!

formatClassDefinition:aString in:aClass elementsInto: elements

    "format (recolor) a class definition expression in a given class.

     Return the text containing font changes and color information."

    ^ self formatExpression:aString in:aClass elementsInto: elements

    "Created: / 10-04-2011 / 18:18:00 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

formatExpression:aString in:aClass elementsInto: elements

    "format (recolor) an expression in a given class.

     Return the text containing font changes and color information."

    ^ self 

        format:aString parsingWith:[:parser | parser expression]

        in:aClass elementsInto:elements

    "

     self

        formatExpression:'(1 + 2) max:5' 

        in:UndefinedObject

        elementsInto:(OrderedCollection new)

    "

!

formatMethod:aString in:aClass using:preferencesOrNil elementsInto: elements

    "format (recolor) a method in a given class.

     Return the text containing font changes and color information."

    "/ obsolete interface

    ^ self

        formatMethod:nil

        source:aString

        in:aClass

        using:preferencesOrNil elementsInto:elements

    "Created: / 25-07-2010 / 08:56:29 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 05-07-2011 / 11:07:50 / cg"

!

formatMethod:aMethodOrNil source:aString in:aClass using:preferencesOrNil elementsInto: elements

    "format (recolor) a method in a given class.

     Return the text containing font changes and color information."

    |highlighter tree text endPos eColor|

    aString isNil ifTrue:[^ nil].

    Error handle:[:ex |

        ex creator isHandled ifTrue:[

            ex reject.    

        ].

        (self parseErrorSignal handles:ex) ifFalse:[

            "Parse error may happen when re-formatting incomplete code while editing"

            ('SyntaxHighlighter [info]: error during highlight: ' , ex description) infoPrintCR.

            "/ ex suspendedContext fullPrintAll.

        ].

        ^ aString

    ] do:[

        highlighter := self for:(ReadStream on:aString string) in:aClass.

        highlighter elements: elements.

        preferencesOrNil notNil ifTrue:[highlighter preferences:preferencesOrNil].

        "/ highlighter ignoreErrors:true.

        highlighter ignoreWarnings:true.

        highlighter sourceText:(text := aString string asText).

        "/ use an array here - this can be changed much faster using #at:put:

        text emphasisCollection:(Array new:aString size).

        tree := highlighter parseMethod.

        "/ now, convert the emphasis-array to a runArray

        text emphasisCollection:(text emphasis asRunArray).

        tree == #Error ifTrue:[

            eColor := UserPreferences current errorColor.

            eColor notNil ifTrue:[

                "/ mhmh - which is better ...

                "/ alternative1: color rest after error in red

                text 

                    emphasizeFrom:(highlighter sourceStream position1Based) 

                    to:text size 

                    with:(#color->eColor).

            ] ifFalse:[

                "/ alternative2: take original emphasis for rest

                endPos := highlighter sourceStream position1Based.

                endPos >= text size ifTrue:[

                    ^ Array with: text with: highlighter elements

                ].

                ^ ((text copyTo:endPos) , (aString copyFrom:(endPos+1)))

            ].

            "/ alternative3: no emphasis for rest.

        ].

        ^text 

    ]

    "

     self

        formatMethod:'foo 

    ^ self bar:''hello''.

    ' , (Character doubleQuote asString) , 'some comment' , (Character doubleQuote asString) , '

'

        in:UndefinedObject

    "

    "Modified: / 22-08-2006 / 13:32:04 / cg"

    "Created: / 05-07-2011 / 10:39:21 / cg"

!

formatStatementList:aString in:aClass elementsInto: elements

    "format (recolor) a statement list in a given class.

     Return the text containing font changes and color information."

    ^ self 

        format:aString parsingWith:[:parser | parser statementList]

        in:aClass elementsInto:elements

    "

     self

        formatStatementList:'(1 + 2) max:5. 1 + 2' 

        in:UndefinedObject

        elementsInto:(OrderedCollection new).

    "

! !

!SyntaxHighlighter2 methodsFor:'accessing'!

elements

    ^ elements

!

elements:something

    "the element collection, to collect variables, selectors etc. into"

    elements := something.

    "Modified (comment): / 21-08-2011 / 09:13:31 / cg"

! !

!SyntaxHighlighter2 methodsFor:'initialization'!

initialize

    super initialize.

    elements := SortedCollection new.

    lastVariableElements := Dictionary new.

    "Created: / 14-02-2010 / 13:08:27 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 25-06-2010 / 13:04:37 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 21-08-2011 / 09:37:35 / cg"

! !

!SyntaxHighlighter2 methodsFor:'parsing-expressions'!

binaryExpressionFor:receiverArg

    "parse a binary-expression; return a node-tree, nil or #Error"

    |receiver expr arg sel pos1 pos2 lno|

    receiver := receiverArg.

    (receiver == #Error) ifTrue:[^ #Error].

    "special kludge: since Scanner cannot know if -digit is a binary

     expression or a negative constant, handle cases here"

    [(tokenType == #BinaryOperator) 

     or:[(tokenType == $|)

     or:[(tokenType == $^ and:[parserFlags allowCaretAsBinop])

         or:[((tokenType == #Integer) or:[tokenType == #Float])

             and:[tokenValue < 0]]]]

    ] whileTrue:[

        "/ kludge alarm: in a function-call argList, #, is not a binarySelector

        inFunctionCallArgument == true ifTrue:[

            ((tokenType == #BinaryOperator) and:[tokenName = ',']) ifTrue:[

                ^ receiver

            ].

        ].

        pos1 := tokenPosition.

        lno := tokenLineNr.

        "/ kludge alarm: bar, caret and minus are not scanned as binop

        (tokenType == $|) ifTrue:[

            sel := '|'.

            sel := self selectorCheck:sel for:receiver position:tokenPosition to:tokenPosition.

            self nextToken.

        ] ifFalse:[

            (tokenType == $^) ifTrue:[

                sel := '^'.

                sel := self selectorCheck:sel for:receiver position:tokenPosition to:tokenPosition.

                self nextToken.

            ] ifFalse:[

                (tokenType == #BinaryOperator) ifTrue:[

                    sel := tokenName.

                    sel := self selectorCheck:sel for:receiver position:tokenPosition to:(tokenPosition + tokenName size - 1).

                    self nextToken

                ] ifFalse:[

                    sel := '-'.

                    token := tokenValue := tokenValue negated.

                    tokenPosition := tokenPosition + 1. "/ to skip the sign

                ]

            ].

        ].

        pos2 := pos1 + sel size - 1.

        self markSelector:sel from:pos1 to:pos2 receiverNode:receiver.

        lastSelectorElement := nil.

        arg := self unaryExpression.

        (arg == #Error) ifTrue:[^ #Error].

        expr := BinaryNode receiver:receiver selector:sel arg:arg fold:foldConstants.

        expr isErrorNode ifTrue:[

            self parseError:(expr errorString) position:pos1 to:tokenPosition.

            errorFlag := false. "ok, user wants it - so he'll get it"

            expr := BinaryNode receiver:receiver selector:sel arg:arg fold:nil.

        ].

        expr lineNumber:lno.

        expr selectorPosition:pos1.

        self checkPlausibilityOf:expr from:pos1 to:pos2.

        receiver := expr.   "/ for next message

    ].

    ^ receiver

    "Modified: / 09-01-1998 / 19:05:18 / stefan"

    "Modified: / 14-02-2010 / 17:54:53 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 19-01-2012 / 10:46:49 / cg"

!

expression

    "parse a cascade-expression; return a node-tree, nil or #Error.

     expression ::= keywordExpression

                    | keywordExpression cascade

     cascade ::= ';' expressionSendPart

                 | cascade ';' expressionSendPart

     expressionSendPart ::= { KEYWORD binaryExpression }

                            | BINARYOPERATOR unaryExpression

                            | IDENTIFIER

    "

    |receiver arg sel args pos pos2 lno tokenEnd realReceiver positions|

    pos := tokenPosition.

    receiver := self keywordExpression.

    (receiver == #Error) ifTrue:[^ #Error].

    (tokenType == $;) ifTrue:[

        receiver isMessage ifFalse:[

            self syntaxError:'left side of cascade must be a message expression'

                    position:pos to:tokenPosition.

            realReceiver := receiver. "/ only to allow continuing.

        ] ifTrue:[

            realReceiver := receiver receiver.

        ].

        [tokenType == $;] whileTrue:[

            self nextToken.

            (tokenType == #Identifier) ifTrue:[

                tokenEnd := tokenPosition + tokenName size - 1.

                self markSelector:tokenName from:tokenPosition to:tokenEnd receiverNode:realReceiver.

                sel := tokenName.

                sel := self selectorCheck:tokenName for:realReceiver position:tokenPosition to:tokenEnd.

                receiver := CascadeNode receiver:receiver selector:sel.

                receiver lineNumber:tokenLineNr.

                self nextToken.

            ] ifFalse:[

                (tokenType == #BinaryOperator) ifTrue:[

                    tokenEnd := tokenPosition + tokenName size - 1.

                    self markSelector:tokenName from:tokenPosition to:tokenEnd receiverNode:realReceiver.

                    lastSelectorElement := nil.

                    sel := tokenName.

                    sel := self selectorCheck:tokenName for:realReceiver position:tokenPosition to:tokenEnd.

                    lno := tokenLineNr. 

                    self nextToken.

                    arg := self unaryExpression.

                    (arg == #Error) ifTrue:[^ #Error].

                    receiver := CascadeNode receiver:receiver selector:sel arg:arg.

                    receiver lineNumber:lno.

                ] ifFalse:[

                    (tokenType == #Keyword) ifTrue:[

                        tokenEnd := tokenPosition + tokenName size - 1.

                        positions := OrderedCollection with:(tokenPosition to:tokenEnd).

                        pos := tokenPosition.

                        pos2 := tokenEnd.

                        lno := tokenLineNr. 

                        sel := tokenName.

                        self nextToken.

                        arg := self binaryExpression.

                        (arg == #Error) ifTrue:[^ #Error].

                        args := Array with:arg.

                        [tokenType == #Keyword] whileTrue:[

                            tokenEnd := tokenPosition + tokenName size - 1.

                            positions add:(tokenPosition to:tokenEnd).

                            sel := sel , tokenName.

                            self nextToken.

                            arg := self binaryExpression.

                            (arg == #Error) ifTrue:[^ #Error].

                            args := args copyWith:arg.

                            pos2 := tokenEnd

                        ].

                        positions do:[:p |

                            self markSelector:sel from:p start to:p stop receiverNode:realReceiver.

                        ].

                        lastSelectorElement := nil.                                

                        sel := self selectorCheck:sel for:realReceiver position:pos to:pos2.

                        receiver := CascadeNode receiver:receiver selector:sel args:args.

                        receiver lineNumber:lno.

                    ] ifFalse:[

                        (tokenType == #Error) ifTrue:[^ #Error].

                        self syntaxError:('invalid cascade; ' , tokenType printString , ' unexpected')

                                position:tokenPosition to:source position1Based - 1.

                        ^ #Error

                    ]

                ]

            ]

        ].

        "obscure (unspecified ?) if selector follows; Question:

        is

                'expr sel1; sel2 sel3'

        to be parsed as: 

                (t := expr.

                 t sel1.

                 t sel2) sel3

         or:

                (t := expr.

                 t sel1.

                 t sel2 sel3)

        "

        ((tokenType == #Identifier) 

         or:[(tokenType == #BinaryOperator)

             or:[tokenType == #Keyword]]) ifTrue:[

            self syntaxError:'ambigous cascade - please group using (...)'

                    position:tokenPosition to:source position1Based - 1.

            ^ #Error

"/            self warning: "syntaxError:" 'possibly ambigous cascade - please group using (...)'

"/                    position:tokenPosition to:source position - 1.

"/            tokenType == #Identifier ifTrue:[

"/                ^ self unaryExpressionFor:receiver

"/            ].

"/            tokenType == #BinaryOperator ifTrue:[

"/                ^ self binaryExpressionFor:receiver

"/            ].

"/            ^ self keywordExpressionFor:receiver

        ]

    ].

    ^ receiver

    "Modified: / 19-01-2000 / 16:22:16 / cg"

    "Modified: / 14-02-2010 / 17:58:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

keywordExpressionFor:receiverArg

    "parse a keyword-expression; return a node-tree, nil or #Error.

     keywordExpression ::= binaryexpression

                           | { KEYWORD-PART binaryExpression }

    "

    |expr receiver sel arg args posR1 posR2 pos1 pos2 lno positions constVal|

    receiver := receiverArg.

    posR1 := tokenPosition.

    (tokenType == #Keyword) ifFalse:[^ receiver].

    pos1 := posR2 := tokenPosition.

    pos2 := tokenPosition + tokenName size - 1.

    positions := OrderedCollection with:(pos1 to:pos2).

    sel := tokenName.

    lno := tokenLineNr.

    self nextToken.

    arg := self binaryExpression.

    (arg == #Error) ifTrue:[^ #Error].

    args := Array with:arg.

    [tokenType == #Keyword] whileTrue:[

        sel := sel , tokenName.

        pos2 := tokenPosition + tokenName size - 1.

        positions add:(tokenPosition to:pos2).

        self nextToken.

        arg := self binaryExpression.

        (arg == #Error) ifTrue:[^ #Error].

        args := args copyWith:arg.

    ].

    positions do:[:p |

        self markSelector:sel from:p start to:p stop receiverNode:receiver.

    ].

    lastSelectorElement := nil.

    sel := self selectorCheck:sel for:receiver positions:positions.