"{ Package: 'stx:libtool' }"!

!AbstractSyntaxHighlighter class methodsFor:'api highlighting'!

formatExpression:aString in:aClass elementsInto:elementsCollection

    ^self formatExpression:aString in:aClass

    "Created: / 25-07-2010 / 08:57:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (format): / 04-10-2011 / 19:47:20 / cg"

! !

!AbstractSyntaxHighlighter class methodsFor:'api highlighting'!

formatMethod:aString in:aClass using:preferencesOrNil elementsInto: elements

    ^self formatMethod:aString in:aClass using:preferencesOrNil

    "Created: / 25-07-2010 / 08:58:00 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!ArrayedCollection methodsFor:'inspecting'!

inspector2TabForHexDump

    "a tab, showing a hex dump"

    |wrapper myByteSize|

    myByteSize := self size * self class elementByteSize.

    wrapper := Plug new.

    wrapper respondTo:#size with:[ myByteSize ].

    wrapper respondTo:#at: with:[:byteIdx | self byteAt:byteIdx ].

    wrapper respondTo:#do: with:[:aBlock | 1 to:myByteSize 

                                            do:[:i |

                                                aBlock value:(self byteAt:i) 

                                            ].

                                ].

    ^ Tools::Inspector2Tab new

            priority: 40;

            label:'Hexdump';

            view: ((ScrollableView for:TextView) 

                    list:(AbstractFileBrowser 

                                contentsOfBytesAsHexDump:wrapper 

                                numberOfAddressDigits:(myByteSize hexPrintString size) 

                                addressStart:0) expandTabs:false scanForNonStrings:false includesNonStrings:false;

                    yourself);

            yourself

    "Created: / 13-02-2012 / 15:08:42 / cg"

! !

!Block methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    self homeMethod isNil ifTrue:[

        ^ Dictionary new

            declareAllNewFrom:(super inspectorExtraAttributes ? #());

            add:'-code' -> 'no home method';

            add:'-source' -> 'no home method';

            yourself

    ].

    ^ Dictionary new

        declareAllNewFrom:(super inspectorExtraAttributes ? #());

        add:'-code' -> [ String streamContents:[:s | self homeMethod decompileTo:s]];

        add:'-source' -> [ self homeMethod source];

        yourself

    "Created: / 15-11-2011 / 14:24:10 / cg"

! !

!Breakpoint methodsFor:'accessing'!

icon

    ^description icon

    "Created: / 11-07-2011 / 18:21:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!BreakpointDescription methodsFor:'accessing'!

icon

    "do not use abbreviations like bpnt or brp or similar;

     when I do not know the exact name, I tend to search for implementors/senders

     of '*break*' or '*disabled*'.

     I will not find anything useful and have to single step if methods are named

     cryptically."

    condition isNil ifTrue:[

        state == #enabled ifTrue:[^ ToolbarIconLibrary breakpointRedEnabled16x16].

        state == #disabled ifTrue:[^ ToolbarIconLibrary breakpointRedDisabled16x16].

        state == #tracing ifTrue:[^ ToolbarIconLibrary tracepointBlue16x16].

    ] ifFalse:[

        state == #enabled ifTrue:[^ ToolbarIconLibrary breakpointBlueEnabled16x16].

        state == #disabled ifTrue:[^ ToolbarIconLibrary breakpointBlueDisabled16x16].

    ].

    ^nil

    "Created: / 28-06-2011 / 08:29:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 27-01-2012 / 13:46:23 / cg"

! !

!ByteArray methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    ^ Dictionary new

        declareAllNewFrom:(super inspectorExtraAttributes ? #());

        add:'-hexstring' -> [ self hexPrintString "WithSeparator:Character space" ];

        add:'-hexadecimal' ->

            [

                String

                    streamContents:[:s |

                        self class isWords ifTrue:[

                            self asWordArray printOn:s base:16 showRadix:true

                        ] ifFalse:[

                            self class isLongs ifTrue:[

                                self asLongIntegerArray printOn:s base:16 showRadix:true

                            ] ifFalse:[

                                self asByteArray printOn:s base:16 showRadix:true

                            ]

                        ]

                    ]

            ];

        yourself

    "Created: / 18-09-2006 / 21:29:59 / cg"

    "Modified: / 06-10-2006 / 13:57:20 / cg"

! !

!Change methodsFor:'private'!

flattenOnto: aCollection 

	aCollection add: self

! !

!Change methodsFor:'private'!

flattenedChanges

	| changes |

	changes := OrderedCollection new.

	self flattenOnto: changes.

	^changes

! !

!Change methodsFor:'accessing'!

removed

    ^(self objectAttributeAt: #removed) ? false

    "Created: / 24-10-2009 / 21:10:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Change methodsFor:'accessing'!

removed: aBoolean

    ^self objectAttributeAt: #removed put: aBoolean

    "Created: / 24-10-2009 / 21:11:09 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!ChangeSet methodsFor:'utilities'!

condenseChangesForRemoved

    "remove all changes which has been removed (marked for removal

     by aChange removed: true)"

    |changesToRemove|

    changesToRemove := self select:[:aChange | 

        aChange isCompositeChange ifTrue:

            [aChange condenseChangesForRemoved].        

        aChange removed

    ].

    self condenseChanges:changesToRemove

    "Created: / 05-11-2001 / 14:21:17 / cg"

    "Modified: / 12-10-2006 / 16:51:27 / cg"

! !

!ChangeSet methodsFor:'private'!

flattenOnto: aCollection 

    self do:[:change|change flattenOnto: aCollection]

! !

!ChangeSet methodsFor:'private'!

flattenedChanges

	| changes |

	changes := OrderedCollection new.

	self flattenOnto: changes.

	^changes

! !

!ChangeSet methodsFor:'inspecting'!

inspector2TabBrowser

    ^self newInspector2Tab

        label: 'Changes';    

        priority: 35;

        "JV@2011-08-06: Cannot do 'UserPreferences current changeSetBrowserClass'

         here since ChangeSetBrowser has no #on: and it is not an application model.

         Thus, enforce Tools::ChangeSetBrowser2 here..."

        application: ((Tools::ChangeSetBrowser2 on: self) beOneColumn; yourself)

    "Modified: / 25-07-2011 / 12:22:07 / sr"

    "Modified: / 06-08-2011 / 21:22:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 13-09-2011 / 11:55:53 / cg"

! !

!ChangeSet methodsFor:'inspecting'!

inspector2Tabs

    ^ #( inspector2TabCommon inspector2TabBrowser )

    "Created: / 05-07-2011 / 13:40:19 / cg"

! !

!Character methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    ^ Dictionary new

	declareAllNewFrom:(super inspectorExtraAttributes ? #());

	add:'-hexValue' -> [ self codePoint radixPrintStringRadix:16 ];

	add:'-string' -> [ self stringSpecies with:self ];

	add:'-utf8String' -> [ self utf8Encoded ];

	add:'-utf8' -> [ self utf8Encoded asByteArray hexPrintStringWithSeparator:Character space ];

	yourself

    "

     $a inspect

    "

    "Created: / 22-10-2006 / 03:52:20 / cg"

! !

!CharacterArray methodsFor:'inspecting'!

inspector2TabBytes

    ^self newInspector2Tab

        label: 'Bytes';

        priority: 25;

        view: ((ScrollableView for:EditTextView) contents: 

                (self asByteArray hexPrintStringWithSeparator:Character space); yourself)

    "Created: / 17-02-2008 / 10:10:50 / janfrog"

    "Created: / 20-07-2011 / 16:36:52 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 21-08-2011 / 07:32:57 / cg"

! !

!CharacterArray methodsFor:'inspecting'!

inspector2TabHTML

    ^self newInspector2Tab

        label: 'HTML';

        priority: 35;

        view: ((ScrollableView for:HTMLDocumentView) setText: self; yourself)

    "Created: / 17-02-2008 / 10:10:50 / janfrog"

    "Created: / 07-11-2011 / 12:35:15 / cg"

! !

!CharacterArray methodsFor:'inspecting'!

inspector2TabText

    ^self newInspector2Tab

        label: 'String';

        priority: 50;

        view: ((ScrollableView for:EditTextView) contents: self; yourself)

    "Created: / 17-02-2008 / 10:10:50 / janfrog"

    "Modified: / 21-08-2011 / 08:02:57 / cg"

! !

!CharacterArray methodsFor:'inspecting'!

inspector2Tabs

    HTMLDocumentView notNil ifTrue:[

        (self startsWith:'<!!DOCTYPE html') ifTrue:[

            ^ #( inspector2TabCommon inspector2TabText inspector2TabBytes inspector2TabHTML )

        ].

    ].

    ^ #( inspector2TabCommon inspector2TabText inspector2TabBytes )

    "Created: / 05-07-2011 / 13:40:27 / cg"

! !

!CharacterArray methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    |d|

    d := Dictionary new

	declareAllNewFrom:(super inspectorExtraAttributes ? #());

	add:'-utf8String' -> [ self utf8Encoded ];

	add:'-utf8' -> [ self utf8Encoded asByteArray hexPrintStringWithSeparator:Character space ];

	yourself.

    HTMLUtilities notNil ifTrue:[

	d add:'-html' -> [ HTMLUtilities escapeCharacterEntities:self ].

    ].

    ^ d

    "

     'aou' inspect

    "

    "Created: / 22-10-2006 / 03:52:20 / cg"

! !

!Collection methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    ^ Dictionary new

	declareAllNewFrom:(super inspectorExtraAttributes ? #());

	add:('-size' -> [ self size ]);

	yourself

    "

     'hello' inspect

    "

    "Created: / 06-10-2006 / 13:56:52 / cg"

    "Modified: / 06-10-2006 / 17:43:45 / cg"

! !

!Color methodsFor:'inspecting'!

inspectorClass

    "return the class of an appropriate inspector.

     ST/X has a specialized ColorInspectorView for that"

    ^ ColorInspectorView

    "Modified: 23.4.1996 / 13:39:50 / cg"

! !

!Color methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    ^ Dictionary new

	declareAllNewFrom:(super inspectorExtraAttributes ? #());

	add:'-rgb' -> [ self rgbValue hexPrintString ];

	add:'-html' -> [ self htmlPrintString ];

	yourself

    "

     Color red inspect

    "

! !

!CompositeChange methodsFor:'utilities'!

condenseChangesForRemoved

    self changes condenseChangesForRemoved

! !

!CompositeChange methodsFor:'private'!

flattenOnto: aCollection

    changes do:[:change|change flattenOnto: aCollection]

! !

!CompositeChange methodsFor:'accessing'!

removed

    ^changes allSatisfy: [:e|e removed]

! !

!CompositeChange methodsFor:'accessing'!

removed: aBoolean

    changes do:[:e|e removed: aBoolean]

! !

!Date methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    ^ Dictionary new

        declareAllNewFrom:(super inspectorExtraAttributes ? #());

        add:'-dayInWeek' -> [ self dayInWeek printString , ' "', self dayOfWeekName , '"' ];

        add:'-dayInYear' -> [ self dayInYear ];

        add:'-daysInMonth' -> [ self daysInMonth ];

        add:'-monthName' -> [ self monthName ];

        add:'-leapYear' -> [ self isLeapYear ];

        yourself

    "

     Date today inspect

    "

    "Created: / 20-01-2011 / 12:19:05 / cg"

! !

!Dictionary methodsFor:'inspecting'!

inspector2TabLabel

    ^ 'Dictionary'

    "Created: / 14-07-2011 / 11:57:18 / cg"

! !

!Dictionary methodsFor:'inspecting'!

inspectorClass

    "redefined to use DictionaryInspector

     (instead of the default Inspector)."

    ^ DictionaryInspectorView

! !

!EditTextView methodsFor:'accessing-dimensions'!

absoluteXOfPosition:positionInText 

    |accumulatedX container|

    accumulatedX := 0.

    container := self.

    [ container notNil ] whileTrue:[

        accumulatedX := accumulatedX + container origin x.

        container := container isTopView ifFalse:[

                    container container

                ] ifTrue:[ nil ].

    ].

    ^ (self xOfPosition:positionInText) + accumulatedX

    "Created: / 16-02-2010 / 10:05:19 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!EditTextView methodsFor:'accessing-dimensions'!

absoluteYOfCursor

    | accumulatedY container |

    accumulatedY := 0.

    container := self.

    [ container notNil ] whileTrue:[

        accumulatedY := accumulatedY + container origin y.

        container := container isTopView 

            ifFalse:[container container]

            ifTrue:[nil].

    ].

    ^(self yOfCursor) + accumulatedY

    "Created: / 27-05-2005 / 07:45:53 / janfrog"

    "Modified: / 27-05-2005 / 23:03:40 / janfrog"

! !

!EditTextView methodsFor:'accessing-dimensions'!

xOfPosition: positionInText

    | line col |

    line := self lineOfCharacterPosition: positionInText.

    col  := positionInText - (self characterPositionOfLine:line col:1) + 1.

    ^

        (self xOfCol:col inVisibleLine:(self listLineToVisibleLine: line))

            - viewOrigin x.

    "Created: / 16-02-2010 / 10:04:27 / Jan Vrany <jan.vrany@fit.cvut.cz>"