"

 COPYRIGHT (c) 2010 by Jan Vrany, SWING Research Group. CTU in Prague

	      All Rights Reserved

Permission is hereby granted, free of charge, to any person

obtaining a copy of this software and associated documentation

files (the 'Software'), to deal in the Software without

restriction, including without limitation the rights to use,

copy, modify, merge, publish, distribute, sublicense, and/or sell

copies of the Software, and to permit persons to whom the

Software is furnished to do so, subject to the following

conditions:

The above copyright notice and this permission notice shall be

included in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND,

EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES

OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND

NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT

HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,

WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING

FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR

OTHER DEALINGS IN THE SOFTWARE.

"

"{ Package: 'stx:libtool' }"

"{ NameSpace: Tools }"

CodeViewService subclass:#BreakpointService

	instanceVariableNames:'breakpoints currentMethod currentMethodClass methodHolder'

	classVariableNames:''

	poolDictionaries:''

	category:'Interface-CodeView'

!

!BreakpointService class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2010 by Jan Vrany, SWING Research Group. CTU in Prague

	      All Rights Reserved

Permission is hereby granted, free of charge, to any person

obtaining a copy of this software and associated documentation

files (the 'Software'), to deal in the Software without

restriction, including without limitation the rights to use,

copy, modify, merge, publish, distribute, sublicense, and/or sell

copies of the Software, and to permit persons to whom the

Software is furnished to do so, subject to the following

conditions:

The above copyright notice and this permission notice shall be

included in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND,

EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES

OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND

NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT

HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,

WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING

FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR

OTHER DEALINGS IN THE SOFTWARE.

"

! !

!BreakpointService class methodsFor:'accessing'!

label

    "Answers a short label - for UI"

    ^ 'Breakpoints'

! !

!BreakpointService class methodsFor:'testing'!

isUsefulFor:aCodeView

    "this filters useful services.

     Redefined to return true for myself - not for subclasses"

    ^ self == Tools::BreakpointService

    "Created: / 22-07-2013 / 14:01:17 / cg"

! !

!BreakpointService methodsFor:'accessing'!

breakpoints

    ^ breakpoints

! !

!BreakpointService methodsFor:'change & update'!

update: aspect with: param from: sender

    aspect == #visibility ifTrue:[^ self].

    aspect == #sizeOfView ifTrue:[^ self].

    aspect == #classHolder ifTrue:[^ self].

    aspect == #languageHolder ifTrue:[^ self].

    sender == codeView modifiedChannel ifTrue:[^ self].

    "/ ATTENTION: I thought that fetching the methodHolder once in initialize would

    "/ be ok. However, it seems not (codeView gives me something which it does not use/change later).

    "/ so this fetch is called in update as well.

    "/ maybe s.o. (ie. Jan) fixes CodeView2

    (aspect == #methodHolder or:[sender == self fetchMethodHolder]) ifTrue:[

        self updateCurrentMethod.

    ].

    super update: aspect with: param from: sender

    "Created: / 06-07-2011 / 15:21:08 / cg"

!

updateBreakPointsFor:aMethod

    |methodsBreakPoints|

    "/ Transcript show:'update breakpoints for method: '; showCR:aMethod.

    aMethod notNil ifTrue:[

        aMethod literalsDo:[:eachLiteral |

            (eachLiteral isKindOf:Breakpoint) ifTrue:[

                methodsBreakPoints isNil ifTrue:[

                    methodsBreakPoints := OrderedCollection new.

                ].

                methodsBreakPoints add:eachLiteral copy.

            ].

        ].

        currentMethodClass := aMethod mclass.

    ] ifFalse:[

        currentMethodClass := nil

    ].

    breakpoints := methodsBreakPoints.

    currentMethod := aMethod.

    "Created: / 06-07-2011 / 15:24:09 / cg"

    "Modified: / 06-07-2011 / 17:32:54 / jv"

!

updateCurrentMethod

    |method realMethod oldBreakPoints|

    "/ codeView methodHolder class == BlockValue ifTrue:[self breakPoint:#cg].

    method := realMethod := codeView method.

    (method notNil and:[method mclass isNil]) ifTrue:[

        "/ hack: ouch - was wrapped in the meantime;

        "/ hurry up and update. Should be done elsewhere (in codeView)

        realMethod := MethodWithBreakpoints allInstances detect:[:m | m originalMethod == method and:[m mclass notNil]] ifNone:nil.

        realMethod isNil ifTrue:[

            realMethod := WrappedMethod allInstances detect:[:m | m originalMethod == method and:[m mclass notNil]] ifNone:nil.

        ].

    ].

    realMethod ~~ currentMethod ifTrue:[

        "/ self fetchMethodHolder setValue:realMethod.

        oldBreakPoints := breakpoints.

        self updateBreakPointsFor:realMethod.

        oldBreakPoints ~= breakpoints ifTrue:[

            gutterView invalidate.

        ]

    ].

    "Modified: / 22-07-2013 / 13:33:28 / cg"

! !

!BreakpointService methodsFor:'event handling'!

buttonPress:button x:x y:y in:view

    |lineNr|

    view == gutterView ifTrue:[

        button == 1 ifTrue:[

            lineNr := textView yVisibleToLineNr:y.

            lineNr notNil ifTrue:[ self setOrToggleBreakpointAtLine:lineNr ].

            ^ true.

        ].

        button == 3 ifTrue:[

            ^ true.

        ]

    ].

    ^ false

    "Created: / 17-06-2011 / 13:05:22 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 28-06-2011 / 08:31:39 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 19-09-2011 / 14:41:00 / cg"

!

linesDeletedFrom: start to: end

    breakpoints isEmptyOrNil ifTrue:[^self].

    self moveBreakpointsAfterLine: start - 1 by: (end - start + 1) negated

    "Created: / 06-07-2011 / 17:16:27 / jv"

!

linesInsertedFrom: start to: end

    breakpoints isEmptyOrNil ifTrue:[^self].

    self moveBreakpointsAfterLine: start - 1 by: (end - start + 1)

    "Created: / 06-07-2011 / 17:16:36 / jv"

! !

!BreakpointService methodsFor:'help'!

flyByHelpText

    |topView|

    (self canCreateOrToggleBreakpointAtLine:nil) ifFalse:[

        ((topView := codeView topView) class == DebugView) ifTrue:[

            self hasBreakpoints ifFalse:[

                ^ 'Sorry - cannot add breakpoint in the debugger (would need recompilation)\(can only add breakpoints if stopped at a method breakpoint)' withCRs

            ].

            ^ 'Sorry - cannot add new breakpoint if method is already entered\(i.e. if not stopped at a breakpoint).' withCRs

        ].

        ^ 'Cannot add breakpoint when modified. Please accept first.'

    ].

    ^ 'Click to toggle breakpoint. Shift-Click to toggle tracepoint.'

    "Created: / 27-01-2012 / 14:04:52 / cg"

! !

!BreakpointService methodsFor:'initialization'!

fetchMethodHolder

    "redefinable in subclasses, which do not have a codeView2/methodHolder"

    "/ ATTENTION: I thought that fetching the methodHolder once in initialize would

    "/ be ok. However, it seems not (codeView gives me something which it does not use/change later).

    "/ so this fetch is called in update as well.

    "/ maybe s.o. (ie. Jan) fixes CodeView2

    methodHolder := codeView methodHolder.

    ^ methodHolder

!

initialize

    super initialize.

    breakpoints := OrderedCollection new.

    "Created: / 17-06-2011 / 13:49:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!BreakpointService methodsFor:'private'!

breakpointAtLine:line

    |pos|

    breakpoints isNil ifTrue:[^ nil].

    pos := textView characterPositionOfLine:line col:1.

    ^ breakpoints 

        detect:[:each | each position = pos ] 

        ifNone:[ 

            breakpoints 

                detect:[:each | each line == line and:[each position isNil ]] 

                ifNone:[ nil ]

        ]

    "Modified: / 17-06-2011 / 13:59:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (format): / 05-07-2011 / 21:33:23 / cg"

!

moveBreakpointsAfterLine:line by: delta

    |pos |

    breakpoints do:[:bpnt|

        bpnt line >= line ifTrue:[

            pos := textView characterPositionOfLine:bpnt line + delta col:1.

            bpnt position:pos line:(bpnt line + delta). 

        ]

    ].

    "/gutterView redrawLinesFrom: line.

    "Created: / 17-06-2011 / 13:45:22 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Created: / 06-07-2011 / 17:26:30 / jv"

    "Modified: / 02-08-2012 / 09:27:10 / cg"

!

recompile

    "recompile the current method for changed breakpoints"

    |oldMethod newMethod compilerClass compiler class selector|

    oldMethod := codeView method.

    (oldMethod notNil and:[oldMethod hasPrimitiveCode not]) ifTrue:[

        "/ be careful: if the text has been edited/modified, do not compile

        textView modified ifTrue:[

            self breakPoint: #cg.

            self breakPoint: #jv.

            ^self.

        ] ifFalse:[

            "/ prepare to get reachable bpts

            breakpoints do:[:bp | bp isReached:false].

            class := oldMethod mclass.

            class isNil ifTrue:[

                class := codeView classHolder value.

                class isNil ifTrue:[

                    self breakPoint:#jv.

                    Dialog warn:'oops - lost the methods''s class'.

                    ^ self.

                ]

            ].

            selector := oldMethod selector.

            Class withoutUpdatingChangesDo:[

                "/ compilerClass := ByteCodeCompilerWithBreakpointSupport.

                compilerClass := oldMethod programmingLanguage compilerWithBreakpointSupportClass.

                compilerClass isNil ifTrue:[

                    Dialog warn:'No breakpoint support for this programming language'.

                    ^ self.

                ].

                compiler := compilerClass new.

                compiler breakpoints:breakpoints.

"/ not needed - new compilers already know it

"/                compiler methodClass:(oldMethod programmingLanguage isSTXJavaScript 

"/                                            ifTrue:[JavaScriptFunctionWithBreakpoints]

"/                                            ifFalse:[MethodWithBreakpoints]).

                newMethod := compiler

                            compile:oldMethod source

                            forClass:class

                            inCategory:oldMethod category

                            notifying:nil

                            install:false

                            skipIfSame:false

                            silent:true

                            foldConstants:true

                            ifFail:[ Transcript showCR:'BreakpointService: failed to recompile for breakpoint' ].

                selector isNil ifTrue:[

                    "/ May happen as the selector is not stored in the method but

                    "/ searches through method's mclass methodDictionary.

                    "/ Following should be save as breakpoint is not installed when

                    "/ the code is modified...

                    selector := compiler selector.

                ].

                oldMethod isWrapped ifTrue:[

                    "/ update the wrapped method - do not install

                    newMethod originalMethod: oldMethod originalMethod.

                    oldMethod replaceOriginalMethodWith:newMethod.

                ] ifFalse:[

                    "/ install

                    newMethod originalMethod: oldMethod.

                    (class primAddSelector: selector withMethod:newMethod) ifFalse:[

                        oldMethod mclass:class.

                        self breakPoint: #cg.

                        self breakPoint: #jv.

                        ^ self

                    ].

                ].

                breakpoints := breakpoints

                                select:[:bp |

"/                                    bp isReached ifFalse:[ 

"/                                        "/ Transcript show:'remove unreached:'; showCR:bp 

"/                                    ].

                                    bp isReached

                                ].

                "/ must update breakpoints BEFORE the following, because it leads to a change

                "/ notification, which may clear the breakpoints collection!!

                self fetchMethodHolder value:newMethod.

                oldMethod mclass isNil ifTrue:[

                    "/ although this is not strictly true, not doing this

                    "/ would confuse a lot of other tools (such as the browser)

                    oldMethod mclass:class.

                ].

                class changed:#methodTrap with:selector. "/ tell browsers

                Smalltalk changed:#methodTrap with:(MethodTrapChangeNotificationParameter changeClass:class changeSelector:selector).

            ].

        ]

    ]

    "Created: / 05-07-2011 / 21:33:13 / cg"

    "Modified: / 18-07-2012 / 10:53:22 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 22-07-2013 / 16:00:13 / cg"

!

setOrToggleBreakpointAtLine:line

    |pos bpnt prepareFullBreakSupport mClass ok|

    "/ if true, setting a single breakpoint in a method will create

    "/ a whole set of invisible (and disabled) breakpoints in that method,

    "/ one for each line.

    "/ These can later be enabled in the debugger

    "/ (otherwise, the debugger's behavior is stupid, as it cannot recompile a method

    "/ to set additional breakpoints).

    "/ We accept the additional overhead, as we are in debug mode anyway.

    "/ prepareFullBreakSupport := false.

    prepareFullBreakSupport := true.

    codeView method isNil ifTrue:[

        ^ self

    ].

    textView reallyModified ifTrue:[

        "/ leads to ugly behavior (method no longer found), if we allow

        "/ this...

        Dialog warn:'Please accept first (cannot set breakpoint while text is modified)'.

        ^ self

    ].

    bpnt := self breakpointAtLine:line.

    bpnt isNil ifTrue:[

        "/ no breakpoint there - create a new one as required (i.e. recompile)

        ok := (self canCreateOrToggleBreakpointAtLine:line).

        ok ifFalse:[

            (currentMethod isMethodWithBreakpoints and:[ prepareFullBreakSupport ]) ifFalse:[

                codeView topView class == DebugView ifTrue:[

                    (Dialog 

                        confirm:'Sorry, in an active method, I can only add new breakpoints in an already breakpointed method.

(i.e. a method stopped at a method breakpoint or one which already has statement breakpoints)

The reason is that the method needs to be recompiled for the breakpoint, which would not affect the method being currently executed.

You can proceed to set the breakpoint, but it will only affect the next call into this method, not the current invocation.'

                        yesLabel:'Set Breakpoint for Next Call' noLabel:'Ok') ifTrue:[

self halt.

                            ok := true.

                        ]

                ] ifFalse:[

                    Dialog warn:'Sorry, cannot add a new breakpoint here.'.

                ].

            ]

        ].

        ok ifTrue:[

            prepareFullBreakSupport ifTrue:[

                "/ add a (disabled) breakpoint for every source line. This

                "/ allows for breakpoints to be enabled/disabled in the debugger...

                1 to:textView numberOfLines do:[:eachLine |

                    |oldBPnt eachPos otherBpnt|

                    oldBPnt := self breakpointAtLine:eachLine.

                    oldBPnt isNil ifTrue:[

                        eachPos := textView characterPositionOfLine:eachLine col:1.

                        breakpoints isNil ifTrue:[ breakpoints := OrderedCollection new].

                        breakpoints add:((otherBpnt := Breakpoint new) position:eachPos line:eachLine).

                        eachLine == line ifTrue:[

                            bpnt := otherBpnt.

                        ] ifFalse:[

                            otherBpnt beInvisible.

                        ]

                    ].

                ].

            ] ifFalse:[

                pos := textView characterPositionOfLine:line col:1.

                breakpoints add:((bpnt := Breakpoint new) position:pos line:line).

            ].

            Screen current shiftDown ifTrue:[

                "/ trace

                bpnt beTracepoint

            ].

            self assert: breakpoints notEmptyOrNil.

            "/ recompile the method with breakpoints

            self recompile.

        ]

    ] ifFalse:[

        "/ breakpoint already there - just enable/disable

        Screen current shiftDown ifTrue:[

            bpnt toggleTracing

        ] ifFalse:[

            bpnt toggle.

        ].

        (mClass := currentMethod mclass) isNil ifTrue:[

            "/ hack: ouch - was wrapped in the meantime;

            "/ hurry up and update. Should be done elsewhere (in codeView)

            self updateCurrentMethod.

            currentMethod notNil ifTrue:[ mClass := currentMethod mclass ].

        ].

        mClass notNil ifTrue:[